Math Pro 數學補給站 Board logo

標題: 用Maxima解題 [打印本頁]

作者: bugmens    時間: 2009-3-15 11:02     標題: 用Maxima解題

Maxima簡介
http://zh.wikipedia.org/wiki/Maxima

中文教學
http://math.nccu.edu.tw/~yenlung ... l/maximalinear.html
http://yenlung.math.nccu.edu.tw/index.html/idisk/maximalinear.pdf
http://math.npue.edu.tw/front/bin/ptlist.phtml?Category=119

其他的教學網頁
http://www.eonet.ne.jp/~kyo-ju/maxima.pdf
http://people.ysu.edu/~gkerns/maxima/
http://www.math.hawaii.edu/home/wxmaxima.html
http://maxima.sourceforge.net/documentation.html
101.6.16補充
http://math.stanford.edu/~paquin/MaximaBook.pdf
討論區
http://www.math.utexas.edu/pipermail/maxima/2013/

101.11.13補充
http://maxima-online.org/
線上執行maxima的網頁,輸入指令後點選Calculate。


當然Maple和Mathematica都是非常專業的軟體,各項功能都非常強大而且有眾多的套件可以解決不同領域的問題,這是Maxima所比不上的,但我只要能解決高中程度的問題,Maxima算是不錯的選擇
以下是我試用Maxima近一年來的筆記,放在這裡也算是個紀錄

[ 本帖最後由 bugmens 於 2013-8-17 06:42 AM 編輯 ]
作者: bugmens    時間: 2009-3-15 11:17

https://math.pro/db/thread-407-1-1.html
求出下列聯立方程式的解  \( x,y,z ∈R\)
$$ x+xy+xyz=12 $$
$$ y+yz+yzx=5 $$
$$ z+zx+zxy=6 $$


(%i1) x+x*y+x*y*z=12;  y+y*z+y*z*x=5;  z+z*x+z*x*y=6;
(%o1) \( xyz+xy+x=12 \)
(%o2) \( xyz+yz+y=5 \)
(%o3) \( xyz+xz+z=6 \)

/*
(2)式*x-(1)式
(3)式*y-(2)式
(1)式*z-(3)式*/


(%i4) ratsimp(%o2*x-%o1);  ratsimp(%o3*y-%o2);  ratsimp(%o1*z-%o3);
(%o4) \( x^2yz-x=5x-12 \)
(%o5) \( xy^2z-y=6y-5 \)
(%o6) \( xyz^2-z=12z-6 \)

/*
得到xyz=(6x-12)/x=(7y-5)/y=(13z-6)/z*/


(%i7) (%o4+x)/x;  (%o5+y)/y;  (%o6+z)/z;
(%o7) \( xyz=\frac{6x-12}{x} \)
(%o8) \( xyz=\frac{7y-5}{y} \)
(%o9) \( xyz=\frac{13z-6}{z} \)

/*
從(6x-12)/x=(7y-5)/y 得到y
從(6x-12)/x=(13z-6)/z 得到z*/


(%i10) solve([rhs(%o7)=rhs(%o8),rhs(%o7)=rhs(%o9)],[y,z]);
(%o10) [ [ \( y=\frac{5x}{x+12},z=\frac{6x}{7x+12} \) ] ]

/*
y,z分別代入(1)式*/


(%i11) ev(%o1,%o10[1]);
(%o11) \( \frac{30x^3}{(x+12)(7x+12)}+\frac{5x^2}{x+12}+x=12 \)

/*
解方程式得到x的三個答案x=4,-2,-3*/


(%i12) factor(%-12);
(%o12) \( \frac{72(x-4)(x+2)(x+3)}{(x+12)(7x+12)}=0 \)

/*
將x代回y=5x/(x+12),z=6x/(7x+12)
得到答案(4,5/4,3/5),(-2,-1,6),(-3,-5/3,2)*/


(%i13) ev(%o10[1],x=4);
(%o13) [ \( y=\frac{5}{4},z=\frac{3}{5} \) ]

(%i14) ev(%o10[1],x=-2);
(%o14) [ \( y=-1,z=6 \) ]

(%i15) ev(%o10[1],x=-3);
(%o15) [ \( y=-\frac{5}{3},z=2 \) ]

(%i16) 


[ 本帖最後由 bugmens 於 2009-3-15 12:44 PM 編輯 ]
作者: bugmens    時間: 2009-3-21 22:52

http://forum.nta.org.tw/examservice/showthread.php?t=47986
求經過(-1,-2),(0,4),(2,1),(4,-1)之等軸雙曲線方程式(97南港高工)


/*
設等軸雙曲線方程式為x^2+a*x*y-y^2+b*x+c*y+d=0;*/


(%i) x^2+a*x*y-y^2+b*x+c*y+d=0;
(%o1) \( -y^2+axy+cy+x^2+bx+d=0 \)

/*
將(-1,-2),(0,4),(2,1),(4,-1)四點的座標代入*/


(%i2) ev(%o1,x=-1,y=-2);  ev(%o1,x= 0,y= 4);  ev(%o1,x= 2,y= 1);  ev(%o1,x= 4,y=-1);
(%o2) \( d-2c-b+2a-3=0 \)
(%o3) \( d+4c-16=0 \)
(%o4) \( d+c+2b+2a+3=0 \)
(%o5) \( d-c+4b-4a+15=0 \)

/*
解聯立方程式得a,b,c,d*/


(%i6) solve([%o2,%o3,%o4,%o5],[a,b,c,d]);
(%o6) [[ \( a=-\frac{10}{19} , b=-\frac{91}{19} , c=\frac{53}{19} , d=\frac{92}{19} \) ]]

/*
將a,b,c,d代回原式得到答案


(%i7) ev(%o1,%[1]);
(%o7) \( -y^2-\frac{10xy}{19}+\frac{53y}{19}+x^2-\frac{91x}{19}+\frac{92}{19}=0 \)

(%i8) ratsimp(%*19);
(%o8) \( -y^2+(53-10x)y+19x^2-91x+92=0 \)



[ 本帖最後由 bugmens 於 2009-3-21 10:56 PM 編輯 ]
作者: bugmens    時間: 2009-3-31 21:39

TRML2002團體賽
設實數數列\( <a_n> \)滿足\( a_n=a_{n-1}-a_{n-1} \) (\( n=1,2,... \)),且\( a_{100}=1 \),\( a_{200}=2 \),試求\( a_{300} \)。


(%i1) a[1]:a$  a[2]:b$  a[n]:=a[n-1]-a[n-2];
(%o3) \( a_n:=a_{n-1}-a_{n-2} \)

/*
列出數列前12項發現每隔6個一循環*/

(%i4) for n:1 thru 12 do print("a[",n,"]=",a[n]);
\( a[  1  ]= a \)
\( a[  2  ]= b \)
\( a[  3  ]= b-a \)
\( a[  4  ]= -a \)
\( a[  5  ]= -b \)
\( a[  6  ]= a-b \)
\( a[  7  ]= a \)
\( a[  8  ]= b \)
\( a[  9  ]= b-a \)
\( a[  10  ]= -a \)
\( a[  11  ]= -b \)
\( a[  12  ]= a-b \)
(%o4) done

/*
第100項為1,a=-1*/

(%i5) a[100]=1;
(%o5) \( -a=1 \)

/*
第200項為2,b=2*/

(%i6) a[200]=2;
(%o6) \( b=2 \)

/*
第300項為-3*/

(%i7) a[300];
(%o7) \( a-b \)



[ 本帖最後由 bugmens 於 2009-3-31 10:03 PM 編輯 ]
作者: bugmens    時間: 2009-4-10 21:50

TRML2007個人賽
設數列{\( a_{n} \)}滿足\( a_{n+2}=a_{n+1}-a_{n} \)且\( a_{2}=96 \)。已知此數列前2005項的和等於2006,則此數列前2007項的和等於


(%i1) a[1]:a$  a[2]:b$  a[n]:=a[n-1]-a[n-2];
(%o3) \( a_{n}:=a_{n-1}-a_{n-2} \)

/*
第2項為96,b=96

(%i5) a[2]=96;
(%o5) \( b=96 \)

/*
前2005項的和為2006,a=2006

(%i6) sum(a[k],k,1,2005)=2006;
(%o6) \( a=2006 \)

/*
前2007項的和為2b=192

(%i7) sum(a[k],k,1,2007);
(%o7) \( 2b \)


作者: bugmens    時間: 2009-4-18 01:15

滿足方程組\(  \frac{1}{x}+\frac{1}{2 y}=(x^2+3y^2)(3x^2+y^2)  \),\( \frac{1}{x}-\frac{1}{2 y}=2(y^4-x^4) \)的實數對\( (x,y) \)。
William Lowell Putnam Mathematical Competition 2001,97中一中
http://forum.nta.org.tw/examservice/showthread.php?t=46779#8
2006 全國高中數學能力競賽台北市試題
http://www.math.nuk.edu.tw/senpe ... h_TaipeiCity_02.pdf
2005 全國高中數學能力競賽台灣省雲嘉區試題
http://www.math.nuk.edu.tw/senpe ... _High_ChiaYi_01.pdf


(%i1) 1/x+1/(2*y)=(x^2+3*y^2)*(3*x^2+y^2);
(%o1) \( \frac{1}{2y}+\frac{1}{x}=(y^2+3x^2)(3y^2+x^2) \)

(%i2) 1/x-1/(2*y)=2*(y^4-x^4);
(%o2) \( \frac{1}{x}-\frac{1}{2y}=2(y^4-x^4) \)

(%i3) (%o1+%o2)*x;  (%o1-%o2)*y;
(%o3) \( 2=x(2(y^4-x^4)+(y^2+3x^2)(3y^2+x^2)) \)
(%o4) \( 1=y((y^2+3x^2)(3y^2+x^2)-2(y^4-x^4)) \)

(%i5) ratsimp(%o3);  ratsimp(%o4);
(%o5) \(  2=5xy^4+10x^3 y^2+x^5  \)
(%o6) \( 1=y^5+10x^2y^3+5x^4y \)

(%i7) factor(%o5+%o6);  factor(%o5-%o6);
(%o7) \( 3=(y+x)^5 \)
(%o8) \( 1=-(y-x)^5 \)

(%i9) %o7^(1/5);  %o8^(1/5);
(%o9) \( 3^{1/5}=y+x \)
(%o10) \( 1=x-y \)

(%i11) solve([%o9,%o10],[x,y]);
(%o11) \( [  [x=\frac{3^{1/5}+1}{2},y=\frac{3^{1/5}-1}{2}]  ] \)



[ 本帖最後由 bugmens 於 2009-4-18 01:26 AM 編輯 ]
作者: bugmens    時間: 2009-5-3 11:23

用利美佛定理,表示出sin5θ=?(用sinθ表示),cos5θ=?(用cosθ表示)(新竹高中)
http://forum.nta.org.tw/oldphpbb2/viewtopic.php?t=4189
用cosθ來表示cos5θ?(95士林高商)
http://forum.nta.org.tw/oldphpbb2/viewtopic.php?t=41891


利用利美佛定理,對(cosx+i*sinx)^5展開
cos5x+i*sin5x=(cosx+i*sinx)^5

(%i1) expand((cos(x)+%i*sin(x))^5);
(%o1) \( i sin(x)^{5}+5 cos(x)sin(x)^{4}-10 i cos(x)^{2}sin(x)^{3}-10 cos(x)^{3} sin(x)^{2}+5 i cos(x)^{4} sin(x)+cos(x)^{5} \)

分出實部虛部
(%i2) realpart(%)+%i*imagpart(%);
(%o2) \( i \left(sin(x)^{5}-10cos(x)^{2}sin(x)^{3}+5 cos(x)^{4}sin(x) \right)+5cos(x)sin(x)^{4}-10cos(x)^{3}sin(x)^{2}+cos(x)^{5} \)

實部用sin(x)^2=1-cos(x)^2換掉
虛部用cos(x)^2=1-sin(x)^2換掉

(%i3) ratsubst(1-cos(x)^2,sin(x)^2,realpart(%o2))+%i*(ratsubst(1-sin(x)^2,cos(x)^2,imagpart(%o2)));
(%o3) \( i \left(16sin(x)^{5}-20sin(x)^{3}+5sin(x) \right)+16cos(x)^{5}-20cos(x)^{3}+5cos(x) \)

另一種直接得到答案的方法
(%i4) trigexpand(cos(5*x));
(%o4) \( 5cos(x)sin(x)^{4}-10cos(x)^{3}sin(x)^{2}+cos(x)^5 \)
(%i5) ratsubst(1-cos(x)^2,sin(x)^2,%);
(%o5) \( 16 cos(x)^{5}-20 cos(x)^{3}+5 cos(x) \)

sin(5x)的答案
(%i6) trigexpand(sin(5*x));
(%o6) \( sin(x)^{5}-10 cos(x)^{2}sin(x)^{3}+5 cos(x)^{4}sin(x) \)
(%i7) ratsubst(1-sin(x)^2,cos(x)^2,%);
(%o7) \( 16 sin(x)^{5}-20 sin(x)^{3}+5 sin(x) \)

作者: bugmens    時間: 2009-5-16 06:31

求\( \frac{1}{(x-3)(x-2)^2} \)第八項的係數?
(97松山工農)

100.10.30補充題目出處
求\( \displaystyle \frac{1}{(x-3)(x-2)^2} \)中\( x^8 \)的係數。
答案:\( \displaystyle -\Bigg(\; \frac{1}{3} \Bigg)\; ^9-7 \Bigg(\; \frac{1}{2} \Bigg)\; ^{10} \)
張福春、曾介玫,一般生成函數之應用,數學傳播32卷3期 pp.12-35


/*
設定次方從小排到大*/

(%i) powerdisp : true;
(%o1) true

/*
假設1/((x-3)*(x-2)^2)展開式為
a0+a1x+a2x^2+a3x^3+...

(%i2) 1/((x-3)*(x-2)^2)=sum(a[k]*x^k,k,0,10);
(%o2) \( \frac{1}{(-3+x)(-2+x)^2}=a_{0}+a_{1}x+a_{2}x^{2}+a_{3}x^{3}+a_{4}x^{4}+a_{5}x^{5}+a_{6}x^{6}+a_{7}x^{7}+a_{8}x^{8}+a_{9}x^{9}+a_{10}x^{10} \)

/*
將1/((x-3)*(x-2)^2)換成部分分式*/

(%i3) partfrac(lhs(%),x)=rhs(%);
(%o3) \( \frac{1}{-3+x}-\frac{1}{(-2+x)^2}-\frac{1}{-2+x}=a_{0}+a_{1}x+a_{2}x^{2}+a_{3}x^{3}+a_{4}x^{4}+a_{5}x^{5}+a_{6}x^{6}+a_{7}x^{7}+a_{8}x^{8}+a_{9}x^{9}+a_{10}x^{10} \)

/*
兩邊作八次微分*/

(%i4) diff(%, x, 8);
(%o4) \( \frac{40320}{(-3+x)^9}-\frac{362880}{(-2+x)^10}-\frac{40320}{(-2+x)^9}=40320 a_{8}+362880 a_{9}x+1814400 a_{10}x^2 \)

/*
用x=0代入,將其他x^n項去掉*/

(%i5) ev(%,x=0);
(%o5) \( -\frac{4858175}{17496}=40320 a_{8} \)

/*
兩邊同除8!=40320得到答案*/

(%i6) %/40320;
(%o6) \( -\frac{138805}{20155392}=a_{8} \)

/*
用泰勒展開式驗證答案*.

(%i7) taylor(1/((x-3)*(x-2)^2),x,0,8);
(%o7) \( -\frac{1}{12}-\frac{x}{9}-\frac{43x^{2}}{432}-\frac{97x^{3}}{1296}-\frac{793x^{4}}{15552}-\frac{761x^{5}}{23328}-\frac{11191x^{6}}{559872}-\frac{19939x^{7}}{1679616}-\frac{138805x^{8}}{20155392}+... \)


[ 本帖最後由 bugmens 於 2011-10-30 07:02 PM 編輯 ]
作者: bugmens    時間: 2009-8-2 06:30

半徑為1cm、2cm、3cm的三個圓互相外切,如圖所示。有一個圓落於它們之間,分別與這三個外切,求這個小圓的半徑。
(98國立清水高中,https://math.pro/db/thread-836-1-1.html)


(%i1) (x-0)^2+(y-3)^2=(2+r)^2;
   (x-0)^2+(y-0)^2=(1+r)^2;
   (x-4)^2+(y-0)^2=(3+r)^2;
(%o1) \( (y-3)^2+x^2=(r+2)^2 \)
(%o2) \( y^2+x^2=(r+1)^2 \)
(%o3) \( y^2+(x-4)^2=(r+3)^2 \)

解出x
(%i4) ratsimp(%o2-%o3);  solve(%,[x]);
(%o4) \( 8x-16=-4r-8 \)
(%o5) \( \displaystyle [\ x=-\frac{r-2}{2} ]\ \)

解出y
(%i6) ratsimp(%o2-%o1);  solve(%,[y]);
(%o6) \( 6y-9=-2r-3 \)
(%o7) \( \displaystyle [\ y=-\frac{r-3}{3} ]\ \)

代回(2)式,得到r的方程式
(%i8) subst(rhs(%o5[1]),x,%o2);
(%o8) \( \displaystyle y^2+\frac{(r-2)^2}{4}=(r+1)^2 \)

(%i9) subst(rhs(%o7[1]),y,%);
(%o9) \( \displaystyle \frac{(r-2)^2}{4}+\frac{(r-3)^2}{9}=(r+1)^2 \)

解出r值
(%i10) solve(%,[r]);
(%o10) \( \displaystyle [\ r=\frac{6}{23},r=-6 ]\ \)

得圓心座標
(%i11) ev(%o5,%o10[1]);ev(%o7,%o10[1]);
(%o11) \( \displaystyle [\ x=\frac{20}{23} ]\ \)
(%o12) \( \displaystyle [\ y=\frac{21}{23} ]\ \)


[ 本帖最後由 bugmens 於 2009-8-2 06:33 AM 編輯 ]
作者: bugmens    時間: 2009-9-16 10:35

題目出處 https://math.pro/db/thread-857-1-1.html

假設a,b是實數來解題,只是\( \overline{z_1 z_2} \)不曉得是相乘取共軛複數還是\( z_1 , z_2 \)在複數平面的距離


設定實部在前,虛部在後
(%i) powerdisp:true;
(%o) true


設定z1為√3/2*a+(a+1)i
(%2) z1:sqrt(3)/2*a+(a+1)*%i;
(%o2) \( \frac{\sqrt{3}a}{2}+%i(1+a) \)

設定z2為-3√3b+(b+2)i
(%i3) z2:-3*sqrt(3)*b+(b+2)*%i;
(%o3) \( -3^{3/2}b+%i(2+b) \)

將3z1^2+z2^2展開
(%i4) expand(3*z1^2+z2^2);
(%o4) \( \displaystyle -7-6a+3^{3/2}%i a-\frac{3a^2}{4}+3^{3/2}%ia^2-4b-4 \cdot 3^{3/2}%i b+26b^2-2 \cdot 3^{3/2}%i b^2 \)

將實部和虛部分開
(%i5) realpart(%o4)=0;imagpart(%o4)=0;
(%o5) \( -7-6a-\frac{3a^2}{4}-4b+26b^2=0 \)
(%o6) \( 3^{3/2}+3^{3/2}a^2-4 \cdot 3^{3/2}b-2 \cdot 3^{3/2}b^2=0 \)

(%i7) ratsimp(%o5*4);ratsimp(%o6/3^(3/2));
(%o7) \( -28-24a-3a^2-16b+104b^2=0 \)
(%o8) \( a+a^2-4b-2b^2=0 \)

得到a的解析式
(%i9) solve(%o7+%o8*3,a);
(%o9) \( \displaystyle [a=\frac{-4-4b+14b^2}{3}] \)

代回%o8,得到b的答案
(%i10) ev(%o8,%o9);factor(%);
(%o10) \( \displaystyle -4b-2b^2+\frac{-4-4b+14b^2}{3}+\frac{(-4-4b+14b^2)^2}{9}=0 \)
(%o11) \( \displaystyle \frac{4(-1+b)(-1+7b)(1+4b+7b^2)}{9}=0 \)

代回%o9,得到a的答案
(%i12) ev(%o9,b=1);ev(%o9,b=1/7);
(%o12) \( [a=2] \)
(%o13) \( [a=\frac{10}{7}] \)

或者直接用solve解%o7,%o8得a,b兩組答案
(%i14) solve([%o7,%o8],[a,b]);
(%o14) \( \displaystyle[[a=2,b=1],[a=\frac{10}{7},b=\frac{1}{7}]] \)

代回%o2,%o3,得到z1,z2兩組答案
(%i15) ev([%o2,%o3],%o14[1]);
(%o15) \( [\sqrt{3}+3%i,-3^{3/2}+3 % i] \)

(%i16) ev([%o2,%o3],%o14[2]);
(%o16) \( \displaystyle [-\frac{5 \sqrt{3}}{7}-\frac{3%i}{7},-\frac{3^{3/2}}{7}+\frac{15 %i}{7}] \)



[ 本帖最後由 bugmens 於 2009-9-16 11:06 AM 編輯 ]
作者: bugmens    時間: 2009-10-17 10:42

設a與b均為整數。已知\( ax^5+bx^4+1 \)可被\( x^2-x-1 \)整除,試求\( a+b \)之值。
(1999TRML接力賽)

已知多項式\( ax^9+bx^8+1 \)被\( x^2-x-1 \)整除,則數對\( (a,b)= \)?
(2006年中一中第1次學測模擬考,http://jflaith.myweb.hinet.net/ra/RA130.swf)

已知m,n是整數,且\( mx^{17}+nx^{16}+1 \)是\( x^2+x-1 \)的倍式,則m=?
(97中和高中)
這題問的是\( x^2+x-1 \)答案是-987
和下面幾題\( x^2-x-1 \)答案是+987,要注意

Find a if a and b are integers such that \( x^2-x-1 \) is a factor of \( ax^{17}+bx^{16}+1 \).
(1988AIME)

\( a,b \in Z \),若\( ax^{17}+bx^{16}+1 \)能被\( x^2-x-1 \)整除,求\( a= \)?
(94嘉義女中,http://forum.nta.org.tw/oldphpbb2/viewtopic.php?t=21358)

設a,b為整數,且\( x^2-x-1 \)整除\( ax^{17}+bx^{16}+1 \),試求a之值?
(2006TRML團體賽)

已知a,b為實數,若\( ax^{17}+bx^{16}+1 \)能被\( x^2-x-1 \)整除,則a=?
(100麗山高中,https://math.pro/db/thread-1138-1-1.html)
(100楊梅高中,https://math.pro/db/thread-1162-1-2.html)

106.9.17補充
設\(a,b\)為整數,如果多項式\(x^2-x-1\)為\(ax^{17}+bx^{16}+1\)的因式,試求\(a\)之值。
(104高中數學能力競賽,https://math.pro/db/thread-2466-1-6.html)



(%i) fx:a*x^17+b*x^16+1;
(%o1) \( ax^{17}+bx^{16}+1 \)

將x^2換成x+1降次方,直到最高次方為1次停止
(%i2) 
while (hipow(fx,x)>1) do
  (fx:ratsubst(x+1,x^2,fx),
   print(fx)
  )$

(%o2)
\( ax^9+(b+8a)x^8+(8b+28a)x^7+(28b+56a)x^6+(56b+70a)x^5+(70b+56a)x^4+(56b+28a)x^3+(28b+8a)x^2+(8b+a)x+b+1 \)
\( ax^5+(9b+40a)x^4+(112b+248a)x^3+(352b+528a)x^2+(384b+448a)x+128b+128a+1 \)
\( ax^3+(121b+290a)x^2+(866b+1305a)x+489b+696a+1 \)
\( ax^2+(987b+1596a)x+610b+986a+1 \)
\( (987b+1597a)x+610b+987a+1 \)

x項和常數項係數為0,解a,b
987b+1597a=0
610b+987a+1=0

(%i3) solve([coeff(fx,x,1)=0,coeff(fx,x,0)=0],[a,b]);
(%o3) \( [ [a=987,b=-1597] ] \)

利用for迴圈,將前16項的答案列出來發現和費波那契數列有關係
(%i4) 
for i:1 thru 16 do
  (fx:a*x^(i+1)+b*x^i+1,
   while (hipow(fx,x)>1) do
     (fx:ratsubst(x+1,x^2,fx)),
   print(fx,solve([coeff(fx,x,1)=0,coeff(fx,x,0)=0],[a,b]))
  )$

(%o4) 
\( (b+a)x+a+1 [ [a=-1,b=1] ] \)
\( (b+2a)x+b+a+1 [ [a=1,b=-2] ] \)
\( (2b+3a)x+b+2a+1 [ [a=-2,b=3] ] \)
\( (3b+5a)x+2b+3a+1 [ [a=3,b=-5] ] \)
\( (5b+8a)x+3b+5a+1 [ [a=-5,b=8] ] \)
\( (8b+13a)x+5b+8a+1 [ [a=8,b=-13] ] \)
\( (13b+21a)x+8b+13a+1 [ [a=-13,b=21] ] \)
\( (21b+34a)x+13b+21a+1 [ [a=21,b=-34] ] \)
\( (34b+55a)x+21b+34a+1 [ [a=-34,b=55] ] \)
\( (55b+89a)x+34b+55a+1 [ [a=55,b=-89] ] \)
\( (89b+144a)x+55b+89a+1 [ [a=-89,b=144] ] \)
\( (144b+233a)x+89b+144a+1 [ [a=144,b=-233] ] \)
\( (233b+377a)x+144b+233a+1 [ [a=-233,b=377] ] \)
\( (377b+610a)x+233b+377a+1 [ [a=377,b=-610] ] \)
\( (610b+987a)x+377b+610a+1 [ [a=-610,b=987] ] \)
\( (987b+1597a)x+610b+987a+1 [ [a=987,b=-1597] ] \)



可以看到\( a,b \)形成費波那契數列,考試時加一加就可以得到答案
而且610*b+987a+1=0,可視為-F(15)*F(17)+F(16)*F(16)+1=0
在 http://en.wikipedia.org/wiki/Fibonacci_number 可以找到一般式
\( (-1)^n=F_{n+1}F_{n-1}-F^2_n \)

100.11.28補充
原來這恆等式是有名字的
http://en.wikipedia.org/wiki/Cassini_and_Catalan_identities
http://mathworld.wolfram.com/CassinisIdentity.html

[ 本帖最後由 bugmens 於 2017-9-17 04:55 編輯 ]
作者: bugmens    時間: 2009-10-27 23:13


利用部分分式求積分
(%i1) 'integrate(x/(x^3+4*x^2+5*x+2), x);
(%o1) \( \displaystyle \int \frac{x}{x^3+4x^2+5x+2}dx \)

找出分母的因式
(%i2) factor(denom(part(%,1)));
(%o2) \( (x+1)^2(x+2) \)

設定部分分式,假設a,b,c為各分式的係數
(%i3) part(%o1,1)=a/(x+2)+b/(x+1)+c/(x+1)^2;
(%o3) \( \displaystyle \frac{x}{x^3+4x^2+5x+2}=\frac{a}{x+2}+\frac{b}{x+1}+\frac{c}{(x+1)^2} \)

分式通分
(%i4) ratsimp(%);
(%o4) \( \displaystyle \frac{x}{x^3+4x^2+5x+2}=\frac{(b+a)x^2+(c+3b+2a)x+2c+2b+a}{x^3+4x^2+5x+2} \)

去掉分母
(%i5) %*denom(lhs(%));
(%o5) \( x=(b+a)x^2+(c+3b+2a)x+2c+2b+a \)

比較等號兩邊x^2項,x項,常數項係數
(%i6) coeff(%o5,x,0);coeff(%o5,x,1);coeff(%o5,x,2);
(%o6) \( 0=2c+2b+a \)
(%o7) \( 1=c+3b+2a \)
(%o8) \( 0=b+a \)

解出未知數a,b,c
(%i9) solve([%o6,%o7,%o8],[a,b,c]);
(%o9) \( [ [a=-2,b=2,c=-1] ] \)

將a,b,c代回部分分式
(%i10) ev(%o3,part(%o9,1));
(%o10) \( \displaystyle \frac{x}{x^3+4x^2+5x+2}=-\frac{2}{x+2}+\frac{2}{x+1}-\frac{1}{(x+1)^2} \)

或者一開始用partfrac直接得到部分分式
(%i11) partfrac(part(%o1,1),x);
(%o11) \( \displaystyle -\frac{2}{x+2}+\frac{2}{x+1}-\frac{1}{(x+1)^2} \)

將各部分分式積分
(%i12) integrate(%, x);
(%o12) \( \displaystyle -2 log(x+2)+2 log(x+1)+\frac{1}{x+1} \)

答案就和integrate指令算出來的結果相同
(%i13) integrate(x/(x^3+4*x^2+5*x+2), x);
(%o13) \( \displaystyle -2 log(x+2)+2 log(x+1)+\frac{1}{x+1} \)


作者: sinboy    時間: 2009-10-31 18:23

版大您好,我想請教一下您是如何將下列的內容擷取出來的,
(%i4) ratsimp(%o2*x-%o1);  ratsimp(%o3*y-%o2);  ratsimp(%o1*z-%o3);
(%o4) x2
yz
−x=5x−12
(%o5) xy
2
z
−y
=6y
−5
(%o6) xyz
2
−z
=12z
−6
我使用複製會變成下面的樣子
/* [wxMaxima: input   start ] */
ratsimp(%o2*x-%o1);  ratsimp(%o3*y-%o2);  ratsimp(%o1*z-%o3);
/* [wxMaxima: input   end   ] */
選擇copy as image會變成圖檔,怎麼試就是試不出來變成您post的內容那樣有紅色和藍色且可以選取複製,我使用的是0.8.3的版本,謝謝!
作者: bugmens    時間: 2009-11-19 21:39

回答上面的問題
maxima沒有直接轉換的指令,這是我用論壇的指令拼湊出來的
全形的[和]請自行替換成半形的[和]

[img]h ttp://www.permucode.com/maxima/wxm_ul.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_uc.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_ur.gif[/img]

[color=red](%i1)[/color] [color=blue]x^2-4xy+6y^2-2x-20y-29[/color]
[color=red](%o1)[/color] \( 6y^2-4xy-20y+x^2-2x-29 \)

[img]h ttp://www.permucode.com/maxima/wxm_ll.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_lc.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_lr.gif[/img]


-------------------------
求\( x^2-4xy+6y^2-2x-20y=29 \)的正整數解。
(91高中數學能力競賽 台中區複賽試題(二))
http://www.math.nuk.edu.tw/senpengeu/HighSchool/2003_Taiwan_High_Taichung_02.pdf


(%i1) x^2-4*x*y+6*y^2-2*x-20*y-29
(%o1) \( 6y^2-4xy-20y+x^2-2x-29 \)

先整理成x的方程式
(%i2) collectterms(%o1,x);
(%o2) \( 6y^2-20y+x(-4y-2)+x^2-29 \)

(%i3) a:coeff(%o1,x,2);b:coeff(%o1,x,1);c:coeff(%o1,x,0);
(%o3) 1
(%o4) \( -4y-2 \)
(%o5) \( 6y^2-20y-29 \)

求x的判別式
(%i6) b^2-4*a*c;
(%o6) \( (-4y-2)^2-4(6y^2-20y-29) \)

或者用poly_discriminant得判別式
(%i7) poly_discriminant(%o1,x);
(%o7) \( -8y^2+96y+120 \)

(%i8) load("solve_rat_ineq.mac");
(%o8) C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.19.2/share/contrib/solve_rat_ineq.mac

解出y的範圍
(%i9) solve_rat_ineq(%o6>=0);
(%o9) \( [ [y\ge 6-\sqrt{51},y\le \sqrt{51}+6] ] \)

(%i10) float(%[1]);
(%o10) \( [ y \ge -1.14142842854285,y \le 13.14142842854285 ] \)

(%i11)
solution:[]$
for valy:-1 thru 13 do           /*y值從-1到13一個個檢驗*/
  (fx:ev(%o1,y:valy),           /*y代回原方程式*/
   for x in solve(fx,x) do      /*對x解方程式*/
     (valx:rhs(x),
      if numberp(valx)=true then/*若x是整數,就放到solution*/
        solution:append(solution,[[valx,valy]])
     )
  )$
print(solution);

(%o13) \( [ [-3,-1],[1,-1],[21,5],[1,5],[25,7],[5,7],[25,13],[29,13] ] \)

(%i14) load(draw);
(%o14) C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.19.2/share/draw/draw.lisp

將圓錐曲線和8個點畫出來
(%i15)
draw2d(xtics =1,   /*x軸的間隔為1*/
       ytics = 1,  /*y軸的間隔為1*/
       grid = true,/*顯示格線*/
       /*畫出圓錐曲線*/
       implicit(%o1=0,x,-5,31,y,-2,15),
       point_type = 7,
       point_size = 1,
       points(solution)/*畫出整數點座標*/
      )$




[ 本帖最後由 bugmens 於 2013-4-24 05:10 PM 編輯 ]
作者: bugmens    時間: 2009-12-3 22:17

已知\( x,y,z \)均為實數,且\( 2^x+3^y+5^z=7 \),\( 2^{x-1}+3^y+5^{z+1}=11 \),
若\( t=2^{x+1}+3^y+5^{z-1} \),試求t的範圍。(98高雄市聯招)
感謝站長提供解法 https://math.pro/db/thread-797-1-2.html


(%i1) [2^x+3^y+5^z=7,2^(x-1)+3^y+5^(z+1)=11,2^(x+1)+3^y+5^(z-1)=t];
(%o1) \( [5^z+3^y+2^x=7,5^{z+1}+3^y+2^{x-1}=11,5^{z-1}+3^y+2^{x+1}=t] \)

令a=2^x,b=3^y,c=5^z
(%i2) scsimp(%,a=2^x,b=3^y,c=5^z);
(%o2) \( \displaystyle [c+b+a=7,5c+b+\frac{a}{2}=11,\frac{c}{5}+b+2a=t] \)

計算a+b+c=7,a/2+b+5c=11的參數解
(%i3) solve([%[1],%[2]],[a,b,c]);
(%o3) \( [ [a=8%r1-8,b=15-9%r1,c=%r1] ] \)

a,b,c都是正數
(%i4) map (lambda ([x], rhs(x)>0), %[1]);
(%o4) \( [8%r1-8>0,15-9%r1>0,%r1>0] \)

(%i5) load(fourier_elim);
(%o5) C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.19.2/share/contrib/fourier_elim/fourier_elim.lisp

從a>0,b>0,c>0解出%r1的範圍
(%i6) fourier_elim(%o4,[%r1]);
(%o6) \( \displaystyle [1<%r1,%r1<\frac{5}{3}] \)

將a=8%r1-8,c=15-9%r1,c=%r1代回2a+b+c/5=t
(%i7) ev(%o2[3],%o3[1]);
(%o7) \( \displaystyle 2(8%r1-8)-\frac{44%r1}{5}+15=t \)

%r1用t表示
(%i8) solve(%,[%r1]);
(%o8) \( \displaystyle [%r1=\frac{5t+5}{36}] \)

(%i9) ev(%o6,%o8[1]);
(%o9) \( \displaystyle [1<\frac{5t+5}{36},\frac{5t+5}{36}<\frac{5}{3}] \)

再解出t的範圍
(%i10) fourier_elim(%,[t]);
(%o10) \( \displaystyle [\frac{31}{5}<t,t<11] \)



[ 本帖最後由 bugmens 於 2009-12-3 10:21 PM 編輯 ]
作者: bugmens    時間: 2010-1-27 23:28

給定坐標平面上的一錐線C:\( 5x^2-6xy+5y^2-16=0 \)。
(1)若直線L:\( x=3+\alpha t \),\( y=1+\beta t \)(\( t \in R \))與錐線C相切,試求斜率\( \displaystyle \frac{\beta}{\alpha} \)的所有可能值。(10分)
(2)若過點\( T(u,v) \)有一對垂直線與錐線C都相切,試證:\( u^2+v^2-10=0 \)。(10分)
(95台灣師大在職專班)

以下是第1小題

(%i1) 5*x^2-6*x*y+5*y^2-16;
(%o1) \( 5y^2-6xy+5x^2-16 \)

將x=3+αt,y=1+βt代入錐線C
(%i2) ev(%,[x=3+%alpha*t,y=1+%beta*t]);
(%o2) \( 5(\beta t+1)^2-6(\alpha t+3)(\beta t+1)+5(\alpha t+3)^2-16 \)

展開後重新整理成t的方程式
(%i3) collectterms(expand(%),t);
(%o3) \( (5 \beta^2-6 \alpha \beta+5 \alpha^2)t^2+(24 \alpha-8 \beta)t+16 \)

取出各項的係數
(%i4)
a:coeff(%o3,t,2);
b:coeff(%o3,t,1);
c:coeff(%o3,t,0);

(%o4) \( 5\beta^2-6\alpha \beta+5 \alpha^2 \)
(%o5) \( 24\alpha-8 \beta \)
(%o6) \( 16 \)

因為直線L和錐線C相切,故判別式為0
(%i7) b^2-4*a*c=0;expand(%);
(%o7) \( (24 \alpha-8 \beta)^2-64(5 \beta^2-6 \alpha \beta+5 \alpha^2)=0 \)
(%o8) \( 256\alpha^2-256 \beta^2=0 \)

得到的兩個答案
(%i9) solve(%,%beta);  %/%alpha;
(%o9) \( [\beta=-\alpha,\beta=\alpha] \)
(%o10) \( \displaystyle [\frac{\beta}{\alpha}=-1,\frac{\beta}{\alpha}=1] \)






第2小題

(%i1) 5*x^2-6*x*y+5*y^2-16;
(%o1) \( 5y^2-6xy+5x^2-16 \)

假設切線為y=mx+k,代入錐線C
(%i2) y=m*x+k;  ev(%o1,%);
(%o2) \( y=mx+k \)
(%o3) \( 5(mx+k)^2+5x^2-6x(mx+k)-16 \)

展開後重新整理成x的方程式
(%i4) collectterms(expand(%),x);
(%o4) \( (5m^2-6m+5)x^2+(10km-6k)x+5k^2-16 \)

取出各項係數
(%i4)
a:coeff(%o4,x,2);
b:coeff(%o4,x,1);
c:coeff(%o4,x,0);

(%o5) \( 5m^2-6m+5 \)
(%o6) \( 10km-6k \)
(%o7) \( 5k^2-16 \)

因為這對垂直線和錐線C相切,故判別式為0
(%i8) b^2-4*a*c;  expand(%);
(%o8) \( (10km-6k)^2-4(5k^2-16)(5m^2-6m+5) \)
(%o9) \( 320m^2-384m-64k^2+320 \)

又因為兩切線垂直,從根與係數的關係可知c/a=-1
(%i10) coeff(%o9,m,0)/coeff(%o9,m,2)=-1;
(%o10) \( \displaystyle \frac{320-64k^2}{320}=-1 \)

解出k,得到兩切線
(%i11) solve(%,[k]);  map(lambda([t],ev(%o2,t)),%);
(%o11) \( [k=-\sqrt{10},k=\sqrt{10}] \)
(%o12) \( [y=mx-\sqrt{10},y=mx+\sqrt{10}] \)

T(u,v)在兩切線上,代入直線方程式
(%i13) ev(%,[x=u,y=v]);
(%o13) \( [v=mu-\sqrt{10},v=mu+\sqrt{10}] \)

又兩切線互相垂直,故斜率相乘為-1
(%i14) 
map(lambda([t],solve(t,[m])),%);
rhs(%[1][1])*rhs(%[2][1])=-1;

(%o14) \( \displaystyle [ [m=\frac{v+\sqrt{10}}{u}],[m=\frac{v-\sqrt{10}}{u}] ] \)
(%o15) \( \displaystyle \frac{(v-\sqrt{10})(v+\sqrt{10})}{u^2}=-1 \)

化簡後得到答案
(%i16) ratsimp(%*u^2+u^2);
(%o16) \( v^2+u^2-10=0 \)



[ 本帖最後由 bugmens 於 2010-1-28 12:14 AM 編輯 ]
作者: bugmens    時間: 2010-2-10 12:26

求\( x^2+2y^2=4 \)與\( y^2=4\sqrt{2}x \)的公切線方程式?
https://math.pro/db/thread-903-1-1.html


假設切線為y=mx+b
(%i1) y=m*x+b;
(%o1) \( y=mx+b \)

將y=mx+b代入x^2+2y^2=4
(%i2) ev(x^2+2*y^2-4,%o1);
(%o2) \( 2(mx+b)^2+x^2-4 \)

展開後重新整理成x的方程式
(%i3) collectterms(expand(%),x);
(%o3) \( (2m^2+1)x^2+4bmx+2b^2-4 \)

因為直線和橢圓相切,故判別式為0
(%i4) poly_discriminant(%,x)=0;
(%o4) \( 32m^2-8b^2+16=0 \)

將y=mx+b代入y^2=4√2x
(%i5) ev(y^2-4*sqrt(2)*x,%o1);
(%o5) \( (mx+b)^2-2^{5/2}x \)

展開後重新整理成x的方程式
(%i6) collectterms(expand(%),x);
(%o6) \( m^2x^2+(2bm-2^{5/2})x+b^2 \)

因為直線和拋物線相切,故判別式為0
(%i7) poly_discriminant(%,x)=0;
(%o7) \( 32-2^{9/2}bm=0 \)


從(%o4) 32m^2-8b^2+16=0
 (%o7) 32-2^(9/2)*bm=0
解出m,b

(%i8) solve([%o4,%o7],[m,b]);
(%o8) \( \displaystyle [ [m=-\frac{1}{\sqrt{2}},b=-2],[m=\frac{1}{\sqrt{2}},b=2],[m=-%i,b=\sqrt{2}%i],[m=%i,b=-\sqrt{2}%i] ] \)

得到兩條切線方程式
(%i9) 
ev(%o1,%o8[1]);
ev(%o1,%o8[2]);

(%o9) \( \displaystyle y=-\frac{x}{\sqrt{2}}-2 \)
(%o10) \( \displaystyle y=\frac{x}{\sqrt{2}}+2 \)



[ 本帖最後由 bugmens 於 2010-2-10 12:30 PM 編輯 ]
作者: bugmens    時間: 2010-3-14 22:53

求\( 5x^2-6xy+5y^2-4x-4y+5 \)的最小值,此時x=?,y=?

maxima沒有內建的配方法指令
參考Barton Willis所寫的配方法
http://www.math.utexas.edu/pipermail/maxima/2007/008787.html

(%i1) 
sfactor(p,x) := block([n, cf, s, d],
  p : expand(p),
  n : hipow(p,x),
  if oddp(n) or n = 0 then p else (
   cf : coeff(p,x,n),
   s : x^(n/2),
   d : expand(cf * s^2 - p),
   while hipow(d,x) > 0 do (
     d : expand(first(divide(cf * s^2 - p, 2 * cf * s))),
     s : s - d),
   cf * s^2 + sfactor(p - cf * s^2,x)))$


(%i2) 5*x^2-6*x*y+5*y^2-4*x-4*y+5
(%o2) \( 5y^2-6xy-4y+5x^2-4x+5 \)

先對y配方法
(%i3) sfactor(%,y);
(%o3) \( \displaystyle 5(y-\frac{3x}{5}-\frac{2}{5})^2+\frac{16x^2}{5}-\frac{32x}{5}+\frac{21}{5} \)

再對x配方法
(%i4) part(%,1)+sfactor(rest(%,1),x);
(%o4) \( \displaystyle 5(y-\frac{3x}{5}-\frac{2}{5})^2+\frac{16(x-1)^2}{5}+1 \)

當y-3x/5-2/5=0,x-1=0時有最小值
(%i5) solve([part(%,1),part(%,2)],[x,y]);
(%o5) \( [ [x=1,y=1] ] \)


當x=1,y=1時有最小值1


或者題目太複雜了,改用偏微分解題
Find the minimum value of \( 2x^2+2y^2+5z^2-2xy-4yz-4x-2z+15 \) for real numbers x, y,z.
USA Stanford Mathematics Tournament 2006
http://www.artofproblemsolving.c ... d=166&year=2006

(%i1) 2*x^2+2*y^2+5*z^2-2*x*y-4*y*z-4*x-2*z+15;
(%o1) \( 5z^2-4yz-2z+2y^2-2xy+2x^2-4x+15 \)

分別對x,y,z偏微分
(%i2) 
diff(%o1,x,1)=0;
diff(%o1,y,1)=0;
diff(%o1,z,1)=0;

(%o2) \( -2y+4x-4=0 \)
(%o3) \( -4z+4y-2x=0 \)
(%o4) \( 10z-4y-2=0 \)

解出x,y,z
(%i5) solve([%o2,%o3,%o4],[x,y,z]);
(%o5) \( [ [x=2,y=2,z=1] ] \)

x,y,z代回原式得最小值
(%i6) ev(%o1,%o5[1]);
(%o6) \( 10 \)


當x=2,y=2,z=1時有最小值10

[ 本帖最後由 bugmens 於 2013-4-27 09:15 PM 編輯 ]
作者: bugmens    時間: 2010-8-28 10:38

若\( A=\Bigg[\; \matrix{2 & -2 \cr -3 & 1} \Bigg]\; \),試利用矩陣的對角線化方法求\( A^n \),其中n為自然數。
(99明倫高中,https://math.pro/db/thread-959-1-3.html)

若\( A=\Bigg[\; \matrix{1 & 1 \cr 2 & 0} \Bigg]\; \),求\( A^{50} \)。
(99國立清水高中,https://math.pro/db/thread-1017-1-1.html)


定義A矩陣
(%i1) A:matrix([2,-2],[-3,1]);
(%o1) \( \Bigg[\; \matrix{2 & -2 \cr -3 & 1} \Bigg]\; \)

定義2階單位矩陣
(%i2) I: ident(2);
(%o2) \( \Bigg[\; \matrix{1 & 0 \cr 0 & 1} \Bigg]\; \)

解特徵方程式
(%i3) determinant(A-x*I)=0;solve(%,x);
(%o3) \( (1-x)(2-x)-6=0 \)
(%o4) \( [\ x=4,x=-1 ]\ \)

第一個特徵向量
(%i5) A-rhs(%o4[1])*I;
(%o5) \( \Bigg[\; \matrix{-2 & -2 \cr -3 & -3} \Bigg]\; \)

(%i6) transpose(matrix([%o5[1][2],-%o5[1][1]]));
(%o6) \( \Bigg[\; \matrix{-2 \cr 2} \Bigg]\; \)

第二個特徵向量
(%i7) A-rhs(%o4[2])*I;
(%o7) \( \Bigg[\; \matrix{3 & -2 \cr -3 & 2} \Bigg]\; \)

(%i8) transpose(matrix([%o7[1][2],-%o7[1][1]]));
(%o8) \( \Bigg[\; \matrix{-2 \cr -3} \Bigg]\; \)

定義特徵矩陣為P
(%i9) P:addcol(%o6,%o8);
(%o9) \( \Bigg[\; \matrix{-2 & -2 \cr 2 & -3} \Bigg]\; \)

P的反矩陣
(%i10) invP:invert(P);
(%o9) \( \displaystyle \Bigg[\; \matrix{-\frac{3}{10} & \frac{1}{5} \cr -\frac{1}{5} & -\frac{1}{5}} \Bigg]\; \)

注意:矩陣乘法用.而不是*
(%i11) D:invP.A.P;
(%o11) \( \Bigg[\; \matrix{4 & 0 \cr 0 & -1} \Bigg]\; \)

答案
(%i12) P.D^n.invP;
(%o12) \( \displaystyle \left[ \matrix{\displaystyle \frac{3 \cdot 4^n}{5}+\frac{2 \cdot (-1)^n}{5} & \frac{2 \cdot (-1)^n}{5}-\frac{2 \cdot 4^n}{5} \cr \frac{3 \cdot (-1)^n}{5}-\frac{3 \cdot 4^n}{5} & \frac{2 \cdot 4^n}{5}+\frac{3 \cdot (-1)^n}{5}} \right] \)

或是載入linearalgebra套件
(%i13) load(linearalgebra);
(%o13) C:/PROGRA~1/MAXIMA~1.1/share/maxima/5.22.1/share/linearalgebra/linearalgebra.mac

直接呼叫matrixfun求出答案
(%i14) matrixfun(lambda([x],x^n),A);
(%o14) \( \left[ \matrix{\displaystyle \frac{3 \cdot 4^n+2 \cdot (-1)^n}{5} & -\frac{2 \cdot 4^n-2 \cdot (-1)^n}{5} \cr -\frac{3 \cdot 4^n-3 \cdot (-1)^n}{5} & \frac{2 \cdot 4^n+3 \cdot (-1)^n}{5}} \right] \)


-------------------------

101.11.10補充
\( A=\Bigg[\; \matrix{-1 & -9 \cr 1 & -7} \Bigg]\; \),\( A=PDP^{-1} \),且\( \displaystyle P=\Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \),求\( A^n= \)?(答案以n表示,\( n \in N \))
(101松山工農,https://math.pro/db/thread-1482-1-3.html)


載入linearalgebra.mac才能使用matrixfun指令
(%i1) load("linearalgebra.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/linearalgebra/linearalgebra.mac

定義A矩陣
(%i2) A:matrix([-1,-9],[1,-7]);
(%o2) \( \displaystyle \Bigg[\; \matrix{-1 & -9 \cr 1 & -7} \Bigg]\; \)

定義2階單位矩陣
(%i3) I:ident(2);
(%o3) \( \displaystyle \Bigg[\; \matrix{1 & 0 \cr 0 & 1} \Bigg]\; \)

解特徵方程式,但特徵值重根
(%i4) 
determinant(A-x*I)=0;
solve(%,x);

(%o4) \( (-x-7)(-x-1)+9=0 \)
(%o5) \( [ x=-4 ] \)

求第一個特徵向量
(%i6) (A-rhs(%o5[1])*I).matrix([x],[y])=matrix([0],[0]);
(%o6) \( \displaystyle \Bigg[\; \matrix{3x-9y \cr x-3y} \Bigg]\;=\Bigg[\; \matrix{0 \cr 0} \Bigg]\; \)

(%i7) 
lhs(%)[1][1]=rhs(%)[1][1];
solve(%,[x,y]);
ev(%,%r1=1);
ev(matrix([x],[y]),%[1]);

(%o7) \( 3x-9y=0 \)
(%o8) \( [ [x=3%r1,y=%r1] ] \)
(%o9) \( [ [x=3,y=1] ] \)
(%o10) \( \displaystyle \Bigg[\; \matrix{3 \cr 1} \Bigg]\; \)

求第二個特徵向量
(%i11) (A-rhs(%o5[1])*I).matrix([x],[y])=%;
(%o11) \( \displaystyle \Bigg[\; \matrix{3x-9y \cr x-3y} \Bigg]\;=\Bigg[\; \matrix{3 \cr 1} \Bigg]\; \)

(%i12) 
lhs(%)[1][1]=rhs(%)[1][1];
solve(%,[x,y]);
ev(%,%r2=0);
ev(matrix([x],[y]),%[1]);

(%o12) \( 3x-9y=3 \)
(%o13) \( [ [x=3%r2+1,y=%r2] ] \)
(%o14) \( [ [x=1,y=0] ] \)
(%o15) \( \displaystyle \Bigg[\; \matrix{1 \cr 0} \Bigg]\; \)

兩個特徵向量形成P矩陣
(%i16) P:addcol(%o10,%o15);
(%o16) \( \displaystyle \Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \)

求P的反矩陣
(%i17) inv_P:invert(P);
(%o17) \( \displaystyle \Bigg[\; \matrix{0 & 1 \cr 1 & -3} \Bigg]\; \)

D=P^-1.A.P
矩陣乘法用的是.不是*

(%i18) D:inv_P.A.P;
(%o18) \( \displaystyle \Bigg[\; \matrix{-4 & 1 \cr 0 & -4} \Bigg]\; \)

計算D的n次方
因為這裡的D矩陣不是對角矩陣,無法直接用D^n計算矩陣n次方,所以改用matrixfun來計算

(%i19) matrixfun(lambda([x],x^n),D);
(%o19) \( \displaystyle \Bigg[\; \matrix{(-4)^n & n(-4)^{n-1} \cr 0 & (-4)^n} \Bigg]\; \)

計算A^n=P.D^n.P^-1
(%i20) P.%.inv_P;
(%o20) \( \displaystyle \Bigg[\; \matrix{(-4)^n+3n(-4)^{n-1} & 3((-4)^n-3n(-4)^{n-1})-3(-4)^n \cr n(-4)^{n-1} & (-4)^n-3n(-4)^{n-1}} \Bigg]\; \)

A^n簡化後得到答案
(%i21) ratsimp(%);
(%o21) \( \displaystyle \Bigg[\; \matrix{(3n-4)(-4)^{n-1} & -9n(-4)^{n-1} \cr n(-4)^{n-1} & -(3n+4)(-4)^{n-1}} \Bigg]\; \)

就和matrixfun所計算A^n的結果相同
(%i22) matrixfun(lambda([x],x^n),A);
(%o22) \( \displaystyle \Bigg[\; \matrix{(3n-4)(-4)^{n-1} & -9n(-4)^{n-1} \cr n(-4)^{n-1} & -(3n+4)(-4)^{n-1}} \Bigg]\; \)


參考資料
7.THE JORDAN CANONICAL FORM
https://math.pro/db/attachment.p ... 87&t=1407797768



利用diag.mac所提供的指令來計算矩陣n次方


要載入diag.mac才能使用jordan,ModeMatrix,dispJordan指令
(%i1) load("diag.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/contrib/diag.mac

定義A矩陣
(%i2) A:matrix([-1,-9],[1,-7]);
(%o2) \( \displaystyle \Bigg[\; \matrix{-1 & -9 \cr 1 & -7} \Bigg]\; \)

計算A的特徵根-4,代數重數2(重根)
(%i3) EigenValue:jordan(A);
(%o3) \( [ [-4,2] ] \)

求得P矩陣
(%i4) P:ModeMatrix(A,EigenValue);
(%o4) \( \displaystyle \Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \)

P的反矩陣
(%i5) inv_P:invert(P);
(%o5) \( \displaystyle \Bigg[\; \matrix{0 & 1 \cr 1 & -3} \Bigg]\; \)

求得D矩陣
(%i6) D:dispJordan(EigenValue);
(%o6) \( \displaystyle \Bigg[\; \matrix{-4 & 1 \cr 0 & -4} \Bigg]\; \)

計算D的n次方
(%i7) matrixfun(lambda([x],x^n),D);
(%o7) \( \displaystyle \Bigg[\; \matrix{(-4)^n & n(-4)^{n-1} \cr 0 & (-4)^n} \Bigg]\; \)

計算A^n=P.D^n.P^-1
(%i8) P.%.inv_P;
(%o8) \( \displaystyle \Bigg[\; \matrix{(-4)^n+3n(-4)^{n-1} & 3((-4)^n-3n(-4)^{n-1})-3(-4)^n \cr n(-4)^{n-1} & (-4)^n-3n(-4)^{n-1}} \Bigg]\; \)

A^n簡化後得到答案
(%i9) ratsimp(%);
(%o9) \( \Bigg[\; \matrix{\displaystyle (3n-4)(-4)^{n-1} & -9n(-4)^{n-1} \cr n(-4)^{n-1} & -(3n+4)(-4)^{n-1}} \Bigg]\; \)



我另外找了兩題也是特徵根相同的題目讓各位練習,因為特徵根是1所以會比較簡單
\( A=\displaystyle \Bigg[\; \matrix{-1 & 4 \cr -1 & 3} \Bigg]\; \),則\( A^n= \)   
[答案]
\( \displaystyle P=\Bigg[\; \matrix{-2 & 1 \cr -1 & 0} \Bigg]\; \),\( \displaystyle P^{-1}=\Bigg[\; \matrix{0 & -1 \cr 1 & -2} \Bigg]\; \)
\( \displaystyle D=\Bigg[\; \matrix{1 & 1 \cr 0 & 1} \Bigg]\; \),\( \displaystyle D^n=\Bigg[\; \matrix{1 & n \cr 0 & 1} \Bigg]\; \)
\( \displaystyle A^n=P.D^n.P^{-1}=\Bigg[\; \matrix{1-2n & 4n \cr -n & 2n+1} \Bigg]\; \)


\( A=\displaystyle \Bigg[\; \matrix{4 & -9 \cr 1 & -2} \Bigg]\; \),則\( A^n= \)   
[答案]
\( \displaystyle P=\Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \),\( \displaystyle P^{-1}=\Bigg[\; \matrix{0 & 1 \cr 1 & -3} \Bigg]\; \)
\( \displaystyle D=\Bigg[\; \matrix{1 & 1 \cr 0 & 1} \Bigg]\; \),\( \displaystyle D^n=\Bigg[\; \matrix{1 & n \cr 0 & 1} \Bigg]\; \)
\( \displaystyle A^n=P.D^n.P^{-1}=\Bigg[\; \matrix{3n+1 & -9n \cr n & 1-3n} \Bigg]\; \)


103.8.11補充
設\( I=\left[ \matrix{1 & 0 \cr 0 & 1} \right] \),\( N=\left[ \matrix{1 & 1 \cr -1 & -1} \right] \),求\( (2I-N)^{103}= \)?
(103南大附中,https://math.pro/db/viewthread.php?tid=1942&page=4#pid11839)
有完整的計算式子

[ 本帖最後由 bugmens 於 2014-8-12 07:05 AM 編輯 ]
作者: bugmens    時間: 2010-11-20 22:19

2009用2個或2個以上連續的整數表示,有幾種表示法?
https://math.pro/db/thread-827-1-1.html


從m開始加n個數總和為2009
(%i1) sum(m+(k-1)*1,k,1,n)=2009;
(%o1) \( \displaystyle \sum_{k=1}^{n}m+k-1=2009 \)

載入simplify_sum套件,計算出總和
(%i2) load("simplify_sum");
(%o2) C:/PROGRA~1/MAXIMA~1.1/share/maxima/5.22.1/share/contrib/solve_rec/simplify_sum.mac

(%i3) simplify_sum(%o1);
(%o3) \( \displaystyle \frac{n^2+n}{2}+mn-n=2009 \)

(%i4) ratsimp(%*2);
(%o4) \( n^2+(2m-1)n=4018 \)

(%i5) facout(n,lhs(%))=rhs(%);
(%o5) \( n(n+2m-1)=4018 \)

考慮4018的因數分解
(%i6) d:divisors(rhs(%));
(%o6) {1,2,7,14,41,49,82,98,287,574,2009,4018}

計算出首項和項數
(%i7) 
for divisor in d do
  (fx:ev(%o5,n=divisor),
   solution:solve(fx,[m]),
   if integerp(rhs(solution[1]))=true then
     print("(",rhs(solution[1]),",",divisor,")")
  );

(%o7)
(2009,1)
(1004,2)
(284,7)
(137,14)
(29,41)
(17,49)
(-16,82)
(-28,98)
(-136,287)
(-283,574)
(-1003,2009)
(-2008,4018)
扣除n=1不合的情況,共有11種方法

[ 本帖最後由 bugmens 於 2014-8-12 07:02 AM 編輯 ]
作者: bugmens    時間: 2010-12-8 21:01

驗證\( \displaystyle \root 3 \of {cos \frac{2 \pi}{9}}+\root 3 \of{cos \frac{4 \pi}{9}}+\root 3 \of{cos \frac{8 \pi}{9}}=\root 3 \of{\frac{3}{2}\root 3 \of 9-3} \)

驗證\( \displaystyle \root 3 \of{cos \frac{2 \pi}{9}cos \frac{4 \pi}{9}}+\root 3 \of{cos \frac{4 \pi}{9}cos \frac{8 \pi}{9}}+\root 3 \of{cos \frac{8 \pi}{9}cos \frac{2 \pi}{9}}=\root 3 \of{\frac{3}{4}(1-\root 3 \of 9)} \)

https://math.pro/db/thread-1041-1-1.html



(%i1)
a:cos(2*%pi/9);
b:cos(4*%pi/9);
c:cos(8*%pi/9);
(%o1) \( \displaystyle cos(\frac{2 \pi}{9}) \)
(%o2) \( \displaystyle cos(\frac{4 \pi}{9}) \)
(%o3) \( \displaystyle cos(\frac{8 \pi}{9}) \)

(%i4)
(a*b)^(1/3)+(b*c)^(1/3)+(c*a)^(1/3);
float(%);
(%o4) \( \displaystyle cos(\frac{4 \pi}{9})^{1/3}cos(\frac{8 \pi}{9})^{1/3}+cos(\frac{2 \pi}{9})^{1/3}cos(\frac{8 \pi}{9})^{1/3}+cos(\frac{2 \pi}{9})^{1/3}cos(\frac{4 \pi}{9})^{1/3} \)
(%o5) -0.93219386761704

(%i6) 
(3/4*(1-9^(1/3)))^(1/3);
float(%);

(%o6) \( \displaystyle \frac{3^{1/3}(1-9^{1/3})^{1/3}}{4^{1/3}} \)
(%o7) -0.93219386761704

(%i8) 
a^(1/3)+b^(1/3)+c^(1/3);
float(%);

(%o8) \( \displaystyle cos(\frac{8 \pi}{9})^{1/3}+cos(\frac{4 \pi}{9})^{1/3}+cos(\frac{2 \pi}{9})^{1/3} \)
(%o9) 0.49341462591879

(%i10) 
(3/2*9^(1/3)-3)^(1/3);
float(%);


(%o10) \( \displaystyle (\frac{3 9^{1/3}}{2}-3)^{1/3} \)
(%o11) 0.49341462591879


作者: bugmens    時間: 2011-3-19 20:14

設\( \displaystyle f(z)=\frac{z+a}{z+b} \)且\( g(z)=f(f(z)) \),其中a及b為複數。若\( |a|=1 \)且對所有使得\( g(g(z)) \)有定義的z都滿足\( g(g(z))=z \),則最大可能的\( |b| \)值與最小可能的\( |b| \)值之差是多少?(A) 0  (B) \( \sqrt{2}-1 \)  (C) \( \sqrt{3}-1 \)  (D) 1  (E) 2
(2011AMC12 https://math.pro/db/thread-1080-1-1.html)



定義f(z)函數
(%i1) f(z):=(z+a)/(z+b);
(%o1) \( \displaystyle f(z):=\frac{z+a}{z+b} \)

定義g(z)函數
(%i2) g(z):=f(f(z));
(%o2) g(z):=f(f(z))

(%i3) g(g(z));
(%o3) 

計算g(g(z))=z化簡後的結果
(%i4) ratsimp(%)=z;
(%o4) \( \displaystyle \frac{(ab^2+2ab+a^2+3a+1)z+ab^3+ab^2+(2a^2+a)b+2a^2+a}{(b^3+b^2+(2a+1)b+2a+1)z+b^4+3ab^2+2ab+a^2+a}=z \)

(%i5) num(lhs(%o4))=rat(denom(lhs(%o4))*rhs(%o4));
(%o5) \( (ab^2+2ab+a^2+3a+1)z+ab^3+ab^2+(2a^2+a)b+2a^2+a=(b^3+b^2+(2a+1)b+2a+1)z^2+(b^4+3ab^2+2ab+a^2+a)z \)

(%i6) rhs(%)-lhs(%);
(%o6) \( (b^3+b^2+(2a+1)b+2a+1)z^2+(b^4+2ab^2-2a-1)z-ab^3-ab^2+(-2a^2-a)b-2a^2-a \)

(...)z^2+(...)z+(...)=0
不管複數z是多少代入的結果都是0
可知原式是恆等式,各項係數為0

(%i7) 
factor(coeff(%o6,z,2))=0;
factor(coeff(%o6,z,1))=0;
factor(coeff(%o6,z,0))=0;

(%o7) \( (b+1)(b^2+2a+1)=0 \)
(%o8) \( (b-1)(b+1)(b^2+2a+1)=0 \)
(%o9) \( -a(b+1)(b^2+2a+1)=0 \)

從三個式子解出b
(%i10) solve([%o7,%o8,%o9],b);
(%o10) \( [ [b=\sqrt{-2a-1}],[b=-\sqrt{-2a-1}],[b=-1] ] \)

因為|a|=1,令a=cos(t)+i*sin(t)代入,求b的範圍
(%i11) ev(%o10[1][1],a=cos(t)+%i*sin(t));
(%o11) \( b=\sqrt{-2(\%i  sin(t)+cos(t))-1} \)

計算複數b的絕對值
(%i12) trigsimp(cabs(%));
(%o12) \( |b|=(4 cos(t)+5)^{1/4} \)

當t=0時|b|有最大值√3
(%i13) ev(%o12,t=0);
(%o13) \( |b|=\sqrt{3} \)

當t=π時|b|有最小值1
(%i14) ev(%o12,t=%pi);
(%o14) \( |b|=1 \)



[ 本帖最後由 bugmens 於 2011-3-19 08:21 PM 編輯 ]
作者: bugmens    時間: 2011-7-11 15:03

尤拉在1742年時,將白努力所舉的四次多項式\( f(x) \)分解為二次多項式
\( \displaystyle x^2-\Bigg(\; 2+\sqrt{4+2 \sqrt{7}} \Bigg)\; x+\Bigg(\; 1+\sqrt{4+2 \sqrt{7}}+\sqrt{7} \Bigg)\; \)
與二次多項式
\( \displaystyle x^2-\Bigg(\; 2-\sqrt{4+2 \sqrt{7}} \Bigg)\; x+\Bigg(\; 1-\sqrt{4+2 \sqrt{7}}+\sqrt{7} \Bigg)\; \)
的乘積。白努利所舉的多項式\( f(x) \)=(以降次排列表示)
(100華江高中二招,https://math.pro/db/thread-1177-1-1.html)



用公式解得方程式的兩根
(%i1) 
x^2-(2+sqrt(4+2*sqrt(7)))*x+(1+sqrt(4+2*sqrt(7))+sqrt(7))=0;
solve(%,x);

(%o1) \( x^2-(\sqrt{2 \sqrt{7}+4}+2)x+\sqrt{2 \sqrt{7}+4}+\sqrt{7}+1=0 \)
(%o2)
[ \( \displaystyle x=\frac{-\sqrt{2}\sqrt{\sqrt{7}-2}%i+\sqrt{2\sqrt{7}+4}+2}{2} \),
\( \displaystyle x=\frac{\sqrt{2}\sqrt{\sqrt{7}-2}%i+\sqrt{2\sqrt{7}+4}+2}{2} \) ]

取第一個根來計算
(%i3) %[1]
(%o3) \( \displaystyle x=\frac{-\sqrt{2}\sqrt{\sqrt{7}-2}%i+\sqrt{2\sqrt{7}+4}+2}{2} \)

兩邊都減1
(%i4) ratsimp(%-1);
(%o4) \( \displaystyle x-1=\frac{\sqrt{2 \sqrt{7}+4}-\sqrt{2}\sqrt{\sqrt{7}-2}%i}{2} \)

兩邊平方
(%i5) ratsimp(%^2);
(%o5) \( \displaystyle x^2-2x+1=-\frac{\sqrt{2}\sqrt{\sqrt{7}-2}\sqrt{2 \sqrt{7}+4}%i-4}{2} \)

rootscontract指令可以將獨立的根號乘在一起
√(x-1)*√(x+1)=√(x^2-1)

(%i6) rootscontract(%);
(%o6) \( \displaystyle x^2-2x+1=-\frac{2 \sqrt{-3}-4}{2} \)

兩邊都減2
(%i7) ratsimp(%-2);
(%o7) \( x^2-2x-1=-\sqrt{3}%i \)

兩邊平方去掉i
(%i8) %^2;
(%o8) \( (x^2-2x-1)^2=-3 \)

得到答案i
(%i9) expand(%+3);
(%o9) \( x^4-4x^3+2x^2+4x+4=0 \)









101.2.10補充一題
\( \displaystyle f(x)=\Bigg[\; x^2-\frac{\sqrt{10+2 \sqrt{5}}+\sqrt{10-2 \sqrt{5}}}{2}x+\sqrt{5} \Bigg]\; \Bigg[\; x^2+\frac{\sqrt{10+2 \sqrt{5}}+\sqrt{10-2 \sqrt{5}}}{2}x+\sqrt{5} \Bigg]\; \)
求乘開後的\( f(x) \)


(%i1) x^2+(sqrt(10+2*sqrt(5))+sqrt(10-2*sqrt(5)))/2*x+sqrt(5);
(%o1) \( x^2+\frac{(\sqrt{2 \sqrt{5}+10}+\sqrt{10-2 \sqrt{5}})x}{2}+\sqrt{5} \)

(%i2) x^2-(sqrt(10+2*sqrt(5))+sqrt(10-2*sqrt(5)))/2*x+sqrt(5);
(%o2) \( x^2-\frac{(\sqrt{2 \sqrt{5}+10}+\sqrt{10-2 \sqrt{5}})x}{2}+\sqrt{5} \)

(%i3) %o1*%o2;
(%o3) \( \displaystyle \Bigg(\; x^2-\frac{(\sqrt{2 \sqrt{5}+10}+\sqrt{10-2 \sqrt{5}})x}{2}+\sqrt{5} \Bigg)\; \Bigg(\; x^2+\frac{(\sqrt{2 \sqrt{5}+10}+\sqrt{10-2 \sqrt{5}})x}{2}+\sqrt{5} \Bigg)\; \)

(%i4) expand(%);
(%o4) \( \displaystyle x^4-\frac{\sqrt{10-2 \sqrt{5}} \sqrt{2 \sqrt{5}+10}x^2}{2}+2 \sqrt{5}x^2-5x^2+5 \)

(%i5) rootscontract(%);
(%o5) \( x^4-5x^2+5 \)



[ 本帖最後由 bugmens 於 2012-2-10 09:49 PM 編輯 ]
作者: bugmens    時間: 2012-5-18 19:53

設\( \displaystyle A=\Bigg[\; \matrix{1 & 4 \cr 3 & 2} \Bigg]\;  \),且X、Y均為二階方陣,滿足\( X+Y=\Bigg[\; \matrix{1 & 0 \cr 0 & 1}\Bigg]\;  \),\( XY=\Bigg[\; \matrix{0 & 0 \cr 0 & 0}\Bigg]\; \),\( aX+bY=A \),其中\( a>b \),a、b為常數,則\( X^n= \)?
(101臺南二中,https://math.pro/db/thread-1335-1-1.html)



(%i1) 
a*X+b*Y=matrix([1,4],[3,2]);
X+Y=matrix([1,0],[0,1]);

(%o1) \( \displaystyle bY+aX=\Bigg[\; \matrix{1 & 4 \cr 3 & 2} \Bigg]\; \)
(%o2) \( \displaystyle Y+X=\Bigg[\; \matrix{1 & 0 \cr 0 & 1} \Bigg]\; \)

solve指令無法解矩陣方程式,只好用加減消去法解出X,Y
(%i3) 
ratsimp((%o1-%o2*a)/(b-a));
ratsimp((-%o1+%o2*b)/(b-a));

(%o3) \( \displaystyle Y=\Bigg[\; \matrix{-\frac{a-1}{b-a} & \frac{4}{b-a} \cr \frac{3}{b-a} & -\frac{a-2}{b-a}} \Bigg]\; \)
(%o4) \( \displaystyle X=\Bigg[\; \matrix{\frac{b-1}{b-a} & -\frac{4}{b-a} \cr -\frac{3}{b-a} & \frac{b-2}{b-a}} \Bigg]\; \)

X.Y相乘為0矩陣
(%i5) rhs(%o4).rhs(%o3)=matrix([0,0],[0,0]);
(%o5) \( \displaystyle \Bigg[\; \matrix{-\frac{(a-1)(b-1)}{(b-a)^2}-\frac{12}{(b-a)^2} & \frac{4(b-1)}{(b-a)^2}+\frac{4(a-2)}{(b-a)^2} \cr \frac{3(b-2)}{(b-a)^2}+\frac{3(a-1)}{(b-a)^2} & -\frac{(a-2)(b-2)}{(b-a)^2}-\frac{12}{(b-a)^2}} \Bigg]\;=\Bigg[\; \matrix{0 & 0 \cr 0 & 0} \Bigg]\; \)

相乘後各元素為0
(%i6) 
lhs(%o5)[1][1]=rhs(%o5)[1][1];
lhs(%o5)[2][1]=rhs(%o5)[2][1];

(%o6) \( \displaystyle -\frac{(a-1)(b-1)}{(b-a)^2}-\frac{12}{(b-a)^2}=0 \)
(%o7) \( \displaystyle \frac{3(b-2)}{(b-a)^2}+\frac{3(a-1)}{(b-a)^2}=0 \)

整理式子
(%i8) 
factor(%o6);
factor(%o7);

(%o8) \( \displaystyle -\frac{ab-b-a+13}{(b-a)^2}=0 \)
(%o9) \( \displaystyle \frac{3(b+a-3)}{(b-a)^2}=0 \)

解出a,b,得到兩解,但第二組不合
(%i10) solve([%o8,%o9],[a,b]);
(%o10) \( [ [a=5,b=-2],[a=-2,b=5] ] \)

將第一組解代回X,Y矩陣
(%i11) 
ev(%o3,%o10[1]);
ev(%o4,%o10[1]);

(%o11) \( \displaystyle Y=\Bigg[\; \matrix{\frac{4}{7} & -\frac{4}{7} \cr -\frac{3}{7} & \frac{3}{7}} \Bigg]\; \)
(%o12) \( \displaystyle X=\Bigg[\; \matrix{\frac{3}{7} & \frac{4}{7} \cr \frac{3}{7} & \frac{4}{7}} \Bigg]\; \)

計算X矩陣的平方會得到自己(X^2=X),所以X的n次方還是自己
(%i13) rhs(%).rhs(%);
(%o13) \( \displaystyle \Bigg[\; \matrix{\frac{3}{7} & \frac{4}{7} \cr \frac{3}{7} & \frac{4}{7}} \Bigg]\; \)



[ 本帖最後由 bugmens 於 2012-5-18 07:54 PM 編輯 ]
作者: bugmens    時間: 2012-8-23 22:33

上學期教到數據分析時,想要修改課本的題目數據讓學生練習
但改了一個數字平均數就變成分數或標準差變成根號,改來改去就是湊不出整數的答案
讓我想到能否用maxima幫忙檢查,於是就花了一些時間寫成程式
回頭想想相關係數、回歸直線應該也能寫成程式,將來要命題時就有很多現成的題目可以用



makelist和random:隨機產生list
mean:從list資料中計算平均數
std:從list資料中計算標準差
integerp:檢查是否為整數

(%i1) 
StandardDeviation(LowerBound,UpperBound,n):=block(
for i:1 thru 1000 do
  (data:makelist(random(UpperBound-LowerBound+1)+LowerBound,n),
   mean:mean(data),
   std:std(data),
   if integerp(mean)=true and integerp(std)=true then
     print(data,"平均數=",mean,"標準差=",std)
  )
)$


StandardDeviation(下界,上界,個數)
(%i2) StandardDeviation(6,15,5);
[5,10,15,15,15] 平均數=12 標準差=4
[6,8,9,10,12] 平均數=9 標準差=2


指令:StandardDeviation(50,100,5);
說明:從50到100的範圍中任意取5筆資料
範例:甲生第一次月考五科成績分別為82,80,54,68,71,則成績的平均數為 71 ,標準差為 10 
其他範例
58,56,59,70,52平均數59,標準差6
83,65,76,77,79平均數76,標準差6
84,90,93,76,72平均數83,標準差8
74,73,67,85,61平均數72,標準差8
94,86,92,98,75平均數89,標準差8
82,67,87,97,77平均數82,標準差10

指令:StandardDeviation(170,190,5);
說明:從170到190的範圍中任意取5筆資料
範例:籃球隊5位先發球員的身高為178,182,181,180,184公分,試求此5人身高的平均數為 181 ,標準差為 2 
其他範例
172,178,175,184,176平均數177標準差4
186,183,180,174,182平均數181標準差4
176,170,174,178,182平均數176標準差4
172,176,178,175,184平均數177標準差4
182,188,176,184,180平均數182標準差4
177,178,190,174,186平均數181標準差6

指令:StandardDeviation(40,80,6);
說明:從40到80的範圍中任意取6筆資料
範例:某高中一年二班其中6位學生的體重為68,62,70,73,67,74公斤,則此6人的平均數為 69 ,標準差為 4 
其他範例
77,65,67,68,61,64平均數67標準差5
52,50,52,53,61,44平均數52標準差5
67,65,73,59,55,59平均數63標準差6
73,55,61,57,66,60平均數62標準差6
41,52,53,53,58,43平均數50標準差6
73,80,65,73,55,74平均數70標準差8
64,60,48,55,66,73平均數61標準差8

指令:StandardDeviation(6,15,5);
說明:從6到15的範圍中任意取5筆資料
範例:甲生的五科學測成績分別為9,6,12,10,8級分,則平均數為 9 ,標準差為 2 
其他範例
11,12,9,13,15平均數12標準差2
10,12,8,11,14平均數11標準差2
13,13,13,8,13平均數12標準差2
11,7,13,10,9平均數10標準差2
14,10,12,8,11平均數11標準差2
10,15,15,15,15平均數14標準差2

[ 本帖最後由 bugmens 於 2012-8-23 10:36 PM 編輯 ]
作者: bugmens    時間: 2012-9-1 17:55

產生分組的資料,並檢驗平均數和標準差是否為整數


(%i1) 
GroupStandardDeviation(LowerBound,Group,n):=block(
for i:1 thru 1000 do
  (datas:create_list([LowerBound+10*j,random(n)+1],j,0,Group-1),
   list:[],
   for data in datas do
     list:append(create_list(data[1],i,1,data[2]),list),
   mean:mean(list),
   std:std(list),
   if integerp(mean)=true and integerp(std)=true then
     print("分組資料",datas,"平均數=",mean,"標準差=",std)
  )
)$


GroupStandardDeviation(第一組的組中點,組數,個數)
(%i2) GroupStandardDeviation(55,5,10);
分組資料[[55,3],[65,1],[75,2],[85,3],[95,1]]平均數=73標準差=14
分組資料[[55,2],[65,9],[75,1],[85,5],[95,3]]平均數=74標準差=13


指令:GroupStandardDeviation(55,5,10);
說明:從第一組組中點55開始,共取5組,每組個數小於10位
範例:某班月考的數學成績統計如下

成績

50~6060~7070~8080~9090~100

人數

18821
求全班的平均數為 72 ,標準差 9 
其他範例:
分組資料[[55,3],[65,1],[75,2],[85,3],[95,1]]平均數73標準差14
分組資料[[55,2],[65,9],[75,1],[85,5],[95,3]]平均數74標準差13
分組資料[[55,1],[65,2],[75,4],[85,8],[95,5]]平均數82標準差11
分組資料[[55,9],[65,5],[75,3],[85,3],[95,4]]平均數70標準差15

指令:GroupStandardDeviation(155,4,15);
說明:從第一組組中點155開始,共取4組,每組個數小於15位
範例:20名學生的身高統計如下:

身高

150~160160~170170~180180~190

人數

5591
求這20名學生的平均身高為 168 ,標準差 9 
其他範例:
分組資料[[155,11],[165,12],[175,15],[185,2]]平均數167標準差9
分組資料[[155,7],[165,9],[175,12],[185,2]]平均數168標準差9
分組資料[[155,3],[165,11],[175,9],[185,2]]平均數169標準差8
分組資料[[155,3],[165,7],[175,9],[185,1]]平均數169標準差8

指令:GroupStandardDeviation(45,5,10);
說明:從第一組組中點45開始,共取5組,每組個數小於10位
範例:有25位學生的體重統計如下:

體重

40~5050~6060~7070~8080~90

人數

65932
其體重的平均數 61 ,標準差 12 
其他範例:
分組資料[[45,2],[55,8],[65,9],[75,10],[85,1]]平均數65標準差10
分組資料[[45,7],[55,3],[65,9],[75,5],[85,1]]平均數61標準差12
分組資料[[45,6],[55,5],[65,5],[75,3],[85,1]]平均數59標準差12
分組資料[[45,6],[55,10],[65,4],[75,3],[85,2]]平均數59標準差12
作者: bugmens    時間: 2012-10-6 19:53

計算相關係數


要先載入descriptive.mac才能使用cov指令
(%i1) load("descriptive.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/descriptive/descriptive.mac

(%i2) 
CorrelationCoefficient(XLowerBound,XUpperBound,YLowerBound,YUpperBound,n):=block(
for i:1 thru 10000 do
  (x:create_list(random(XUpperBound-XLowerBound+1)+XLowerBound,i,1,n),
   y:create_list(random(YUpperBound-YLowerBound+1)+YLowerBound,i,1,n),
   data:matrix(x,y),
   cov:cov(transpose(data)),
   denom:sqrt(cov[1,1]*cov[2,2]),
   if cov[1,2]#0 and cov[1,1]#0 and cov[2,2]#0 and
      integerp(cov[1,1])=true and integerp(cov[2,2])=true and
      integerp(denom)=true then
     (print("資料",data),
      print("第一組 平均",mean(x),"標準差",std(x)),
      print("第二組 平均",mean(y),"標準差",std(y)),
      print("共變數",cov[1,2],"相關係數",cov[1,2]/denom)
     )
  )
)$


CorrelationCoefficient(第一組下界,第一組上界,第二組下界,第二組上界,個數)
(%i3) CorrelationCoefficient(160,175,55,75,5);
資料\( \Bigg[\; \matrix{164 & 165 & 161 & 167 & 163 \cr 61 & 64 & 58 & 62 & 70} \Bigg]\; \)
第一組 平均164標準差2
第二組 平均63標準差4
共變數\( \displaystyle \frac{6}{5} \)相關係數\( \displaystyle \frac{3}{20} \)
資料\( \Bigg[\; \matrix{174 & 166 & 163 & 167 & 165 \cr 72 & 60 & 73 & 74 & 56} \Bigg]\; \)
第一組 平均167標準差\( \sqrt{14} \)
第二組 平均67標準差\( 2\sqrt{14} \)
共變數8相關係數\( \displaystyle \frac{2}{7} \)


指令:CorrelationCoefficient(160,175,55,75,5);
說明:第一組範圍為160~175,第二組範圍為55~75,產生5筆資料
範例:高一某班的5位同學身高與體重的資料如下表所示

身高(公分)

164165161167163

體重(公斤)

6164586270

求身高與體重的相關係數為\( \displaystyle \frac{3}{20} \)。
其他範例:
資料\( \Bigg[\; \matrix{174 & 166 & 163 & 167 & 165 \cr 72 & 60 & 73 & 74 & 56} \Bigg]\; \)
第一組 平均167標準差\( \sqrt{14} \)
第二組 平均67標準差\( 2\sqrt{14} \)
共變數8相關係數\( \displaystyle \frac{2}{7} \)

指令:CorrelationCoefficient(50,80,60,90,5);
說明:第一組範圍50~80,第二組範圍60~90,個數5個
範例:五位同學的英文和數學段考成績如下表:

英文

6871647562

數學

8067767973

則英文和數學的相關係數為\( \frac{6}{55} \)
其他範例:
資料\( \Bigg[\; \matrix{59 & 80 & 56 & 53 & 62 \cr 76 & 82 & 78 & 89 & 70} \Bigg]\; \)
第一組 平均62標準差\( 3\sqrt{10} \)
第二組 平均79標準差\( 2\sqrt{10} \)
共變數\( \displaystyle -\frac{21}{5} \)相關係數\( \displaystyle -\frac{7}{100} \)

資料\( \Bigg[\; \matrix{61 & 62 & 68 & 64 & 55 \cr 68 & 77 & 79 & 60 & 76} \Bigg]\; \)
第一組 平均62標準差\( 3\sqrt{2} \)
第二組 平均72標準差\( 5\sqrt{2} \)
共變數\( \displaystyle -\frac{6}{5} \)相關係數\( \displaystyle -\frac{1}{25} \)
資料\( \Bigg[\; \matrix{52 & 50 & 58 & 54 & 56 \cr 68 & 72 & 76 & 80 & 84} \Bigg]\; \)
第一組 平均54標準差\( 2\sqrt{2} \)
第二組 平均76標準差\( 4\sqrt{2} \)
共變數\( \displaystyle \frac{48}{5} \)相關係數\( \displaystyle \frac{3}{5} \)

但數字太大學生計算時容易出錯,平均一錯後面整個答案都是錯的
以下的數字比較簡單,適合用在平時測驗及期中考試
資料\( \Bigg[\; \matrix{3 & 3 & 1 & 5 \cr 5 & 3 & 3 & 1} \Bigg]\; \)
第一組 平均3標準差\( \sqrt{2} \)
第二組 平均3標準差\( \sqrt{2} \)
共變數\( \displaystyle -1 \)相關係數\( \displaystyle -\frac{1}{2} \)
資料\( \Bigg[\; \matrix{5 & 5 & 5 & 1 \cr 5 & 1 & 1 & 1} \Bigg]\; \)
第一組 平均4標準差\( \sqrt{3} \)
第二組 平均2標準差\( \sqrt{3} \)
共變數\( \displaystyle 1 \)相關係數\( \displaystyle \frac{1}{3} \)
資料\( \Bigg[\; \matrix{1 & -3 & -1 & -1 \cr 2 & 0 & 0 & -2} \Bigg]\; \)
第一組 平均-1標準差\( \sqrt{2} \)
第二組 平均0標準差\( \sqrt{2} \)
共變數\( \displaystyle 1 \)相關係數\( \displaystyle \frac{1}{2} \)
資料\( \Bigg[\; \matrix{-1 & -3 & 3 & -3 \cr 3 & -3 & -3 & -1} \Bigg]\; \)
第一組 平均-1標準差\( \sqrt{6} \)
第二組 平均-1標準差\( \sqrt{6} \)
共變數\( \displaystyle -1 \)相關係數\( \displaystyle -\frac{1}{6} \)
資料\( \Bigg[\; \matrix{2 & -2 & 2 & 2 \cr 3 & 3 & -1 & 3} \Bigg]\; \)
第一組 平均1標準差\( \sqrt{3} \)
第二組 平均2標準差\( \sqrt{3} \)
共變數\( \displaystyle -1 \)相關係數\( \displaystyle -\frac{1}{3} \)
資料\( \Bigg[\; \matrix{-3 & 3 & 1 & -1 \cr -1 & -3 & 3 & 1} \Bigg]\; \)
第一組 平均0標準差\( \sqrt{5} \)
第二組 平均0標準差\( \sqrt{5} \)
共變數\( \displaystyle -1 \)相關係數\( \displaystyle -\frac{1}{5} \)

[ 本帖最後由 bugmens 於 2012-10-6 08:01 PM 編輯 ]
作者: bugmens    時間: 2012-10-28 10:26

計算迴歸直線方程式


要先載入descriptive.mac才能使用cov指令
(%i1) load("descriptive.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/descriptive/descriptive.mac

(%i2) 
LinearRegression(XLowerBound,XUpperBound,YLowerBound,YUpperBound,n):=block(
for i:1 thru 50 do
  (x:create_list(random(XUpperBound-XLowerBound+1)+XLowerBound,i,1,n),
   y:create_list(random(YUpperBound-YLowerBound+1)+YLowerBound,i,1,n),
   data:matrix(x,y),
   cov:cov(transpose(data)),
   m:cov[1,2]/cov[1,1],
   if cov[1,1]#0 and cov[2,2]#0 and integerp(mean(x))=true and integerp(mean(y))=true then
     print("資料",data,"迴歸直線","y-",mean(y),"=",m,"(x-",mean(x),")")
  )
)$


LinearRegression(第一組下界,第一組上界,第二組下界,第二組上界,個數)
(%i3) LinearRegression(1,10,1,10,5);
資料\( \displaystyle \Bigg[\; \matrix{5 & 3 & 6 & 7 & 4 \cr 8 & 3 & 4 & 1 & 4} \Bigg]\; \)迴歸直線 \( \displaystyle y-4=-\frac{2}{5}(x-5) \)
(%o3) done


指令:LinearRegression(1,10,1,10,5);
說明:第一組範圍為1~10,第二組範圍為1~10,產生5筆資料
範例:設有兩組資料如下:

x

53674

y

83414
則y對x的迴歸直線方程式為 \( \displaystyle y-4=-0.4(x-5) \) 
其他範例:
資料\( \displaystyle \Bigg[\; \matrix{6 & 5 & 4 & 8 & 2 \cr 7 & 2 & 6 & 5 & 10} \Bigg]\; \)迴歸直線 \( \displaystyle y-6=-\frac{7}{10}(x-5) \)
資料\( \displaystyle \Bigg[\; \matrix{5 & 5 & 10 & 5 & 5 \cr 10 & 7 & 2 & 9 & 7} \Bigg]\; \)迴歸直線 \( \displaystyle y-7=-\frac{5}{4}(x-6) \)
資料\( \displaystyle \Bigg[\; \matrix{3 & 4 & 9 & 3 & 1 \cr 7 & 7 & 5 & 9 & 7} \Bigg]\; \)迴歸直線 \( \displaystyle y-7=-\frac{1}{3}(x-4) \)
資料\( \displaystyle \Bigg[\; \matrix{8 & 1 & 9 & 5 & 7 \cr 10 & 10 & 7 & 6 & 7} \Bigg]\; \)迴歸直線 \( \displaystyle y-8=-\frac{1}{5}(x-6) \)
資料\( \displaystyle \Bigg[\; \matrix{3 & 4 & 2 & 5 & 1 \cr 4 & 5 & 7 & 4 & 10} \Bigg]\; \)迴歸直線 \( \displaystyle y-6=-\frac{7}{5}(x-3) \)
資料\( \displaystyle \Bigg[\; \matrix{3 & 8 & 2 & 7 & 10 \cr 1 & 2 & 7 & 10 & 10} \Bigg]\; \)迴歸直線 \( \displaystyle y-6=\frac{1}{2}(x-6) \)

範例:在一個化學反應中,某化學物質的反應速率為Y g/min與某種催化劑的量X g有關,現在紀錄了5組數據於下表中,試求Y對X的迴歸直線方程式

X

678910

Y

689913
則Y關於X的迴歸直線為\( \displaystyle y-9=\frac{3}{2}(x-8) \)
其他範例:
資料\( \displaystyle \Bigg[\; \matrix{6 & 7 & 8 & 9 & 10 \cr 8 & 8 & 9 & 11 & 14} \Bigg]\; \)迴歸直線 \( \displaystyle y-10=\frac{3}{2}(x-8) \)
資料\( \displaystyle \Bigg[\; \matrix{6 & 7 & 8 & 9 & 10 \cr 5 & 6 & 9 & 10 & 10} \Bigg]\; \)迴歸直線 \( \displaystyle y-8=\frac{7}{5}(x-8) \)
資料\( \displaystyle \Bigg[\; \matrix{6 & 7 & 8 & 9 & 10 \cr 4 & 4 & 5 & 6 & 11} \Bigg]\; \)迴歸直線 \( \displaystyle y-6=\frac{8}{5}(x-8) \)
資料\( \displaystyle \Bigg[\; \matrix{6 & 7 & 8 & 9 & 10 \cr 5 & 7 & 9 & 10 & 14} \Bigg]\; \)迴歸直線 \( \displaystyle y-9=\frac{21}{10}(x-8) \)


範例:某冰店為了研究溫度與冰品銷售的影響,經過統計後得到下表:

溫度x℃

3031323334

份數y份

59779495100
則y關於x的迴歸直線為 \( y-85=10(x-32) \) 
其他範例:
資料\( \displaystyle \Bigg[\; \matrix{30 & 31 & 32 & 33 & 34 \cr 66 & 70 & 72 & 92 & 100} \Bigg]\; \)迴歸直線 \( \displaystyle y-80=9(x-32) \)
資料\( \displaystyle \Bigg[\; \matrix{30 & 31 & 32 & 33 & 34 \cr 56 & 58 & 70 & 82 & 99} \Bigg]\; \)迴歸直線 \( \displaystyle y-73=11(x-32) \)
資料\( \displaystyle \Bigg[\; \matrix{33 & 34 & 35 & 36 & 37 \cr 82 & 109 & 116 & 123 & 125} \Bigg]\;
\)迴歸直線 \( \displaystyle y-111=10(x-35) \)
資料\( \displaystyle \Bigg[\; \matrix{33 & 34 & 35 & 36 & 37 \cr 83 & 86 & 102 & 106 & 128} \Bigg]\; \)迴歸直線 \( \displaystyle y-101=11(x-35) \)
資料\( \displaystyle \Bigg[\; \matrix{33 & 34 & 35 & 36 & 37 \cr 89 & 103 & 114 & 117 & 127} \Bigg]\; \)迴歸直線 \( \displaystyle y-110=9(x-35) \)




利用lsquares_estimates指令計算迴歸直線方程式


要先載入lsquares.mac才能使用lsquares_estimates指令
(%i1) load("lsquares.mac");
(%o1) "C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/lsquares/lsquares.mac"

資料
(%i2) data:matrix([1,9],[2,3],[3,4],[4,7],[5,2]);
(%o2) \( \left[\ \matrix{1 & 9 \cr 2 & 3 \cr 3 & 4 \cr 4 & 7 \cr 5 & 2} \right]\ \)

利用最小平方法計算迴歸直線方程式(y=ax+b)
(%i3) lsquares_estimates(data,[x,y],y=a*x+b,[a,b]);
(%o3) [ [a=-1,b=8] ]


作者: bugmens    時間: 2012-11-13 18:00

設\( r \ge s \ge t \ge u \ge 0 \)且滿足\( 5r+4s+3t+6u=2012 \)。試求\( r+s+t+u \)的最大值與最小值。
(101高中數學能力競賽 台北市筆試一試題,https://math.pro/db/thread-1503-1-1.html)


要先載入simplex.mac才能使用maximize_lp,minimize_lp指令
(%i1) load("simplex.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/contrib/simplex/simplex.mac

按照英文字母順序顯示
(%i2) powerdisp:true;
(%o2) true

假設新的變數x,y,z,w且\( x,y,z,w \ge 0 \)
(%i3)
x=r-s;
y=s-t;
z=t-u;
w=u;

(%o3) \( x=r-s \)
(%o4) \( y=s-t \)
(%o5) \( z=t-u \)
(%o6) \( w=u \)

將舊的變數r,s,t,u改用x,y,z,w表示
(%i7) solve([%o3,%o4,%o5,%o6],[r,s,t,u]);
(%o7) \( [ [r=w+x+y+z,s=w+y+z,t=w+z,u=w] ] \)

將限制式5r+4s+3t+6u=2012改用x,y,z,w表示
(%i8)
5*r+4*s+3*t+6*u=2012;
ev(%,%o7);
cond:ratsimp(%);

(%o8) \( 5r+4s+3t+6u=2012 \)
(%o9) \( 6w+3(w+z)+4(w+y+z)+5(w+x+y+z)=2012 \)
(%o10) \( 18w+5x+9y+12z=2012 \)

將目標函數r+s+t+u改用x,y,z,w表示
(%i11)
r+s+t+u;
obj:ev(%,%o7);

(%o11) \( r+s+t+u \)
(%o12) \( 4w+x+2y+3z \)

使用線性規劃找最大值
obj目標函數,cond限制式,nonegative_lp非負的變數
當\( \displaystyle x=0,y=0,z=\frac{503}{3},w=0 \)時,有最大值503

(%i13) maximize_lp(obj,[cond]),nonegative_lp=true;
(%o13) \( \displaystyle [503,[z=\frac{503}{3},y=0,x=0,w=0]] \)

使用線性規劃找最小值
obj目標函數,cond限制式,nonegative_lp非負的變數
當\( \displaystyle x=\frac{2012}{5},y=0,z=0,w=0 \)時,有最小值\( \displaystyle \frac{2012}{5} \)

(%i14) minimize_lp(obj,[cond]),nonegative_lp=true;
(%o14) \( \displaystyle [\frac{2012}{5},[z=0,y=0,x=\frac{2012}{5},w=0]] \)



[ 本帖最後由 bugmens 於 2012-11-13 06:09 PM 編輯 ]
作者: bugmens    時間: 2013-3-16 10:54

All 20 diagonals are drawn in a regular octagon. At how many distinct points in the interior of the octagon (not on the boundary) do two or more diagonals intersect?
(A)49 (B)65 (C)70 (D)96 (E)128
(2013AMC10A,http://www.artofproblemsolving.c ... Problems/Problem_25)
http://www.youtube.com/watch?v=3ovuMRYs--8
解答可以看上面的連結,但我要藉這個主題來分享一篇論文
Poonen, B. and Rubinstein, M. "The Number of Intersection Points Made by the Diagonals of a Regular Polygon." SIAM J. Disc. Math. 11, 135-156, 1998.
http://www.google.com/search?q=t ... chrome&ie=UTF-8
http://mathworld.wolfram.com/Reg ... ionbyDiagonals.html
論文第3頁列出交點數和區域數的公式,第7頁列出2條對角線、3條對角線、…、7條對角線的交點數。公式請參閱論文



定義δ(m,n)函數
(%i1) delta(m,n):=if mod(n,m)=0 then 1 else 0;
(%o1) \( \delta(m,n):=if mod(n,m)=0 then 1 else 0 \)

交點數公式I(n)
(%i2)
I(n):=binomial(n,4)
      +(-5*n^3+45*n^2-70*n+24)/24*delta(2,n)
      -(3*n/2)*delta(4,n)
      +(-45*n^2+262*n)/6*delta(6,n)
      +42*n*delta(12,n)
      +60*n*delta(18,n)
      +35*n*delta(24,n)
      -38*n*delta(30,n)
      -82*n*delta(42,n)
      -330*n*delta(60,n)
      -144*n*delta(84,n)
      -96*n*delta(90,n)
      -144*n*delta(120,n)
      -96*n*delta(210,n);

(%o2)
\( \displaystyle \matrix{I(n):={n \choose 4}+\frac{(-5)n^3+45n^2+(-70)n+24}{24}\delta(2,n) \cr
+(\; -\frac{3n}{2} )\; \delta(4,n) \cr
+\frac{(-45)n^2+262n}{6}\delta(6,n) \cr
+42 n \delta(12,n) \cr
+60 n \delta(18,n) \cr
+35 n \delta(24,n) \cr
+(-38) n \delta(30,n) \cr
+(-82) n \delta(42,n) \cr
+(-330) n \delta(60,n) \cr
+(-144) n \delta(84,n) \cr
+(-96) n \delta(90,n) \cr
+(-144) n \delta(120,n) \cr
+(-96) n \delta(210,n)} \)

區域數公式R(n)
(%i3)
R(n):=(n^4-6*n^3+23*n^2-42*n+24)/24
      +(-5*n^3+42*n^2-40*n-48)/48*delta(2,n)
      -(3*n/4)*delta(4,n)
      +(-53*n^2+310*n)/12*delta(6,n)
      +(49*n/2)*delta(12,n)
      +32*n*delta(18,n)
      +19*n*delta(24,n)
      -36*n*delta(30,n)
      -50*n*delta(42,n)
      -190*n*delta(60,n)
      -78*n*delta(84,n)
      -48*n*delta(90,n)
      -78*n*delta(120,n)
      -48*n*delta(210,n);

(%o3)
\( \displaystyle \matrix{R(n):=\frac{n^4-6n^3+23 n^2+(-42)n+24}{24} \cr
+\frac{(-5)n^3+42n^2+(-40)n-48}{48}\delta(2,n) \cr
+(\; -\frac{3n}{4} )\; \delta(4,n) \cr
+\frac{(-53)n^2+310n}{12}\delta(6,n) \cr
+\frac{49n}{2}\delta(12,n) \cr
+32 n \delta(18,n) \cr
+19 n \delta(24,n) \cr
+(-36) n \delta(30,n) \cr
+(-50) n \delta(42,n) \cr
+(-190) n \delta(60,n) \cr
+(-78) n \delta(84,n) \cr
+(-48) n \delta(90,n) \cr
+(-78) n \delta(120,n) \cr
+(-48) n \delta(210,n)} \)

2條對角線交於一點的個數
(%i4)
a2(n):=n*((n^3-6*n^2+11*n-6)/24
          +(-5*n^2+46*n-72)/16*delta(2,n)
          -9/4*delta(4,n)
          +(-19*n+110)/2*delta(6,n)
          +54*delta(12,n)
          +84*delta(18,n)
          +50*delta(24,n)
          -24*delta(30,n)
          -100*delta(42,n)
          -432*delta(60,n));

(%o4)
\( \displaystyle \matrix{a2(n):=n \Bigg(\; \frac{n^3-6n^2+11n-6}{24} \cr
+\frac{(-5)n^2+46n-72}{16} \delta(2,n) \cr
+\frac{-9}{4}\delta(4,n) \cr
+\frac{(-19)n+110}{2} \delta(6,n) \cr
+54 \delta(12,n) \cr
+84 \delta(18,n) \cr
+50 \delta(24,n) \cr
+(-24) \delta(30,n) \cr
+(-100) \delta(42,n) \cr
+(-432) \delta(60,n) \Bigg)\;} \)

3條對角線交於一點的個數
(%i5)
a3(n):=n*((5*n^2-48*n+76)/48*delta(2,n)
          +3/4*delta(4,n)
          +(7*n-38)/6*delta(6,n)
          -8*delta(12,n)
          -20*delta(18,n)
          -16*delta(24,n)
          -19*delta(30,n)
          +8*delta(42,n)
          +68*delta(60,n)
          +60*delta(84,n)
          +48*delta(90,n)
          +60*delta(120,n)
          +48*delta(210,n));

(%o5)
\( \displaystyle \matrix{a3(n):=n\Bigg(\; \frac{5n^2-48n+76}{48}\delta(2,n) \cr
+\frac{3}{4} \delta(4,n) \cr
+\frac{7n-38}{6}\delta(6,n) \cr
+(-8)\delta(12,n) \cr
+(-20)\delta(18,n) \cr
+(-16)\delta(24,n) \cr
+(-19)\delta(30,n) \cr
+8 \delta(42,n) \cr
+68 \delta(60,n) \cr
+60 \delta(84,n) \cr
+48 \delta(90,n) \cr
+60 \delta(120,n) \cr
+48 \delta(210,n) \Bigg)\;} \)

4條對角線交於一點的個數
(%i6)
a4(n):=n*((7*n-42)/12*delta(6,n)
          -5/2*delta(12,n)
          -4*delta(18,n)
          +3*delta(24,n)
          +6*delta(42,n)
          +34*delta(60,n)
          -6*delta(84,n)
          -6*delta(120,n));

(%o6)
\( \displaystyle \matrix{a4(n):=n\Bigg(\; \frac{7n-42}{12}\delta(6,n) \cr
-\frac{5}{2}\delta(12,n) \cr
+(-4)\delta(18,n) \cr
+3 \delta(24,n) \cr
+6 \delta(42,n) \cr
+34 \delta(60,n) \cr
+(-6) \delta(84,n) \cr
+(-6) \delta(120,n) \Bigg)\;} \)

5條對角線交於一點的個數
(%i7)
a5(n):=n*((n-6)/4*delta(6,n)
          -3/2*delta(12,n)
          -2*delta(24,n)
          +4*delta(42,n)
          +6*delta(84,n)
          +6*delta(120,n));

(%o7)
\( \displaystyle \matrix{a5(n):=n\Bigg(\; \frac{n-6}{4}\delta(6,n) \cr
-\frac{3}{2} \delta(12,n) \cr
+(-2) \delta(24,n) \cr
+4 \delta(42,n) \cr
+6 \delta(84,n) \cr
+6 \delta(120,n) \Bigg)\;} \)

6條對角線交於一點的個數
(%i8) a6(n):=n*(4*delta(30,n)-4*delta(60,n));
(%o8) \( a6(n):=n(4\delta(30,n)-4 \delta(60,n)) \)

7條對角線交於一點
(%i9) a7(n):=n*(delta(30,n)+4*delta(60,n));
(%o9) \( a7(n):=n(\delta(30,n)+4 \delta(60,n)) \)

以論文第2頁的正30邊形為例,有16801個交點,有21480個區域。
2條對角線交於一點有13800個
3條對角線交於一點有2250個
4條對角線交於一點有420個
5條對角線交於一點有180個
6條對角線交於一點有120個
7條對角線交於一點有30個
15條對角線交於一點有1個(中心)

(%i10)
n:30;
I(n);
R(n);
a2(n);
a3(n);
a4(n);
a5(n);
a6(n);
a7(n);

(%o10) 30
(%o11) 16801
(%o12) 21480
(%o13) 13800
(%o14) 2250
(%o15) 420
(%o16) 180
(%o17) 120
(%o18) 30


作者: bugmens    時間: 2013-4-4 12:22

由邊長為1的正三角形堆疊n層,試問邊長為6時(即\( a_6 \)),所有大大小小之平行四邊形總數為
(101陽明高中,https://math.pro/db/viewthread.php?tid=1433&page=1#pid6580)
公式:\( \displaystyle 3C_{4}^{n+2} \)

可以再進一步問正三角形個數有多少
M. E. Larsen, The eternal triangle - a history of a counting problem, College Math. J., 20 (1989), 370-392.
http://www.google.com/search?q=T ... chrome&ie=UTF-8
http://oeis.org/A002717
http://www.math.ku.dk/~mel/mel.pdf
正三角形個數\( \displaystyle \Bigg[\; \frac{n(n+2)(2n+1)}{8} \Bigg]\; \)
其中還可以細分兩種正三角形
△正三角形個數:\( \displaystyle C_3^{n+2} \)
▽正三角形個數:\( \displaystyle \frac{n(n+2)(2n-1)}{24}-\frac{\delta(n)}{8} \) , \( \displaystyle \delta(n)=\cases{0 \text{for $n$ even} \cr 1 \text{for $n$ odd}} \)



正三角形個數公式f(n)
(%i1) f(n):=floor((n*(n+2)*(2*n+1))/8);
(%o1) \( \displaystyle f(n) :=floor \Bigg(\;\frac{n(n+2)(2n+1)}{8} \Bigg)\; \)

△正三角形個數
(%i2) Delta(n):=binomial(n+2,3);
(%o2) \( \Delta(n) :=\Bigg(\; \matrix{n+2 \cr 3} \Bigg)\; \)

定義δ(n)函數
(%i3) delta(n):=if evenp(n)=true then 0 else 1;
(%o3) \( \delta(n) \):=if evenp(n)=true then 0 else 1

▽正三角形個數
nabla符號為▽,http://en.wikipedia.org/wiki/Nabla_symbol

(%i4) nabla(n):=n*(n+2)*(2*n-1)/24-delta(n)/8;
(%o4) \( \displaystyle nabla(n) :=\frac{n(n+2)(2n-1)}{24}-\frac{\delta(n)}{8} \)

以論文第1頁的n=6為例
 正三角形78個
△正三角形56個
▽正三角形22個

(%i5)
n:6;
f(n);
Delta(n);
nabla(n);

(%o5) 6
(%o6) 78
(%o7) 56
(%o8) 22

[ 本帖最後由 bugmens 於 2014-8-12 09:15 AM 編輯 ]
作者: bugmens    時間: 2014-2-8 11:17

隨機產生數獨
http://www.cymric.jp/maxima/sudoku.html

下載sudoku.mac
將檔案放在C:\Program Files\Maxima-5.31.2\share\maxima\5.31.2\share目錄底下
開啟maxima輸入以下的指令

(%i1) load("sudoku.mac");
(%o1) "C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.31.2/share/sudo.mac"

有50%的機會傳回-1代表產生數獨失敗
(%i2) sudoku();
(%o2) \( \displaystyle \left[ \matrix{9 & 2 & 1 & 5 & 3 & 7 & 6 & 8 & 4 \cr
4 & 3 & 7 & 8 & 2 & 6 & 1 & 5 & 9 \cr
6 & 8 & 5 & 4 & 9 & 1 & 3 & 2 & 7 \cr
2 & 1 & 8 & 7 & 6 & 9 & 4 & 3 & 5 \cr
3 & 9 & 4 & 2 & 8 & 5 & 7 & 6 & 1 \cr
7 & 5 & 6 & 1 & 4 & 3 & 2 & 9 & 8 \cr
5 & 4 & 9 & 3 & 7 & 2 & 8 & 1 & 6 \cr
8 & 6 & 3 & 9 & 1 & 4 & 5 & 7 & 2 \cr
1 & 7 & 2 & 6 & 5 & 8 & 9 & 4 & 3} \right] \)

[ 本帖最後由 bugmens 於 2014-8-12 09:14 AM 編輯 ]
作者: bugmens    時間: 2014-10-18 22:22

設銳角三角形ABC的外接圓半徑為8,已知外接圓圓心到\( \overline{AB} \)的距離2,而到\( \overline{BC} \)的距離為7,則\( \overline{AC}= \)?
(102學測)

學測這題只問\( \overline{AC} \)長度所以比較簡單,可以改求外接圓圓心到\( \overline{AC} \)的距離為何?但為了數字好算,我寫了一個小程式來找有哪些正整數解。

設外接圓圓心為R,圓心到\( \overline{AB} \)的距離為a,到\( \overline{BC} \)的距離為b,到\( \overline{CA} \)的距離為c,試找出正整數解\( (a,b,c,R)= \)?

\( \displaystyle sin B=sin(\theta_1+\theta_2)=sin \theta_1 cos \theta_2+cos \theta_1 sin \theta_2=\frac{a}{R} \cdot \frac{\sqrt{R^2-b^2}}{R}+\frac{\sqrt{R^2-a^2}}{R} \cdot \frac{b}{R} \)

AC弧的圓周角為\( \theta_1+\theta_2 \),圓心角為\( 2 \theta \),所以\( 2(\theta_1+\theta_2)=2 \theta \),\( sin(\theta_1+\theta_2)=sin \theta \)

\( \displaystyle \frac{a \sqrt{R^2-b^2}+b \sqrt{R^2-a^2}}{R^2}=\frac{\sqrt{R^2-c^2}}{R} \)

\( a \sqrt{R^2-b^2}+b \sqrt{R^2-a^2}-R \sqrt{R^2-c^2}=0 \)



要檢驗的式子
(%i1) equation:a*sqrt(R^2-b^2)+b*sqrt(R^2-a^2)-R*sqrt(R^2-c^2);
(%o1) \( -R \sqrt{R^2-c^2}+a \sqrt{R^2-b^2}+b \sqrt{R^2-a^2} \)

將符合上式的(a,b,c,R)印出來
(%i2)
for R:3 thru 30 do
  (for c:1 thru R-1 do
     (for b:1 thru c-1 do
        (for a:1 thru b-1 do
           (if ev(equation,[a=a,b=b,c=c,R=R])=0 then
              (print("a=",a,",b=",b,",c=",c,",R=",R)
              )
           )
        )
     )
  );

\( a=2,b=7,c=11,R=14 \)
\( a=2,b=9,c=12,R=16 \)
\( a=6,b=11,c=14,R=21 \)
\( a=1,b=13,c=22,R=26 \)
\( a=4,b=14,c=22,R=28 \)
\( a=3,b=14,c=25,R=30 \)
(%o2) done



範例1:

設銳角三角形\( ABC \)的外接圓半徑為14,已知外接圓圓心到\( \overline{AB} \)的距離2,而到\( \overline{BC} \)的距離為7,則外接圓圓心到\( \overline{CA} \)的距離為?


範例2:
設銳角三角形ABC的外接圓圓心為\( O \),已知圓心\( O \)到\( \overline{AB} \)的距離2,圓心\( O \)到\( \overline{BC} \)的距離為7,圓心\( O \)到\( \overline{CA} \)的距離為11,則外接圓半徑為?
(提示:要改用\( cos(\theta_1+\theta_2)=cos \theta \)計算)


設三角形ABC的外接圓半徑為\( R \),外接圓圓心到三邊的距離為\( a,b,c \),試證:\( R \)為三次方程式\( x^3-(a^2+b^2+c^2)x-2abc=0 \)的一根。

[ 本帖最後由 bugmens 於 2014-10-20 01:29 PM 編輯 ]
作者: bugmens    時間: 2015-9-7 21:44

三個半徑為1的圓兩兩外切且內切於一個正方形,試問正方形的邊長是   
(102松山工農,https://math.pro/db/thread-1655-1-1.html)


正方形邊長為1,內部8個等圓相切如圖,若圓半徑為\( \displaystyle \frac{a+\sqrt{b}-\sqrt{c}}{4} \),其中\( a,b,c \)均為自然數,求\( (a,b,c)= \)   
(103彰化高中科學班,https://math.pro/db/attachment.p ... 9c&t=1441633124)


這個網頁列出了1到24個單位圓的最小正方形邊長為何?
http://www2.stetson.edu/~efriedma/cirinsqu/
我利用maxima的非線性規劃函數fmin_cobyla求2,3,5個單位圓的最小正方形邊長,只是\( n=5 \)時就得不到正確答案。

要先載入fmin_cobyla.mac才能使用fmin_cobyla指令
(%i1) load("fmin_cobyla.mac");
(%o1) C:/Program Files/Maxima-sbcl-5.37.1/share/maxima/5.37.1/share/cobyla/fmin_cobyla.mac

設定5位小數
(%i2) fpprintprec:5;
(%o2) 5

求內含2個單位圓的最小正方形邊長(s=2+√2)
(%i3)
solution:fmin_cobyla(s,[s,x1,y1,x2,y2],[1,1,1,1,1],
                                constraints=[1<=x1,x1<=s-1,
                                                    1<=y1,y2<=s-1,
                                                    1<=x2,x2<=s-1,
                                                    1<=y2,y2<=s-1,
                                                    sqrt((x1-x2)^2+(y1-y2)^2)>=2]);

(%o3) \( [[s=3.4142,x1=2.4142,y1=1.0,x2=1.0,y2=2.4142],3.4142,62,0] \)

求內含3個單位圓的最小正方形邊長(s=2+1/√2+√6/2)
(%i4)
solution:fmin_cobyla(s,[s,x1,y1,x2,y2,x3,y3],[1,1,1,1,1,1,1],
                                constraints=[1<=x1,x1<=s-1,
                                                    1<=y1,y2<=s-1,
                                                    1<=x2,x2<=s-1,
                                                    1<=y2,y2<=s-1,
                                                    1<=x3,x3<=s-1,
                                                    1<=y3,y3<=s-1,
                                                    sqrt((x1-x2)^2+(y1-y2)^2)>=2,
                                                    sqrt((x2-x3)^2+(y2-y3)^2)>=2,
                                                    sqrt((x3-x1)^2+(y3-y1)^2)>=2]);

(%o4) \( [[s=3.9319,x1=1.0,y1=1.0,x2=1.5176,y2=2.9319,x3=2.9319,y3=1.5176],3.9319,111,0] \)

求內含5個單位圓的最小正方形邊長(s=2+2√2)
只是無法得到正確答案

(%i5)
solution:fmin_cobyla(s,[s,x1,y1,x2,y2,x3,y3,x4,y4,x5,y5],[1,2,1,3,1,4,2,4,1,2,1],
                                constraints=[1<=x1,x1<=s-1,
                                                    1<=y1,y2<=s-1,
                                                    1<=x2,x2<=s-1,
                                                    1<=y2,y2<=s-1,
                                                    1<=x3,x3<=s-1,
                                                    1<=y3,y3<=s-1,
                                                    1<=x4,x4<=s-1,
                                                    1<=y4,y4<=s-1,
                                                    1<=x5,x5<=s-1,
                                                    1<=y5,y5<=s-1,
                                                    sqrt((x1-x2)^2+(y1-y2)^2)>=2,
                                                    sqrt((x1-x3)^2+(y1-y3)^2)>=2,
                                                    sqrt((x1-x4)^2+(y1-y4)^2)>=2,
                                                    sqrt((x1-x5)^2+(y1-y5)^2)>=2,
                                                    sqrt((x2-x3)^2+(y2-y3)^2)>=2,
                                                    sqrt((x2-x4)^2+(y2-y4)^2)>=2,
                                                    sqrt((x2-x5)^2+(y2-y5)^2)>=2,
                                                    sqrt((x3-x4)^2+(y3-y4)^2)>=2,
                                                    sqrt((x3-x5)^2+(y3-y5)^2)>=2,
                                                    sqrt((x4-x5)^2+(y4-y5)^2)>=2]);

(%o5) \( [[s=5.0907,x1=1.0,y1=3.0,x2=3.0,y2=1.0,x3=2.6764,y3=4.0907,x4=4.0907,y4=2.6764,x5=1.0,y5=1.0],5.0907,236,0] \)
作者: bugmens    時間: 2016-4-16 20:43

原本maxima都是用Gnuplot當作預設的繪圖介面,這個網列有許多maxima和Gnuplot的範例
http://riotorto.users.sourceforge.net/Maxima/vtk/index.html

最新的windows的maxima 5.38加入VTK,關於VTK我取自wiki的介紹。

視覺化工具函式庫(VTK, Visualization Toolkit)是一個開放源碼,跨平台、支援平行處理(VTK曾用於處理大小近乎1個Petabyte的資料,其平台為美國Los Alamos國家實驗室所有的具1024個處理器之大型系統)的圖形應用函式庫。
https://zh.wikipedia.org/wiki/VTK

這個網頁列出非常多maxima和VTK的範例
http://riotorto.users.sourceforge.net/vtk/


(%i1) load("draw") $

(%i2) draw_renderer : 'vtk $

範例取自http://riotorto.users.sourceforge.net/vtk/solids/index.html
(%i3)
draw3d(
    color = red,
    sphere([0,2,0],1),
    color = green,
    sphere([0,2,2],1),
    color = blue,
    sphere([0,2,4],1) ) $



[ 本帖最後由 bugmens 於 2016-12-24 06:32 AM 編輯 ]
作者: bugmens    時間: 2016-7-14 17:46

解\(2x^2-11[\;x ]\;+12=0 \)
(建中通訊解題第24期,http://web2.ck.tp.edu.tw/~mathwe ... 30-15&Itemid=37)

若\(x\)是實數,定義\([\;x ]\;\)表示小於或等於\(x\)的最大整數,試求方程式\( 2x^2-5[\;x ]\;+1=0 \)的解。
(建中通訊解題第52期,http://web2.ck.tp.edu.tw/~mathwe ... 30-15&Itemid=37)

[]表高斯符號,求解\(3x^2-19 \cdot [\;x ]\;+20=0\)。
(105高雄餐旅大學附屬高中,https://math.pro/db/thread-2527-1-2.html)

我以建中通訊解題第24期這題示範如何用maxima解題,網友可自行更換係數測試。

要先載入solve_rat_ineq才能使用solve_rat_ineq指令
(%i1) load("solve_rat_ineq");
(%o1) C:\maxima-5.38.0\share\maxima\5.38.0_dirty\share\solve_rat_ineq\solve_rat_ineq.mac

高斯函數方程式2x^2-11[x]+12=0
(%i2) Equation:2*x^2-11*floor(x)+12;
(%o2) \(-11 floor(x)+2x^2+12 \)

移項得到[x]=(2x^2+12)/11
(%i3) FloorX:solve(Equation,floor(x));
(%o4) \( \displaystyle [\; floor(x)=\frac{2x^2+12}{11} ]\; \)

利用x-1<[x],求x的範圍
(%i4) x-1<rhs(FloorX[1]);
(%o4) \( \displaystyle x-1<\frac{2x^2+12}{11} \)

x的範圍為所有實數
(%i5) solve_rat_ineq(%);
0 errors, 0 warnings
(%o5) all

利用[x]≦x,求x的範圍
(%i6) rhs(FloorX[1])<=x;
(%o6) \( \displaystyle \frac{2x^2+12}{11}<=x \)

x的範圍為3/2≦x≦4
(%i7) solve_rat_ineq(%);
(%o7) \( \displaystyle [\;[\; x>=\frac{3}{2},x<=4 ]\; ]\; \)

3/2≦x≦4範圍內,[x]有2,3,4三種可能
(%i8) FloorXInteger:create_list(x,x,ceiling(rhs(%[1][1])),floor(rhs(%[1][2])));
(%o8) \( [\;2,3,4 ]\; \)

將[x]值代回原方程式,解出x
(%i9)
for floorx in FloorXInteger do
  (print("當[x]=",floorx,"時"),
   equation:ev(Equation,floor(x)=floorx),
   print("解方程式",equation,"=0"),
   solution:solve(equation,x),
   print("解為",solution),
   for sol in solution do
      (X:rhs(sol),
       if floor(rhs(sol))=floorx then
         (print("驗算[",X,"]=",floor(X),"是否等於",floorx,"是,正確答案為",sol))
       else
         (print("驗算[",X,"]=",floor(X),"是否等於",floorx,"否,不為正確答案"))
      ),
     print(" ")
  );

當\([\;x ]\;=2\)時
解方程式\( 2x^2-10=0 \)
解為\( [\;x=-\sqrt{5},x=\sqrt{5} ]\; \)
驗算\([\;-\sqrt{5} ]\;=-3\)是否等於2 否,不為正確答案
驗算\([\; \sqrt{5} ]\;=2\)是否等於2 是,正確答案為\(x=\sqrt{5}\)

當\([\;x ]\;=3\)時
解方程式\(2x^2-21=0\)
解為\( \displaystyle [\;x=-\frac{\sqrt{21}}{\sqrt{2}},x=\frac{\sqrt{21}}{\sqrt{2}} ]\; \)
驗算\( \displaystyle \Bigg[\; -\frac{\sqrt{21}}{\sqrt{2}} \Bigg]\;=-4 \)是否等於3 否,不為正確答案
驗算\( \displaystyle \Bigg[\; \frac{\sqrt{21}}{\sqrt{2}} \Bigg]\;=3 \)是否等於3 是,正確答案為\( \displaystyle x=\frac{\sqrt{21}}{\sqrt{2}} \)

當\([\;x ]\;=4\)時
解方程式\(2x^2-32=0\)
解為\( [\;x=-4,x=4 ]\; \)
驗算\([\;-4 ]\;=-4\)是否等於4 否,不為正確答案
驗算\([\;4 ]\;=4\)是否等於4 是,正確答案為\(x=4\)
(%o9) done

[ 本帖最後由 bugmens 於 2016-7-14 08:56 PM 編輯 ]
作者: bugmens    時間: 2016-11-20 20:01

已知\( \Delta ABC \)三邊所在的三直線\( L_{AB} \):\( a_1x+b_1y=c_1 \),\( L_{AC} \):\( a_2x+b_2y=c_2 \),\( L_{BC} \):\(a_3x+b_3y=c_3\),則\( \Delta \)的面積為\( \displaystyle \frac{1}{2}\frac{\left| \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_3&b_3&c_3} \right|^2}{\left| \matrix{a_1&b_1\cr a_2&b_2} \right| \cdot \left| \matrix{a_2&b_2\cr a_3&b_3} \right| \cdot \left| \matrix{a_3&b_3\cr a_1&b_1} \right|} \)之絕對值。
阮瑞泰(2013):已知三角形三邊所在直線方程式之面積公式。科學教育月刊,362 期(9月號),p43~48。
http://www.sec.ntnu.edu.tw/Month ... 修改97-印).pdf
陳建燁(2015): 「已知三邊直線方程式之三角形面積公式」的另一種證法。科學教育月刊,第 382 期(9 月號),p32~34。
http://www.sec.ntnu.edu.tw/Month ... 式」(月刊).pdf

改變變數顯示順序
例:x+y+z+1=0;
原本為z+y+x+1=0;
變成1+x+y+z=0;

(%i1) powerdisp:true;
(%o1) true

計算三角形面積副程式
(%i2)
Triangle(L1,L2,L3):=block
([augcoef,subaugcoef,detaugcoef,detsubaugcoef],
augcoef:augcoefmatrix([L1,L2,L3],[x,y]),
detaugcoef:determinant(augcoef),
print("取出三個直線的係數",matrix([L1],[L2],[L3]),"=>",augcoef,",行列式值=",detaugcoef),
subaugcoef:create_list(submatrix(i,augcoef,3),i,1,3),
detsubaugcoef:create_list(determinant(subaugcoef[ i ]),i,1,3),
print("取",matrix(["L2:",L2],["L3:",L3]),"的x,y係數=>",subaugcoef[1],"行列式值=",detsubaugcoef[1]),
print("取",matrix(["L1:",L1],["L3:",L3]),"的x,y係數=>",subaugcoef[2],"行列式值=",detsubaugcoef[2]),
print("取",matrix(["L1:",L1],["L2:",L2]),"的x,y係數=>",subaugcoef[3],"行列式值=",detsubaugcoef[3]),
print("三角形面積=1/2*",augcoef,"^2/|",subaugcoef[1],subaugcoef[2],subaugcoef[3],"|"),
print("=1/2*",detaugcoef,"^2/|",detsubaugcoef[1],"*",detsubaugcoef[2],"*",detsubaugcoef[3],"|"),
print("=",1/2*detaugcoef^2/abs(detsubaugcoef[1]*detsubaugcoef[2]*detsubaugcoef[3]))
)$


三個直線方程式
(%i5)
L1:x+y=1;
L2:x-y=1;
L3:x+2*y=4;

(%o3) \( x+y=1 \)
(%o4) \( x-y=1 \)
(%o5) \( x+2y=4 \)

得到三角形面積
(%i6) Triangle(L1,L2,L3);
取出三個直線的係數\( \left[ \matrix{x+y=1 \cr x-y=1 \cr x+2y=4} \right] \)=>\( \left[ \matrix{1&1&-1\cr 1&-1&-1\cr 1&2&-4} \right] \),行列式值\(=6\)
取\( \left[ \matrix{L2:&x-y=1 \cr L3:&x+2y=4}\right] \)的\(x,y\)係數=>\( \left[ \matrix{1&-1 \cr 1&2} \right] \)行列式值\(=3\)
取\( \left[ \matrix{L1:&x+y=1 \cr L3:&x+2y=4}\right] \)的\(x,y\)係數=>\( \left[ \matrix{1&1 \cr 1&2} \right] \)行列式值\(=1\)
取\( \left[ \matrix{L1:&x+y=1 \cr L2:&x-y=1}\right] \)的\(x,y\)係數=>\( \left[ \matrix{1&1 \cr 1&-1} \right] \)行列式值\(=-2\)
三角形面積\( =1/2*\left[ \matrix{1&1&-1\cr 1&-1&-1\cr 1&2&-4} \right]^2/|\; \left[ \matrix{1&-1\cr 1&2}\right] \left[ \matrix{1&1\cr 1&2}\right] \left[ \matrix{1&1\cr 1&-1}\right] |\; \)
\( =1/2*6^2/|\; 3*1*-2 |\; \)
\( =3\)
(%o6)
3

___________________________________
在空間中,已知某一四面體\(ABCD\)的四個面所在的平面方程式分別為:
\(E_1\):\( a_1x+b_1y+c_1z+d_1=0 \),\(E_2\):\(a_2x+b_2y+c_2z+d_2=0\)
\(E_3\):\(a_3x+b_3y+c_3z+d_3=0\),\(E_4\):\(a_4x+b_4y+c_4z+d_4=0\)。
令\(A\)為\(E_2,E_3,E_4\)三平面的交點,\(B\)為\(E_1,E_3,E_4\)三平面的交點,
\(C\)為\(E_1,E_2,E_4\)三平面的交點,\(D\)為\(E_1,E_2,E_3\)三平面的交點。
則四面體體積\( \displaystyle V_{ABCD}=\frac{1}{6}\cdot \frac{|\; \left| \matrix{a_1&b_1&c_1&d_1 \cr a_2&b_2&c_2&d_2 \cr a_3&b_3&c_3&d_3 \cr a_4&b_4&c_4&d_4} \right| |\;^3}{|\; \left| \matrix{a_2&b_2&c_2 \cr a_3&b_3&c_3 \cr a_4&b_4&c_4} \right| \cdot \left| \matrix{a_1&b_1&c_1 \cr a_3&b_3&c_3 \cr a_4&b_4&c_4} \right| \cdot \left| \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_4&b_4&c_4} \right| \cdot \left| \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_3&b_3&c_3} \right| |\;} \)。
陳建燁(2015): 已知四面方程式之四面體體積公式。科學教育月刊,第 388 期(5月號),p32~35。
http://www.sec.ntnu.edu.tw/Month ... 公式(修改).pdf

改變變數顯示順序
例:x+y+z+1=0;
原本為z+y+x+1=0;
變成1+x+y+z=0;

(%i1) powerdisp:true;
(%o1) true

計算四面體體積副程式
(%i2)
Tetrahedron(E1,E2,E3,E4):=block
([augcoef,subaugcoef,detaugcoef,detsubaugcoef],
augcoef:augcoefmatrix([E1,E2,E3,E4],[x,y,z]),
print("取出四個平面的係數",matrix([E1],[E2],[E3],[E4]),"=>",augcoef),
subaugcoef:create_list(submatrix(1,augcoef,i),i,1,4),/*針對第1列降階*/
detsubaugcoef:create_list(determinant(subaugcoef[ i ]),i,1,4),
print("針對第1列降階計算行列式值",augcoef),
print("=+",augcoef[1,1],subaugcoef[1],
         "-",augcoef[1,2],subaugcoef[2],
         "+",augcoef[1,3],subaugcoef[3],
         "-",augcoef[1,4],subaugcoef[4]),
print("=+",augcoef[1,1],"*",detsubaugcoef[1],
         "-",augcoef[1,2],"*",detsubaugcoef[2],
         "+",augcoef[1,3],"*",detsubaugcoef[3],
         "-",augcoef[1,4],"*",detsubaugcoef[4]),
print("=",detaugcoef:determinant(augcoef)),
subaugcoef:create_list(submatrix(i,augcoef,4),i,1,4),/*針對第4行降階*/
detsubaugcoef:create_list(determinant(subaugcoef[ i ]),i,1,4),
print("取",matrix(["E2:",E2],["E3:",E3],["E4:",E4]),"的x,y,z係數=>",subaugcoef[1],",行列式值=",detsubaugcoef[1]),
print("取",matrix(["E1:",E1],["E3:",E3],["E4:",E4]),"的x,y,z係數=>",subaugcoef[2],",行列式值=",detsubaugcoef[2]),
print("取",matrix(["E1:",E1],["E2:",E2],["E4:",E4]),"的x,y,z係數=>",subaugcoef[3],",行列式值=",detsubaugcoef[3]),
print("取",matrix(["E1:",E1],["E2:",E2],["E3:",E3]),"的x,y,z係數=>",subaugcoef[4],",行列式值=",detsubaugcoef[4]),
print("四面體體積=1/6*|",augcoef,"|^3/|",subaugcoef[1],"*",subaugcoef[2],"*",subaugcoef[3],"*",subaugcoef[4],"|"),
print("=1/6*|",detaugcoef,"|^3/|",detsubaugcoef[1],"*",detsubaugcoef[2],"*",detsubaugcoef[3],"*",detsubaugcoef[4],"|"),
print("=",1/6*abs(detaugcoef)^3/abs(detsubaugcoef[1]*detsubaugcoef[2]*detsubaugcoef[3]*detsubaugcoef[4]))
)$


4個平面方程式
(%i6)
E1:x+y+z-2=0;
E2:x+y-z=0;
E3:x-y+z=0;
E4:-x+y+z=0;

(%o3) \( -2+x+y+z=0 \)
(%o4) \( x+y-z=0 \)
(%o5) \( x-y+z=0 \)
(%o6) \( -x+y+z=0 \)

得到四面體體積
(%i7) Tetrahedron(E1,E2,E3,E4);
取出四個平面的係數\( \left[ \matrix{-2+x+y+z=0 \cr x+y-z=0 \cr x-y+z=0 \cr -x+y+z=0} \right] \)=>\( \left[ \matrix{1&1&1&-2 \cr 1&1&-1&0 \cr 1&-1&1&0 \cr -1&1&1&0} \right] \)
針對第1列降階計算行列式值\( \left[ \matrix{1&1&1&-2 \cr 1&1&-1&0 \cr 1&-1&1&0 \cr -1&1&1&0} \right] \)
\( =+1 \left[ \matrix{1&-1&0\cr -1&1&0\cr 1&1&0} \right]-1\left[ \matrix{1&-1&0\cr 1&1&0\cr -1&1&0} \right]+1\left[ \matrix{1&1&0\cr 1&-1&0\cr -1&1&0} \right]--2\left[ \matrix{1&1&-1\cr 1&-1&1\cr -1&1&1} \right] \)
\( =+1*0-1*0+1*0--2*-4 \)
\(=-8\)
取\( \left[ \matrix{L2:&x+y-z=0 \cr L3:&x-y+z=0 \cr L4:&-x+y+z=0} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&-1 \cr 1&-1&1 \cr -1&1&1 } \right] \),行列式值\(=-4\)
取\( \left[ \matrix{L1:&-2+x+y+z=0 \cr L3:&x-y+z=0 \cr L4:&-x+y+z=0} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&1 \cr 1&-1&1 \cr -1&1&1 } \right] \),行列式值\(=-4\)
取\( \left[ \matrix{L1:&-2+x+y+z=0 \cr L2:&x+y-z=0 \cr L4:&-x+y+z=0} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&1 \cr 1&1&-1 \cr -1&1&1 } \right] \),行列式值\(=4\)
取\( \left[ \matrix{L1:&-2+x+y+z=0 \cr L2:&x+y-z=0& \cr L3:&x-y+z=0&} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&1 \cr 1&1&-1 \cr 1&-1&1} \right] \),行列式值\(-4\)
四面體體積\(=1/6*|\; \left[ \matrix{1&1&1&-2\cr 1&1&-1&0\cr 1&-1&1&0\cr -1&1&1&0}\right] |\;^3/|\; \left[ \matrix{1&1&-1 \cr 1&-1&1 \cr -1&1&1}\right]*\left[ \matrix{1&1&1 \cr 1&-1&1 \cr -1&1&1}\right]*\left[ \matrix{1&1&1 \cr 1&1&-1 \cr -1&1&1}\right]*\left[ \matrix{1&1&1 \cr 1&1&-1 \cr 1&-1&1}\right] |\;\)
\( =1/6*|\; -8 |\;^3/|\; -4*-4*4*-4 |\; \)
\( =\displaystyle \frac{1}{3} \)
(%o7) \( \displaystyle \frac{1}{3} \)

[ 本帖最後由 bugmens 於 2016-12-3 08:35 PM 編輯 ]
作者: bugmens    時間: 2016-12-3 20:19

用行列式計算平面上的平行四邊形面積與空間中的平行六面體體積
http://www.sec.ntnu.edu.tw/Month ... (月刊修改).pdf
___________________________________

已知\( \Bigg\{\; \matrix{t_1 \le a_1x+b_1y \le t_2 \cr s_1 \le a_2x+b_2y \le s_2} \)求滿足條件的點\((x,y)\)所形成的平行四邊形面積\( \displaystyle =\frac{(t_2-t_1)(s_2-s_1)}{\left|\ \matrix{a_1&b_1 \cr a_2&b_2} \right|\ } \)的絕對值。

我以100新北市國中聯招這題示範如何使用Parallelogram(L1,L2)副程式。

在坐標平面上\(L_1\):\(x-y=0\)、\( L_2 \):\( x-y=h \),\( h<0 \)、\( L_3 \):\( \displaystyle y=-\frac{5}{2} \)及\(x\)軸四條直線圍出一個面積為10的平行四邊形,若直線\(L_2\)與\(y\)軸交點於點\( (0,k) \),則\( k+h \)為何?
(A)0 (B)2 (C)4 (D)8
(100新北市國中聯招,https://math.pro/db/thread-1135-1-1.html)

105.12.7補充
求區域\( S=\{\; (x,y)|\; 0\le a \le 1,0 \le b \le 1,x=a+b+1,y=2a-3b+1 \}\; \)所圍成的區域面積  
(105台南女中,https://math.pro/db/viewthread.php?tid=2488&page=2#pid15152)



改變變數顯示順序
例:x+y+1=0;
原本為y+x+1=0;
變成1+x+y=0;

(%i1) powerdisp:true;
(%o1) true

計算平行四邊形面積副程式
(%i2)
Parallelogram(L1,L2):=block
([coef,detcoef],
coef:coefmatrix([L1[2],L2[2]],[x,y]),
detcoef:determinant(coef),
print("取出二個直線的x,y係數",matrix([L1[2]],[L2[2]]),"=>",coef,",行列式值=",detcoef),
print("=|(",L1[3],"-",L1[1],")(",L2[3],"-",L2[1],")/",coef,"|"),
print("=|",L1[3]-L1[1],"*",L2[3]-L2[1],"/",detcoef,"|"),
print("=",abs((L1[3]-L1[1])*(L2[3]-L2[1])/detcoef))
)$


求1≦2x+3y≦4所圍成的平行四邊形面積?
 5≦6x+7y≦8

(%i4)
L1:[1,2*x+3*y,4];
L2:[5,6*x+7*y,8];

(%o3) \( [\; 1,2x+3y,4 ]\; \)
(%o4) \( [\; 5,6x+7y,8 ]\; \)

求平行四邊形面積
(%i5) Parallelogram(L1,L2);
取出二個直線的\(x,y\)係數\( \left[ \matrix{2x+3y \cr 6x+7y} \right] \)=>\( \left[ \matrix{2&3 \cr 6&7} \right] \),行列式值\(=-4\)
\( =|\; (4-1)(8-5)/ \left[ \matrix{2&3 \cr 6&7} \right] |\; \)
\( =|\; 3*3/-4 |\; \)
\( \displaystyle =\frac{9}{4}\)
(%o5) \( \displaystyle \frac{9}{4} \)

h≦x-y≦0,圍出面積為10的平行四邊形,h<0,求h=?
-5/2≦y≦0
(100新北市國中聯招)

(%i7)
L1:[h,x-y,0];
L3:[-5/2,y,0];

(%o6) \( [\;h,x-y,0 ]\; \)
(%o7) \( \displaystyle [\; -\frac{5}{2},y,0 ]\; \)

(%i8) Parallelogram(L1,L2)=10;
取出二個直線的\( x,y \)係數\( \left[ \matrix{x-y \cr 6x+7y} \right] \)=>\( \left[ \matrix{1&-1 \cr 6&7} \right] \),行列式值\(=13\)
\( =|\; (0-h)(8-5)/ \left[ \matrix{1&-1 \cr 6&7} \right] |\; \)
\( =|\; -h*3/13 |\; \)
\( \displaystyle =\frac{3 |\; h |\;}{13} \)
(%o8) \( \displaystyle \frac{3 |\; h |\;}{13}=10 \)

得到h=-130/3(正不合)
(%i9) to_poly_solve(%,h);
to_poly_solve: to_poly_solver.mac is obsolete; I'm loading to_poly_solve.mac instead.
(%o9) %\( \displaystyle union \left( [\; h=-\frac{130}{3} ]\;,[\; h=\frac{130}{3} ]\; \right)\)

___________________________________

已知\( \cases{\matrix{t_1 \le a_1x+b_1y+c_1z \le t_2 \cr s_1 \le a_2x+b_2y+c_2z \le s_2 \cr u_1 \le a_3x+b_3y+c_3z \le u_2}} \)求滿足條件的\((x,y,z)\)所形成的平行六面體體積\( \displaystyle =\frac{(t_2-t_1)(s_2-s_1)(u_2-u_1)}{\left|\ \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_3&b_3&c_3} \right|\ } \)的絕對值。

我以2題教甄試題來示範如何使用Parallelepiped(L1,L2,L3)副程式。

由三組平行平面\( \cases{\matrix{0 \le x+2y \le 4 \cr -1 \le x-3y+z \le 3 \cr 1 \le x+3y-2z \le 7}} \)所圍成的平行六面體體積為?
(99文華高中,https://math.pro/db/viewthread.php?tid=924&page=1#pid1993)

設空間中\( P(x,y,z) \)滿足不等式\( \displaystyle \Bigg\{\; \matrix{0 \le x+y \le 2 \cr 0 \le y+z \le 2 \cr 0 \le x+z \le 2} \),此P點之點集合形成一平行六面體,求此平行六面體體積為?
(102新化高中,https://math.pro/db/viewthread.php?tid=1710&page=1#pid9038)




改變變數顯示順序
例:x+y+z+1=0;
原本為z+y+x+1=0;
變成1+x+y+z=0;

(%i1) powerdisp:true;
(%o1) true

計算平行六面體體積副程式
(%i2)
Parallelepiped(L1,L2,L3):=block
([coef,detcoef],
coef:coefmatrix([L1[2],L2[2],L3[2]],[x,y,z]),
detcoef:determinant(coef),
print("取出三個直線的x,y,z係數",matrix([L1[2]],[L2[2]],[L3[2]]),"=>",coef,",行列式值=",detcoef),
print("=|(",L1[3],"-",L1[1],")(",L2[3],"-",L2[1],")(",L3[3],"-",L3[1],")/",coef,"|"),
print("=|",L1[3]-L1[1],"*",L2[3]-L2[1],"*",L3[3]-L3[1],"/",detcoef,"|"),
print("=",abs((L1[3]-L1[1])*(L2[3]-L2[1])*(L3[3]-L3[1])/detcoef))
)$


  0≦x+2y   ≦4
求-1≦x-3y+z ≦3所圍成的平行六面體體積?
  1≦x+3y-2z≦7
(99文華高中)

(%i5)
L1:[0,x+2*y,4];
L2:[-1,x-3*y+z,3];
L3:[1,x+3*y-2*z,7];

(%o3) \( [\; 0,x+2y,4 ]\; \)
(%o4) \( [\; -1,x-3y+z,3 ]\; \)
(%o5) \( [\; 1,x+3y-2z,7 ]\; \)

得到平行六面體體積
(%i6) Parallelepiped(L1,L2,L3);
取出三個直線的\(x,y,z\)係數\( \left[ \matrix{x+2y \cr x-3y+z \cr x+3y-2z} \right] \)=>\( \left[ \matrix{1&2&0\cr 1&-3&-1\cr 1&3&-2} \right] \),行列式值\(=9\)
\( =|\; (4-0)(3--1)(7-1)/\left[ \matrix{1&2&0\cr 1&-3&1\cr 1&3&-2} \right] |\; \)
\( =|\; 4*4*6/9 |\; \)
\( \displaystyle =\frac{32}{3} \)

(%o6) \( \displaystyle \frac{32}{3} \)

 0≦x+y≦2
求0≦y+z≦2所圍成的平行六面體體積?
 0≦x+z≦2
(102新化高中)

(%i9)
L1:[0,x+y,2];
L2:[0,y+z,2];
L3:[0,x+z,2];

(%o7) \( [\; 0,x+y,2 ]\; \)
(%o8) \( [\; 0,y+z,2 ]\; \)
(%o9) \( [\; 0,x+z,2 ]\; \)

得到平行六面體體積
(%i10) Parallelepiped(L1,L2,L3);
取出三個直線的\(x,y,z\)係數\( \left[ \matrix{x+y \cr y+z \cr x+z} \right] \)=>\( \left[ \matrix{1&1&0\cr 0&1&1\cr 1&0&1} \right] \),行列式值\(=2\)
\( =|\; (2-0)(2-0)(2-0)/\left[ \matrix{1&1&0\cr 0&1&1\cr 1&0&1} \right] |\; \)
\( =|\; 2*2*2/2 |\; \)
\( =4 \)
(%o10) 4

[ 本帖最後由 bugmens 於 2016-12-7 04:14 AM 編輯 ]
作者: bugmens    時間: 2018-6-24 21:58

在坐標平面上以\(\Omega\)表曲線\(y=x-x^2\)與直線\(y=0\)所圍的有界區域。
(1)試求\(\Omega\)的面積。(3分)
(2)若直線\(y=cx\)將\(\Omega\)分成面積相等的兩塊區域,試求\(c\)之值。
(103指考數甲,https://math.pro/db/thread-1992-1-1.html)

(%i1)
HalfArea(y):=block
([Bound,LowerB,UpperB,Area,Equation,c],
print("y=",y,"和x軸交點的x坐標",Bound:sort(solve(y=0,x))),
[LowerB,UpperB]:map(rhs,Bound),
print("∫積分從",LowerB,"到",UpperB,"(",y,")dx=",Area:integrate(y,x,LowerB,UpperB)),
print("y=",y,"和y=cx交點的x坐標",Bound:sort(solve(y=c*x,x))),
[LowerB,UpperB]:map(rhs,Bound),
print("∫積分從",LowerB,"到",UpperB,"(",y-c*x,")dx為原來面積的一半"),
print("積分結果",Equation:factor(integrate(y-c*x,x,LowerB,UpperB)),"=",1/2,"*",Area),
print("去掉分數",Equation: (Equation=1/2*Area)*denom(lhs(Equation))),
print("開三次根號",Equation:Equation^(1/3)),
print("實數",c:solve(Equation,c)[1]),
return(rhs(c))
)$


(%i2)   c:HalfArea(x-x^2);
\(y=x-x^2\)和\(x\)軸交點的\(x\)坐標\( \left[x=0,x=1 \right] \)
∫積分從0到1\(\displaystyle (x-x^2)dx=\frac{1}{6}\)
\(y=x-x^2\)和\(y=cx\)交點的\(x\)坐標\(\left[x=0,x=1-c\right]\)
∫積分從0到\(1-c(-x^2-cx+x)dx\)為原來面積的一半
積分結果\(\displaystyle -\frac{(c-1)^3}{6}=\frac{1}{2}*\frac{1}{6} \)
去掉分數\(\displaystyle -(c-1)^3=\frac{1}{2}\)
開三次根號\( \displaystyle 1-c=\frac{1}{2^{1/3}} \)
實數\( \displaystyle c=\frac{2^{1/3}-1}{2^{1/3}} \)
(%o2) \( \displaystyle \frac{2^{1/3}-1}{2^{1/3}} \)




歡迎光臨 Math Pro 數學補給站 (https://math.pro/db/) 論壇程式使用 Discuz! 6.1.0