發新話題
打印

用Maxima解題

推到噗浪
推到臉書
設a與b均為整數。已知\( ax^5+bx^4+1 \)可被\( x^2-x-1 \)整除,試求\( a+b \)之值。
(1999TRML接力賽)

已知多項式\( ax^9+bx^8+1 \)被\( x^2-x-1 \)整除,則數對\( (a,b)= \)?
(2006年中一中第1次學測模擬考,http://jflaith.myweb.hinet.net/ra/RA130.swf)

已知m,n是整數,且\( mx^{17}+nx^{16}+1 \)是\( x^2+x-1 \)的倍式,則m=?
(97中和高中)
這題問的是\( x^2+x-1 \)答案是-987
和下面幾題\( x^2-x-1 \)答案是+987,要注意

Find a if a and b are integers such that \( x^2-x-1 \) is a factor of \( ax^{17}+bx^{16}+1 \).
(1988AIME)

\( a,b \in Z \),若\( ax^{17}+bx^{16}+1 \)能被\( x^2-x-1 \)整除,求\( a= \)?
(94嘉義女中,http://forum.nta.org.tw/oldphpbb2/viewtopic.php?t=21358)

設a,b為整數,且\( x^2-x-1 \)整除\( ax^{17}+bx^{16}+1 \),試求a之值?
(2006TRML團體賽)

已知a,b為實數,若\( ax^{17}+bx^{16}+1 \)能被\( x^2-x-1 \)整除,則a=?
(100麗山高中,https://math.pro/db/thread-1138-1-1.html)
(100楊梅高中,https://math.pro/db/thread-1162-1-2.html)



(%i) fx:a*x^17+b*x^16+1;
(%o1) \( ax^{17}+bx^{16}+1 \)

將x^2換成x+1降次方,直到最高次方為1次停止
(%i2) 
while (hipow(fx,x)>1) do
  (fx:ratsubst(x+1,x^2,fx),
   print(fx)
  )$

(%o2)
\( ax^9+(b+8a)x^8+(8b+28a)x^7+(28b+56a)x^6+(56b+70a)x^5+(70b+56a)x^4+(56b+28a)x^3+(28b+8a)x^2+(8b+a)x+b+1 \)
\( ax^5+(9b+40a)x^4+(112b+248a)x^3+(352b+528a)x^2+(384b+448a)x+128b+128a+1 \)
\( ax^3+(121b+290a)x^2+(866b+1305a)x+489b+696a+1 \)
\( ax^2+(987b+1596a)x+610b+986a+1 \)
\( (987b+1597a)x+610b+987a+1 \)

x項和常數項係數為0,解a,b
987b+1597a=0
610b+987a+1=0

(%i3) solve([coeff(fx,x,1)=0,coeff(fx,x,0)=0],[a,b]);
(%o3) \( [ [a=987,b=-1597] ] \)

利用for迴圈,將前16項的答案列出來發現和費波那契數列有關係
(%i4) 
for i:1 thru 16 do
  (fx:a*x^(i+1)+b*x^i+1,
   while (hipow(fx,x)>1) do
     (fx:ratsubst(x+1,x^2,fx)),
   print(fx,solve([coeff(fx,x,1)=0,coeff(fx,x,0)=0],[a,b]))
  )$

(%o4) 
\( (b+a)x+a+1 [ [a=-1,b=1] ] \)
\( (b+2a)x+b+a+1 [ [a=1,b=-2] ] \)
\( (2b+3a)x+b+2a+1 [ [a=-2,b=3] ] \)
\( (3b+5a)x+2b+3a+1 [ [a=3,b=-5] ] \)
\( (5b+8a)x+3b+5a+1 [ [a=-5,b=8] ] \)
\( (8b+13a)x+5b+8a+1 [ [a=8,b=-13] ] \)
\( (13b+21a)x+8b+13a+1 [ [a=-13,b=21] ] \)
\( (21b+34a)x+13b+21a+1 [ [a=21,b=-34] ] \)
\( (34b+55a)x+21b+34a+1 [ [a=-34,b=55] ] \)
\( (55b+89a)x+34b+55a+1 [ [a=55,b=-89] ] \)
\( (89b+144a)x+55b+89a+1 [ [a=-89,b=144] ] \)
\( (144b+233a)x+89b+144a+1 [ [a=144,b=-233] ] \)
\( (233b+377a)x+144b+233a+1 [ [a=-233,b=377] ] \)
\( (377b+610a)x+233b+377a+1 [ [a=377,b=-610] ] \)
\( (610b+987a)x+377b+610a+1 [ [a=-610,b=987] ] \)
\( (987b+1597a)x+610b+987a+1 [ [a=987,b=-1597] ] \)



可以看到\( a,b \)形成費波那契數列,考試時加一加就可以得到答案
而且610*b+987a+1=0,可視為-F(15)*F(17)+F(16)*F(16)+1=0
在 http://en.wikipedia.org/wiki/Fibonacci_number 可以找到一般式
\( (-1)^n=F_{n+1}F_{n-1}-F^2_n \)

100.11.28補充
原來這恆等式是有名字的
http://en.wikipedia.org/wiki/Cassini_and_Catalan_identities
http://mathworld.wolfram.com/CassinisIdentity.html

[ 本帖最後由 bugmens 於 2011-11-28 06:45 AM 編輯 ]

TOP


利用部分分式求積分
(%i1) 'integrate(x/(x^3+4*x^2+5*x+2), x);
(%o1) \( \displaystyle \int \frac{x}{x^3+4x^2+5x+2}dx \)

找出分母的因式
(%i2) factor(denom(part(%,1)));
(%o2) \( (x+1)^2(x+2) \)

設定部分分式,假設a,b,c為各分式的係數
(%i3) part(%o1,1)=a/(x+2)+b/(x+1)+c/(x+1)^2;
(%o3) \( \displaystyle \frac{x}{x^3+4x^2+5x+2}=\frac{a}{x+2}+\frac{b}{x+1}+\frac{c}{(x+1)^2} \)

分式通分
(%i4) ratsimp(%);
(%o4) \( \displaystyle \frac{x}{x^3+4x^2+5x+2}=\frac{(b+a)x^2+(c+3b+2a)x+2c+2b+a}{x^3+4x^2+5x+2} \)

去掉分母
(%i5) %*denom(lhs(%));
(%o5) \( x=(b+a)x^2+(c+3b+2a)x+2c+2b+a \)

比較等號兩邊x^2項,x項,常數項係數
(%i6) coeff(%o5,x,0);coeff(%o5,x,1);coeff(%o5,x,2);
(%o6) \( 0=2c+2b+a \)
(%o7) \( 1=c+3b+2a \)
(%o8) \( 0=b+a \)

解出未知數a,b,c
(%i9) solve([%o6,%o7,%o8],[a,b,c]);
(%o9) \( [ [a=-2,b=2,c=-1] ] \)

將a,b,c代回部分分式
(%i10) ev(%o3,part(%o9,1));
(%o10) \( \displaystyle \frac{x}{x^3+4x^2+5x+2}=-\frac{2}{x+2}+\frac{2}{x+1}-\frac{1}{(x+1)^2} \)

或者一開始用partfrac直接得到部分分式
(%i11) partfrac(part(%o1,1),x);
(%o11) \( \displaystyle -\frac{2}{x+2}+\frac{2}{x+1}-\frac{1}{(x+1)^2} \)

將各部分分式積分
(%i12) integrate(%, x);
(%o12) \( \displaystyle -2 log(x+2)+2 log(x+1)+\frac{1}{x+1} \)

答案就和integrate指令算出來的結果相同
(%i13) integrate(x/(x^3+4*x^2+5*x+2), x);
(%o13) \( \displaystyle -2 log(x+2)+2 log(x+1)+\frac{1}{x+1} \)

TOP

版大您好,我想請教一下您是如何將下列的內容擷取出來的,
(%i4) ratsimp(%o2*x-%o1);  ratsimp(%o3*y-%o2);  ratsimp(%o1*z-%o3);
(%o4) x2
yz
−x=5x−12
(%o5) xy
2
z
−y
=6y
−5
(%o6) xyz
2
−z
=12z
−6
我使用複製會變成下面的樣子
/* [wxMaxima: input   start ] */
ratsimp(%o2*x-%o1);  ratsimp(%o3*y-%o2);  ratsimp(%o1*z-%o3);
/* [wxMaxima: input   end   ] */
選擇copy as image會變成圖檔,怎麼試就是試不出來變成您post的內容那樣有紅色和藍色且可以選取複製,我使用的是0.8.3的版本,謝謝!

TOP

回答上面的問題
maxima沒有直接轉換的指令,這是我用論壇的指令拼湊出來的
全形的[和]請自行替換成半形的[和]

[img]h ttp://www.permucode.com/maxima/wxm_ul.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_uc.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_ur.gif[/img]

[color=red](%i1)[/color] [color=blue]x^2-4xy+6y^2-2x-20y-29[/color]
[color=red](%o1)[/color] \( 6y^2-4xy-20y+x^2-2x-29 \)

[img]h ttp://www.permucode.com/maxima/wxm_ll.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_lc.gif[/img]
[img]h ttp://www.permucode.com/maxima/wxm_lr.gif[/img]


-------------------------
求\( x^2-4xy+6y^2-2x-20y=29 \)的正整數解。
(91高中數學能力競賽 台中區複賽試題(二))
http://www.math.nuk.edu.tw/senpengeu/HighSchool/2003_Taiwan_High_Taichung_02.pdf


(%i1) x^2-4*x*y+6*y^2-2*x-20*y-29
(%o1) \( 6y^2-4xy-20y+x^2-2x-29 \)

先整理成x的方程式
(%i2) collectterms(%o1,x);
(%o2) \( 6y^2-20y+x(-4y-2)+x^2-29 \)

(%i3) a:coeff(%o1,x,2);b:coeff(%o1,x,1);c:coeff(%o1,x,0);
(%o3) 1
(%o4) \( -4y-2 \)
(%o5) \( 6y^2-20y-29 \)

求x的判別式
(%i6) b^2-4*a*c;
(%o6) \( (-4y-2)^2-4(6y^2-20y-29) \)

或者用poly_discriminant得判別式
(%i7) poly_discriminant(%o1,x);
(%o7) \( -8y^2+96y+120 \)

(%i8) load("solve_rat_ineq.mac");
(%o8) C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.19.2/share/contrib/solve_rat_ineq.mac

解出y的範圍
(%i9) solve_rat_ineq(%o6>=0);
(%o9) \( [ [y\ge 6-\sqrt{51},y\le \sqrt{51}+6] ] \)

(%i10) float(%[1]);
(%o10) \( [ y \ge -1.14142842854285,y \le 13.14142842854285 ] \)

(%i11)
solution:[]$
for valy:-1 thru 13 do           /*y值從-1到13一個個檢驗*/
  (fx:ev(%o1,y:valy),           /*y代回原方程式*/
   for x in solve(fx,x) do      /*對x解方程式*/
     (valx:rhs(x),
      if numberp(valx)=true then/*若x是整數,就放到solution*/
        solution:append(solution,[[valx,valy]])
     )
  )$
print(solution);

(%o13) \( [ [-3,-1],[1,-1],[21,5],[1,5],[25,7],[5,7],[25,13],[29,13] ] \)

(%i14) load(draw);
(%o14) C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.19.2/share/draw/draw.lisp

將圓錐曲線和8個點畫出來
(%i15)
draw2d(xtics =1,   /*x軸的間隔為1*/
       ytics = 1,  /*y軸的間隔為1*/
       grid = true,/*顯示格線*/
       /*畫出圓錐曲線*/
       implicit(%o1=0,x,-5,31,y,-2,15),
       point_type = 7,
       point_size = 1,
       points(solution)/*畫出整數點座標*/
      )$




[ 本帖最後由 bugmens 於 2013-4-24 05:10 PM 編輯 ]

TOP

已知\( x,y,z \)均為實數,且\( 2^x+3^y+5^z=7 \),\( 2^{x-1}+3^y+5^{z+1}=11 \),
若\( t=2^{x+1}+3^y+5^{z-1} \),試求t的範圍。(98高雄市聯招)
感謝站長提供解法 https://math.pro/db/thread-797-1-2.html


(%i1) [2^x+3^y+5^z=7,2^(x-1)+3^y+5^(z+1)=11,2^(x+1)+3^y+5^(z-1)=t];
(%o1) \( [5^z+3^y+2^x=7,5^{z+1}+3^y+2^{x-1}=11,5^{z-1}+3^y+2^{x+1}=t] \)

令a=2^x,b=3^y,c=5^z
(%i2) scsimp(%,a=2^x,b=3^y,c=5^z);
(%o2) \( \displaystyle [c+b+a=7,5c+b+\frac{a}{2}=11,\frac{c}{5}+b+2a=t] \)

計算a+b+c=7,a/2+b+5c=11的參數解
(%i3) solve([%[1],%[2]],[a,b,c]);
(%o3) \( [ [a=8%r1-8,b=15-9%r1,c=%r1] ] \)

a,b,c都是正數
(%i4) map (lambda ([x], rhs(x)>0), %[1]);
(%o4) \( [8%r1-8>0,15-9%r1>0,%r1>0] \)

(%i5) load(fourier_elim);
(%o5) C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.19.2/share/contrib/fourier_elim/fourier_elim.lisp

從a>0,b>0,c>0解出%r1的範圍
(%i6) fourier_elim(%o4,[%r1]);
(%o6) \( \displaystyle [1<%r1,%r1<\frac{5}{3}] \)

將a=8%r1-8,c=15-9%r1,c=%r1代回2a+b+c/5=t
(%i7) ev(%o2[3],%o3[1]);
(%o7) \( \displaystyle 2(8%r1-8)-\frac{44%r1}{5}+15=t \)

%r1用t表示
(%i8) solve(%,[%r1]);
(%o8) \( \displaystyle [%r1=\frac{5t+5}{36}] \)

(%i9) ev(%o6,%o8[1]);
(%o9) \( \displaystyle [1<\frac{5t+5}{36},\frac{5t+5}{36}<\frac{5}{3}] \)

再解出t的範圍
(%i10) fourier_elim(%,[t]);
(%o10) \( \displaystyle [\frac{31}{5}<t,t<11] \)



[ 本帖最後由 bugmens 於 2009-12-3 10:21 PM 編輯 ]

TOP

給定坐標平面上的一錐線C:\( 5x^2-6xy+5y^2-16=0 \)。
(1)若直線L:\( x=3+\alpha t \),\( y=1+\beta t \)(\( t \in R \))與錐線C相切,試求斜率\( \displaystyle \frac{\beta}{\alpha} \)的所有可能值。(10分)
(2)若過點\( T(u,v) \)有一對垂直線與錐線C都相切,試證:\( u^2+v^2-10=0 \)。(10分)
(95台灣師大在職專班)

以下是第1小題

(%i1) 5*x^2-6*x*y+5*y^2-16;
(%o1) \( 5y^2-6xy+5x^2-16 \)

將x=3+αt,y=1+βt代入錐線C
(%i2) ev(%,[x=3+%alpha*t,y=1+%beta*t]);
(%o2) \( 5(\beta t+1)^2-6(\alpha t+3)(\beta t+1)+5(\alpha t+3)^2-16 \)

展開後重新整理成t的方程式
(%i3) collectterms(expand(%),t);
(%o3) \( (5 \beta^2-6 \alpha \beta+5 \alpha^2)t^2+(24 \alpha-8 \beta)t+16 \)

取出各項的係數
(%i4)
a:coeff(%o3,t,2);
b:coeff(%o3,t,1);
c:coeff(%o3,t,0);

(%o4) \( 5\beta^2-6\alpha \beta+5 \alpha^2 \)
(%o5) \( 24\alpha-8 \beta \)
(%o6) \( 16 \)

因為直線L和錐線C相切,故判別式為0
(%i7) b^2-4*a*c=0;expand(%);
(%o7) \( (24 \alpha-8 \beta)^2-64(5 \beta^2-6 \alpha \beta+5 \alpha^2)=0 \)
(%o8) \( 256\alpha^2-256 \beta^2=0 \)

得到的兩個答案
(%i9) solve(%,%beta);  %/%alpha;
(%o9) \( [\beta=-\alpha,\beta=\alpha] \)
(%o10) \( \displaystyle [\frac{\beta}{\alpha}=-1,\frac{\beta}{\alpha}=1] \)






第2小題

(%i1) 5*x^2-6*x*y+5*y^2-16;
(%o1) \( 5y^2-6xy+5x^2-16 \)

假設切線為y=mx+k,代入錐線C
(%i2) y=m*x+k;  ev(%o1,%);
(%o2) \( y=mx+k \)
(%o3) \( 5(mx+k)^2+5x^2-6x(mx+k)-16 \)

展開後重新整理成x的方程式
(%i4) collectterms(expand(%),x);
(%o4) \( (5m^2-6m+5)x^2+(10km-6k)x+5k^2-16 \)

取出各項係數
(%i4)
a:coeff(%o4,x,2);
b:coeff(%o4,x,1);
c:coeff(%o4,x,0);

(%o5) \( 5m^2-6m+5 \)
(%o6) \( 10km-6k \)
(%o7) \( 5k^2-16 \)

因為這對垂直線和錐線C相切,故判別式為0
(%i8) b^2-4*a*c;  expand(%);
(%o8) \( (10km-6k)^2-4(5k^2-16)(5m^2-6m+5) \)
(%o9) \( 320m^2-384m-64k^2+320 \)

又因為兩切線垂直,從根與係數的關係可知c/a=-1
(%i10) coeff(%o9,m,0)/coeff(%o9,m,2)=-1;
(%o10) \( \displaystyle \frac{320-64k^2}{320}=-1 \)

解出k,得到兩切線
(%i11) solve(%,[k]);  map(lambda([t],ev(%o2,t)),%);
(%o11) \( [k=-\sqrt{10},k=\sqrt{10}] \)
(%o12) \( [y=mx-\sqrt{10},y=mx+\sqrt{10}] \)

T(u,v)在兩切線上,代入直線方程式
(%i13) ev(%,[x=u,y=v]);
(%o13) \( [v=mu-\sqrt{10},v=mu+\sqrt{10}] \)

又兩切線互相垂直,故斜率相乘為-1
(%i14) 
map(lambda([t],solve(t,[m])),%);
rhs(%[1][1])*rhs(%[2][1])=-1;

(%o14) \( \displaystyle [ [m=\frac{v+\sqrt{10}}{u}],[m=\frac{v-\sqrt{10}}{u}] ] \)
(%o15) \( \displaystyle \frac{(v-\sqrt{10})(v+\sqrt{10})}{u^2}=-1 \)

化簡後得到答案
(%i16) ratsimp(%*u^2+u^2);
(%o16) \( v^2+u^2-10=0 \)



[ 本帖最後由 bugmens 於 2010-1-28 12:14 AM 編輯 ]

TOP

求\( x^2+2y^2=4 \)與\( y^2=4\sqrt{2}x \)的公切線方程式?
https://math.pro/db/thread-903-1-1.html


假設切線為y=mx+b
(%i1) y=m*x+b;
(%o1) \( y=mx+b \)

將y=mx+b代入x^2+2y^2=4
(%i2) ev(x^2+2*y^2-4,%o1);
(%o2) \( 2(mx+b)^2+x^2-4 \)

展開後重新整理成x的方程式
(%i3) collectterms(expand(%),x);
(%o3) \( (2m^2+1)x^2+4bmx+2b^2-4 \)

因為直線和橢圓相切,故判別式為0
(%i4) poly_discriminant(%,x)=0;
(%o4) \( 32m^2-8b^2+16=0 \)

將y=mx+b代入y^2=4√2x
(%i5) ev(y^2-4*sqrt(2)*x,%o1);
(%o5) \( (mx+b)^2-2^{5/2}x \)

展開後重新整理成x的方程式
(%i6) collectterms(expand(%),x);
(%o6) \( m^2x^2+(2bm-2^{5/2})x+b^2 \)

因為直線和拋物線相切,故判別式為0
(%i7) poly_discriminant(%,x)=0;
(%o7) \( 32-2^{9/2}bm=0 \)


從(%o4) 32m^2-8b^2+16=0
 (%o7) 32-2^(9/2)*bm=0
解出m,b

(%i8) solve([%o4,%o7],[m,b]);
(%o8) \( \displaystyle [ [m=-\frac{1}{\sqrt{2}},b=-2],[m=\frac{1}{\sqrt{2}},b=2],[m=-%i,b=\sqrt{2}%i],[m=%i,b=-\sqrt{2}%i] ] \)

得到兩條切線方程式
(%i9) 
ev(%o1,%o8[1]);
ev(%o1,%o8[2]);

(%o9) \( \displaystyle y=-\frac{x}{\sqrt{2}}-2 \)
(%o10) \( \displaystyle y=\frac{x}{\sqrt{2}}+2 \)



[ 本帖最後由 bugmens 於 2010-2-10 12:30 PM 編輯 ]

TOP

求\( 5x^2-6xy+5y^2-4x-4y+5 \)的最小值,此時x=?,y=?

maxima沒有內建的配方法指令
參考Barton Willis所寫的配方法
http://www.math.utexas.edu/pipermail/maxima/2007/008787.html

(%i1) 
sfactor(p,x) := block([n, cf, s, d],
  p : expand(p),
  n : hipow(p,x),
  if oddp(n) or n = 0 then p else (
   cf : coeff(p,x,n),
   s : x^(n/2),
   d : expand(cf * s^2 - p),
   while hipow(d,x) > 0 do (
     d : expand(first(divide(cf * s^2 - p, 2 * cf * s))),
     s : s - d),
   cf * s^2 + sfactor(p - cf * s^2,x)))$


(%i2) 5*x^2-6*x*y+5*y^2-4*x-4*y+5
(%o2) \( 5y^2-6xy-4y+5x^2-4x+5 \)

先對y配方法
(%i3) sfactor(%,y);
(%o3) \( \displaystyle 5(y-\frac{3x}{5}-\frac{2}{5})^2+\frac{16x^2}{5}-\frac{32x}{5}+\frac{21}{5} \)

再對x配方法
(%i4) part(%,1)+sfactor(rest(%,1),x);
(%o4) \( \displaystyle 5(y-\frac{3x}{5}-\frac{2}{5})^2+\frac{16(x-1)^2}{5}+1 \)

當y-3x/5-2/5=0,x-1=0時有最小值
(%i5) solve([part(%,1),part(%,2)],[x,y]);
(%o5) \( [ [x=1,y=1] ] \)


當x=1,y=1時有最小值1


或者題目太複雜了,改用偏微分解題
Find the minimum value of \( 2x^2+2y^2+5z^2-2xy-4yz-4x-2z+15 \) for real numbers x, y,z.
USA Stanford Mathematics Tournament 2006
http://www.artofproblemsolving.c ... d=166&year=2006

(%i1) 2*x^2+2*y^2+5*z^2-2*x*y-4*y*z-4*x-2*z+15;
(%o1) \( 5z^2-4yz-2z+2y^2-2xy+2x^2-4x+15 \)

分別對x,y,z偏微分
(%i2) 
diff(%o1,x,1)=0;
diff(%o1,y,1)=0;
diff(%o1,z,1)=0;

(%o2) \( -2y+4x-4=0 \)
(%o3) \( -4z+4y-2x=0 \)
(%o4) \( 10z-4y-2=0 \)

解出x,y,z
(%i5) solve([%o2,%o3,%o4],[x,y,z]);
(%o5) \( [ [x=2,y=2,z=1] ] \)

x,y,z代回原式得最小值
(%i6) ev(%o1,%o5[1]);
(%o6) \( 10 \)


當x=2,y=2,z=1時有最小值10

[ 本帖最後由 bugmens 於 2013-4-27 09:15 PM 編輯 ]

TOP

若\( A=\Bigg[\; \matrix{2 & -2 \cr -3 & 1} \Bigg]\; \),試利用矩陣的對角線化方法求\( A^n \),其中n為自然數。
(99明倫高中,https://math.pro/db/thread-959-1-3.html)

若\( A=\Bigg[\; \matrix{1 & 1 \cr 2 & 0} \Bigg]\; \),求\( A^{50} \)。
(99國立清水高中,https://math.pro/db/thread-1017-1-1.html)


定義A矩陣
(%i1) A:matrix([2,-2],[-3,1]);
(%o1) \( \Bigg[\; \matrix{2 & -2 \cr -3 & 1} \Bigg]\; \)

定義2階單位矩陣
(%i2) I: ident(2);
(%o2) \( \Bigg[\; \matrix{1 & 0 \cr 0 & 1} \Bigg]\; \)

解特徵方程式
(%i3) determinant(A-x*I)=0;solve(%,x);
(%o3) \( (1-x)(2-x)-6=0 \)
(%o4) \( [\ x=4,x=-1 ]\ \)

第一個特徵向量
(%i5) A-rhs(%o4[1])*I;
(%o5) \( \Bigg[\; \matrix{-2 & -2 \cr -3 & -3} \Bigg]\; \)

(%i6) transpose(matrix([%o5[1][2],-%o5[1][1]]));
(%o6) \( \Bigg[\; \matrix{-2 \cr 2} \Bigg]\; \)

第二個特徵向量
(%i7) A-rhs(%o4[2])*I;
(%o7) \( \Bigg[\; \matrix{3 & -2 \cr -3 & 2} \Bigg]\; \)

(%i8) transpose(matrix([%o7[1][2],-%o7[1][1]]));
(%o8) \( \Bigg[\; \matrix{-2 \cr -3} \Bigg]\; \)

定義特徵矩陣為P
(%i9) P:addcol(%o6,%o8);
(%o9) \( \Bigg[\; \matrix{-2 & -2 \cr 2 & -3} \Bigg]\; \)

P的反矩陣
(%i10) invP:invert(P);
(%o9) \( \displaystyle \Bigg[\; \matrix{-\frac{3}{10} & \frac{1}{5} \cr -\frac{1}{5} & -\frac{1}{5}} \Bigg]\; \)

注意:矩陣乘法用.而不是*
(%i11) D:invP.A.P;
(%o11) \( \Bigg[\; \matrix{4 & 0 \cr 0 & -1} \Bigg]\; \)

答案
(%i12) P.D^n.invP;
(%o12) \( \displaystyle \left[ \matrix{\displaystyle \frac{3 \cdot 4^n}{5}+\frac{2 \cdot (-1)^n}{5} & \frac{2 \cdot (-1)^n}{5}-\frac{2 \cdot 4^n}{5} \cr \frac{3 \cdot (-1)^n}{5}-\frac{3 \cdot 4^n}{5} & \frac{2 \cdot 4^n}{5}+\frac{3 \cdot (-1)^n}{5}} \right] \)

或是載入linearalgebra套件
(%i13) load(linearalgebra);
(%o13) C:/PROGRA~1/MAXIMA~1.1/share/maxima/5.22.1/share/linearalgebra/linearalgebra.mac

直接呼叫matrixfun求出答案
(%i14) matrixfun(lambda([x],x^n),A);
(%o14) \( \left[ \matrix{\displaystyle \frac{3 \cdot 4^n+2 \cdot (-1)^n}{5} & -\frac{2 \cdot 4^n-2 \cdot (-1)^n}{5} \cr -\frac{3 \cdot 4^n-3 \cdot (-1)^n}{5} & \frac{2 \cdot 4^n+3 \cdot (-1)^n}{5}} \right] \)


-------------------------

101.11.10補充
\( A=\Bigg[\; \matrix{-1 & -9 \cr 1 & -7} \Bigg]\; \),\( A=PDP^{-1} \),且\( \displaystyle P=\Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \),求\( A^n= \)?(答案以n表示,\( n \in N \))
(101松山工農,https://math.pro/db/thread-1482-1-3.html)


載入linearalgebra.mac才能使用matrixfun指令
(%i1) load("linearalgebra.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/linearalgebra/linearalgebra.mac

定義A矩陣
(%i2) A:matrix([-1,-9],[1,-7]);
(%o2) \( \displaystyle \Bigg[\; \matrix{-1 & -9 \cr 1 & -7} \Bigg]\; \)

定義2階單位矩陣
(%i3) I:ident(2);
(%o3) \( \displaystyle \Bigg[\; \matrix{1 & 0 \cr 0 & 1} \Bigg]\; \)

解特徵方程式,但特徵值重根
(%i4) 
determinant(A-x*I)=0;
solve(%,x);

(%o4) \( (-x-7)(-x-1)+9=0 \)
(%o5) \( [ x=-4 ] \)

求第一個特徵向量
(%i6) (A-rhs(%o5[1])*I).matrix([x],[y])=matrix([0],[0]);
(%o6) \( \displaystyle \Bigg[\; \matrix{3x-9y \cr x-3y} \Bigg]\;=\Bigg[\; \matrix{0 \cr 0} \Bigg]\; \)

(%i7) 
lhs(%)[1][1]=rhs(%)[1][1];
solve(%,[x,y]);
ev(%,%r1=1);
ev(matrix([x],[y]),%[1]);

(%o7) \( 3x-9y=0 \)
(%o8) \( [ [x=3%r1,y=%r1] ] \)
(%o9) \( [ [x=3,y=1] ] \)
(%o10) \( \displaystyle \Bigg[\; \matrix{3 \cr 1} \Bigg]\; \)

求第二個特徵向量
(%i11) (A-rhs(%o5[1])*I).matrix([x],[y])=%;
(%o11) \( \displaystyle \Bigg[\; \matrix{3x-9y \cr x-3y} \Bigg]\;=\Bigg[\; \matrix{3 \cr 1} \Bigg]\; \)

(%i12) 
lhs(%)[1][1]=rhs(%)[1][1];
solve(%,[x,y]);
ev(%,%r2=0);
ev(matrix([x],[y]),%[1]);

(%o12) \( 3x-9y=3 \)
(%o13) \( [ [x=3%r2+1,y=%r2] ] \)
(%o14) \( [ [x=1,y=0] ] \)
(%o15) \( \displaystyle \Bigg[\; \matrix{1 \cr 0} \Bigg]\; \)

兩個特徵向量形成P矩陣
(%i16) P:addcol(%o10,%o15);
(%o16) \( \displaystyle \Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \)

求P的反矩陣
(%i17) inv_P:invert(P);
(%o17) \( \displaystyle \Bigg[\; \matrix{0 & 1 \cr 1 & -3} \Bigg]\; \)

D=P^-1.A.P
矩陣乘法用的是.不是*

(%i18) D:inv_P.A.P;
(%o18) \( \displaystyle \Bigg[\; \matrix{-4 & 1 \cr 0 & -4} \Bigg]\; \)

計算D的n次方
因為這裡的D矩陣不是對角矩陣,無法直接用D^n計算矩陣n次方,所以改用matrixfun來計算

(%i19) matrixfun(lambda([x],x^n),D);
(%o19) \( \displaystyle \Bigg[\; \matrix{(-4)^n & n(-4)^{n-1} \cr 0 & (-4)^n} \Bigg]\; \)

計算A^n=P.D^n.P^-1
(%i20) P.%.inv_P;
(%o20) \( \displaystyle \Bigg[\; \matrix{(-4)^n+3n(-4)^{n-1} & 3((-4)^n-3n(-4)^{n-1})-3(-4)^n \cr n(-4)^{n-1} & (-4)^n-3n(-4)^{n-1}} \Bigg]\; \)

A^n簡化後得到答案
(%i21) ratsimp(%);
(%o21) \( \displaystyle \Bigg[\; \matrix{(3n-4)(-4)^{n-1} & -9n(-4)^{n-1} \cr n(-4)^{n-1} & -(3n+4)(-4)^{n-1}} \Bigg]\; \)

就和matrixfun所計算A^n的結果相同
(%i22) matrixfun(lambda([x],x^n),A);
(%o22) \( \displaystyle \Bigg[\; \matrix{(3n-4)(-4)^{n-1} & -9n(-4)^{n-1} \cr n(-4)^{n-1} & -(3n+4)(-4)^{n-1}} \Bigg]\; \)


參考資料
7.THE JORDAN CANONICAL FORM
https://math.pro/db/attachment.p ... 87&t=1407797768



利用diag.mac所提供的指令來計算矩陣n次方


要載入diag.mac才能使用jordan,ModeMatrix,dispJordan指令
(%i1) load("diag.mac");
(%o1) C:/PROGRA~1/MAXIMA~1.0-2/share/maxima/5.28.0-2/share/contrib/diag.mac

定義A矩陣
(%i2) A:matrix([-1,-9],[1,-7]);
(%o2) \( \displaystyle \Bigg[\; \matrix{-1 & -9 \cr 1 & -7} \Bigg]\; \)

計算A的特徵根-4,代數重數2(重根)
(%i3) EigenValue:jordan(A);
(%o3) \( [ [-4,2] ] \)

求得P矩陣
(%i4) P:ModeMatrix(A,EigenValue);
(%o4) \( \displaystyle \Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \)

P的反矩陣
(%i5) inv_P:invert(P);
(%o5) \( \displaystyle \Bigg[\; \matrix{0 & 1 \cr 1 & -3} \Bigg]\; \)

求得D矩陣
(%i6) D:dispJordan(EigenValue);
(%o6) \( \displaystyle \Bigg[\; \matrix{-4 & 1 \cr 0 & -4} \Bigg]\; \)

計算D的n次方
(%i7) matrixfun(lambda([x],x^n),D);
(%o7) \( \displaystyle \Bigg[\; \matrix{(-4)^n & n(-4)^{n-1} \cr 0 & (-4)^n} \Bigg]\; \)

計算A^n=P.D^n.P^-1
(%i8) P.%.inv_P;
(%o8) \( \displaystyle \Bigg[\; \matrix{(-4)^n+3n(-4)^{n-1} & 3((-4)^n-3n(-4)^{n-1})-3(-4)^n \cr n(-4)^{n-1} & (-4)^n-3n(-4)^{n-1}} \Bigg]\; \)

A^n簡化後得到答案
(%i9) ratsimp(%);
(%o9) \( \Bigg[\; \matrix{\displaystyle (3n-4)(-4)^{n-1} & -9n(-4)^{n-1} \cr n(-4)^{n-1} & -(3n+4)(-4)^{n-1}} \Bigg]\; \)



我另外找了兩題也是特徵根相同的題目讓各位練習,因為特徵根是1所以會比較簡單
\( A=\displaystyle \Bigg[\; \matrix{-1 & 4 \cr -1 & 3} \Bigg]\; \),則\( A^n= \)   
[答案]
\( \displaystyle P=\Bigg[\; \matrix{-2 & 1 \cr -1 & 0} \Bigg]\; \),\( \displaystyle P^{-1}=\Bigg[\; \matrix{0 & -1 \cr 1 & -2} \Bigg]\; \)
\( \displaystyle D=\Bigg[\; \matrix{1 & 1 \cr 0 & 1} \Bigg]\; \),\( \displaystyle D^n=\Bigg[\; \matrix{1 & n \cr 0 & 1} \Bigg]\; \)
\( \displaystyle A^n=P.D^n.P^{-1}=\Bigg[\; \matrix{1-2n & 4n \cr -n & 2n+1} \Bigg]\; \)


\( A=\displaystyle \Bigg[\; \matrix{4 & -9 \cr 1 & -2} \Bigg]\; \),則\( A^n= \)   
[答案]
\( \displaystyle P=\Bigg[\; \matrix{3 & 1 \cr 1 & 0} \Bigg]\; \),\( \displaystyle P^{-1}=\Bigg[\; \matrix{0 & 1 \cr 1 & -3} \Bigg]\; \)
\( \displaystyle D=\Bigg[\; \matrix{1 & 1 \cr 0 & 1} \Bigg]\; \),\( \displaystyle D^n=\Bigg[\; \matrix{1 & n \cr 0 & 1} \Bigg]\; \)
\( \displaystyle A^n=P.D^n.P^{-1}=\Bigg[\; \matrix{3n+1 & -9n \cr n & 1-3n} \Bigg]\; \)


103.8.11補充
設\( I=\left[ \matrix{1 & 0 \cr 0 & 1} \right] \),\( N=\left[ \matrix{1 & 1 \cr -1 & -1} \right] \),求\( (2I-N)^{103}= \)?
(103南大附中,https://math.pro/db/viewthread.php?tid=1942&page=4#pid11839)
有完整的計算式子

[ 本帖最後由 bugmens 於 2014-8-12 07:05 AM 編輯 ]

TOP

2009用2個或2個以上連續的整數表示,有幾種表示法?
https://math.pro/db/thread-827-1-1.html


從m開始加n個數總和為2009
(%i1) sum(m+(k-1)*1,k,1,n)=2009;
(%o1) \( \displaystyle \sum_{k=1}^{n}m+k-1=2009 \)

載入simplify_sum套件,計算出總和
(%i2) load("simplify_sum");
(%o2) C:/PROGRA~1/MAXIMA~1.1/share/maxima/5.22.1/share/contrib/solve_rec/simplify_sum.mac

(%i3) simplify_sum(%o1);
(%o3) \( \displaystyle \frac{n^2+n}{2}+mn-n=2009 \)

(%i4) ratsimp(%*2);
(%o4) \( n^2+(2m-1)n=4018 \)

(%i5) facout(n,lhs(%))=rhs(%);
(%o5) \( n(n+2m-1)=4018 \)

考慮4018的因數分解
(%i6) d:divisors(rhs(%));
(%o6) {1,2,7,14,41,49,82,98,287,574,2009,4018}

計算出首項和項數
(%i7) 
for divisor in d do
  (fx:ev(%o5,n=divisor),
   solution:solve(fx,[m]),
   if integerp(rhs(solution[1]))=true then
     print("(",rhs(solution[1]),",",divisor,")")
  );

(%o7)
(2009,1)
(1004,2)
(284,7)
(137,14)
(29,41)
(17,49)
(-16,82)
(-28,98)
(-136,287)
(-283,574)
(-1003,2009)
(-2008,4018)
扣除n=1不合的情況,共有11種方法

[ 本帖最後由 bugmens 於 2014-8-12 07:02 AM 編輯 ]

TOP

發新話題