40 1234
發新話題
打印

用Maxima解題

隨機產生數獨
h ttp://www.cymric.jp/maxima/sudoku.html (連結失效)
改放在https://math.pro/db/attachment.p ... 01&t=1538952070

將sudoku.mac放在C:\Program Files\Maxima-5.31.2\share\maxima\5.31.2\share目錄底下
開啟maxima輸入以下的指令

(%i1) load("sudoku.mac");
(%o1) "C:/PROGRA~1/MAXIMA~1.2/share/maxima/5.31.2/share/sudo.mac"

有50%的機會傳回-1代表產生數獨失敗
(%i2) sudoku();
(%o2) \( \displaystyle \left[ \matrix{9 & 2 & 1 & 5 & 3 & 7 & 6 & 8 & 4 \cr
4 & 3 & 7 & 8 & 2 & 6 & 1 & 5 & 9 \cr
6 & 8 & 5 & 4 & 9 & 1 & 3 & 2 & 7 \cr
2 & 1 & 8 & 7 & 6 & 9 & 4 & 3 & 5 \cr
3 & 9 & 4 & 2 & 8 & 5 & 7 & 6 & 1 \cr
7 & 5 & 6 & 1 & 4 & 3 & 2 & 9 & 8 \cr
5 & 4 & 9 & 3 & 7 & 2 & 8 & 1 & 6 \cr
8 & 6 & 3 & 9 & 1 & 4 & 5 & 7 & 2 \cr
1 & 7 & 2 & 6 & 5 & 8 & 9 & 4 & 3} \right] \)

TOP

設銳角三角形ABC的外接圓半徑為8,已知外接圓圓心到\( \overline{AB} \)的距離2,而到\( \overline{BC} \)的距離為7,則\( \overline{AC}= \)?
(102學測)

學測這題只問\( \overline{AC} \)長度所以比較簡單,可以改求外接圓圓心到\( \overline{AC} \)的距離為何?但為了數字好算,我寫了一個小程式來找有哪些正整數解。

設外接圓圓心為R,圓心到\( \overline{AB} \)的距離為a,到\( \overline{BC} \)的距離為b,到\( \overline{CA} \)的距離為c,試找出正整數解\( (a,b,c,R)= \)?

\( \displaystyle sin B=sin(\theta_1+\theta_2)=sin \theta_1 cos \theta_2+cos \theta_1 sin \theta_2=\frac{a}{R} \cdot \frac{\sqrt{R^2-b^2}}{R}+\frac{\sqrt{R^2-a^2}}{R} \cdot \frac{b}{R} \)

AC弧的圓周角為\( \theta_1+\theta_2 \),圓心角為\( 2 \theta \),所以\( 2(\theta_1+\theta_2)=2 \theta \),\( sin(\theta_1+\theta_2)=sin \theta \)

\( \displaystyle \frac{a \sqrt{R^2-b^2}+b \sqrt{R^2-a^2}}{R^2}=\frac{\sqrt{R^2-c^2}}{R} \)

\( a \sqrt{R^2-b^2}+b \sqrt{R^2-a^2}-R \sqrt{R^2-c^2}=0 \)



要檢驗的式子
(%i1) equation:a*sqrt(R^2-b^2)+b*sqrt(R^2-a^2)-R*sqrt(R^2-c^2);
(%o1) \( -R \sqrt{R^2-c^2}+a \sqrt{R^2-b^2}+b \sqrt{R^2-a^2} \)

將符合上式的(a,b,c,R)印出來
(%i2)
for R:3 thru 30 do
  (for c:1 thru R-1 do
     (for b:1 thru c-1 do
        (for a:1 thru b-1 do
           (if ev(equation,[a=a,b=b,c=c,R=R])=0 then
              (print("a=",a,",b=",b,",c=",c,",R=",R)
              )
           )
        )
     )
  );

\( a=2,b=7,c=11,R=14 \)
\( a=2,b=9,c=12,R=16 \)
\( a=6,b=11,c=14,R=21 \)
\( a=1,b=13,c=22,R=26 \)
\( a=4,b=14,c=22,R=28 \)
\( a=3,b=14,c=25,R=30 \)
(%o2) done



範例1:

設銳角三角形\( ABC \)的外接圓半徑為14,已知外接圓圓心到\( \overline{AB} \)的距離2,而到\( \overline{BC} \)的距離為7,則外接圓圓心到\( \overline{CA} \)的距離為?


範例2:
設銳角三角形ABC的外接圓圓心為\( O \),已知圓心\( O \)到\( \overline{AB} \)的距離2,圓心\( O \)到\( \overline{BC} \)的距離為7,圓心\( O \)到\( \overline{CA} \)的距離為11,則外接圓半徑為?
(提示:要改用\( cos(\theta_1+\theta_2)=cos \theta \)計算)


設三角形ABC的外接圓半徑為\( R \),外接圓圓心到三邊的距離為\( a,b,c \),試證:\( R \)為三次方程式\( x^3-(a^2+b^2+c^2)x-2abc=0 \)的一根。

TOP

三個半徑為1的圓兩兩外切且內切於一個正方形,試問正方形的邊長是   
(102松山工農,https://math.pro/db/thread-1655-1-1.html)


正方形邊長為1,內部8個等圓相切如圖,若圓半徑為\( \displaystyle \frac{a+\sqrt{b}-\sqrt{c}}{4} \),其中\( a,b,c \)均為自然數,求\( (a,b,c)= \)   
(103彰化高中科學班,https://math.pro/db/attachment.p ... 9c&t=1441633124)


這個網頁列出了1到24個單位圓的最小正方形邊長為何?
http://www2.stetson.edu/~efriedma/cirinsqu/
我利用maxima的非線性規劃函數fmin_cobyla求2,3,5個單位圓的最小正方形邊長,只是\( n=5 \)時就得不到正確答案。

要先載入fmin_cobyla.mac才能使用fmin_cobyla指令
(%i1) load("fmin_cobyla.mac");
(%o1) C:/Program Files/Maxima-sbcl-5.37.1/share/maxima/5.37.1/share/cobyla/fmin_cobyla.mac

設定5位小數
(%i2) fpprintprec:5;
(%o2) 5

求內含2個單位圓的最小正方形邊長(s=2+√2)
(%i3)
solution:fmin_cobyla(s,[s,x1,y1,x2,y2],[1,1,1,1,1],
                                constraints=[1<=x1,x1<=s-1,
                                                    1<=y1,y2<=s-1,
                                                    1<=x2,x2<=s-1,
                                                    1<=y2,y2<=s-1,
                                                    sqrt((x1-x2)^2+(y1-y2)^2)>=2]);

(%o3) \( [[s=3.4142,x1=2.4142,y1=1.0,x2=1.0,y2=2.4142],3.4142,62,0] \)

求內含3個單位圓的最小正方形邊長(s=2+1/√2+√6/2)
(%i4)
solution:fmin_cobyla(s,[s,x1,y1,x2,y2,x3,y3],[1,1,1,1,1,1,1],
                                constraints=[1<=x1,x1<=s-1,
                                                    1<=y1,y2<=s-1,
                                                    1<=x2,x2<=s-1,
                                                    1<=y2,y2<=s-1,
                                                    1<=x3,x3<=s-1,
                                                    1<=y3,y3<=s-1,
                                                    sqrt((x1-x2)^2+(y1-y2)^2)>=2,
                                                    sqrt((x2-x3)^2+(y2-y3)^2)>=2,
                                                    sqrt((x3-x1)^2+(y3-y1)^2)>=2]);

(%o4) \( [[s=3.9319,x1=1.0,y1=1.0,x2=1.5176,y2=2.9319,x3=2.9319,y3=1.5176],3.9319,111,0] \)

求內含5個單位圓的最小正方形邊長(s=2+2√2)
只是無法得到正確答案

(%i5)
solution:fmin_cobyla(s,[s,x1,y1,x2,y2,x3,y3,x4,y4,x5,y5],[1,2,1,3,1,4,2,4,1,2,1],
                                constraints=[1<=x1,x1<=s-1,
                                                    1<=y1,y2<=s-1,
                                                    1<=x2,x2<=s-1,
                                                    1<=y2,y2<=s-1,
                                                    1<=x3,x3<=s-1,
                                                    1<=y3,y3<=s-1,
                                                    1<=x4,x4<=s-1,
                                                    1<=y4,y4<=s-1,
                                                    1<=x5,x5<=s-1,
                                                    1<=y5,y5<=s-1,
                                                    sqrt((x1-x2)^2+(y1-y2)^2)>=2,
                                                    sqrt((x1-x3)^2+(y1-y3)^2)>=2,
                                                    sqrt((x1-x4)^2+(y1-y4)^2)>=2,
                                                    sqrt((x1-x5)^2+(y1-y5)^2)>=2,
                                                    sqrt((x2-x3)^2+(y2-y3)^2)>=2,
                                                    sqrt((x2-x4)^2+(y2-y4)^2)>=2,
                                                    sqrt((x2-x5)^2+(y2-y5)^2)>=2,
                                                    sqrt((x3-x4)^2+(y3-y4)^2)>=2,
                                                    sqrt((x3-x5)^2+(y3-y5)^2)>=2,
                                                    sqrt((x4-x5)^2+(y4-y5)^2)>=2]);

(%o5) \( [[s=5.0907,x1=1.0,y1=3.0,x2=3.0,y2=1.0,x3=2.6764,y3=4.0907,x4=4.0907,y4=2.6764,x5=1.0,y5=1.0],5.0907,236,0] \)

TOP

原本maxima都是用Gnuplot當作預設的繪圖介面,這個網列有許多maxima和Gnuplot的範例
http://riotorto.users.sourceforge.net/Maxima/vtk/index.html

最新的windows的maxima 5.38加入VTK,關於VTK我取自wiki的介紹。

視覺化工具函式庫(VTK, Visualization Toolkit)是一個開放源碼,跨平台、支援平行處理(VTK曾用於處理大小近乎1個Petabyte的資料,其平台為美國Los Alamos國家實驗室所有的具1024個處理器之大型系統)的圖形應用函式庫。
https://zh.wikipedia.org/wiki/VTK

這個網頁列出非常多maxima和VTK的範例
http://riotorto.users.sourceforge.net/vtk/


(%i1) load("draw") $

(%i2) draw_renderer : 'vtk $

範例取自http://riotorto.users.sourceforge.net/vtk/solids/index.html
(%i3)
draw3d(
    color = red,
    sphere([0,2,0],1),
    color = green,
    sphere([0,2,2],1),
    color = blue,
    sphere([0,2,4],1) ) $

TOP

解\(2x^2-11[\;x ]\;+12=0 \)
(建中通訊解題第24期,http://web2.ck.tp.edu.tw/~mathwe ... 30-15&Itemid=37)

若\(x\)是實數,定義\([\;x ]\;\)表示小於或等於\(x\)的最大整數,試求方程式\( 2x^2-5[\;x ]\;+1=0 \)的解。
(建中通訊解題第52期,http://web2.ck.tp.edu.tw/~mathwe ... 30-15&Itemid=37)

[]表高斯符號,求解\(3x^2-19 \cdot [\;x ]\;+20=0\)。
(105高雄餐旅大學附屬高中,https://math.pro/db/thread-2527-1-2.html)

111.4.24補充
假設\([\; ]\;\)為高斯記號(說明:例如\([\;a ]\;\)表示小於或等於實數\(a\)的最大整數),請求出方程式\(x^2-12[\;x ]\;+11=0\)的所有解   
(111桃園高中,https://math.pro/db/thread-3632-1-1.html)

我以建中通訊解題第24期這題示範如何用maxima解題,網友可自行更換係數測試。

要先載入solve_rat_ineq才能使用solve_rat_ineq指令
(%i1) load("solve_rat_ineq");
(%o1) C:\maxima-5.38.0\share\maxima\5.38.0_dirty\share\solve_rat_ineq\solve_rat_ineq.mac

高斯函數方程式2x^2-11[x]+12=0
(%i2) Equation:2*x^2-11*floor(x)+12;
(%o2) \(-11 floor(x)+2x^2+12 \)

移項得到[x]=(2x^2+12)/11
(%i3) FloorX:solve(Equation,floor(x));
(%o4) \( \displaystyle [\; floor(x)=\frac{2x^2+12}{11} ]\; \)

利用x-1<[x],求x的範圍
(%i4) x-1<rhs(FloorX[1]);
(%o4) \( \displaystyle x-1<\frac{2x^2+12}{11} \)

x的範圍為所有實數
(%i5) solve_rat_ineq(%);
0 errors, 0 warnings
(%o5) all

利用[x]≦x,求x的範圍
(%i6) rhs(FloorX[1])<=x;
(%o6) \( \displaystyle \frac{2x^2+12}{11}<=x \)

x的範圍為3/2≦x≦4
(%i7) solve_rat_ineq(%);
(%o7) \( \displaystyle [\;[\; x>=\frac{3}{2},x<=4 ]\; ]\; \)

3/2≦x≦4範圍內,[x]有2,3,4三種可能
(%i8) FloorXInteger:create_list(x,x,ceiling(rhs(%[1][1])),floor(rhs(%[1][2])));
(%o8) \( [\;2,3,4 ]\; \)

將[x]值代回原方程式,解出x
(%i9)
for floorx in FloorXInteger do
  (print("當[x]=",floorx,"時"),
   equation:ev(Equation,floor(x)=floorx),
   print("解方程式",equation,"=0"),
   solution:solve(equation,x),
   print("解為",solution),
   for sol in solution do
      (X:rhs(sol),
       if floor(rhs(sol))=floorx then
         (print("驗算[",X,"]=",floor(X),"是否等於",floorx,"是,正確答案為",sol))
       else
         (print("驗算[",X,"]=",floor(X),"是否等於",floorx,"否,不為正確答案"))
      ),
     print(" ")
  );

當\([\;x ]\;=2\)時
解方程式\( 2x^2-10=0 \)
解為\( [\;x=-\sqrt{5},x=\sqrt{5} ]\; \)
驗算\([\;-\sqrt{5} ]\;=-3\)是否等於2 否,不為正確答案
驗算\([\; \sqrt{5} ]\;=2\)是否等於2 是,正確答案為\(x=\sqrt{5}\)

當\([\;x ]\;=3\)時
解方程式\(2x^2-21=0\)
解為\( \displaystyle [\;x=-\frac{\sqrt{21}}{\sqrt{2}},x=\frac{\sqrt{21}}{\sqrt{2}} ]\; \)
驗算\( \displaystyle \Bigg[\; -\frac{\sqrt{21}}{\sqrt{2}} \Bigg]\;=-4 \)是否等於3 否,不為正確答案
驗算\( \displaystyle \Bigg[\; \frac{\sqrt{21}}{\sqrt{2}} \Bigg]\;=3 \)是否等於3 是,正確答案為\( \displaystyle x=\frac{\sqrt{21}}{\sqrt{2}} \)

當\([\;x ]\;=4\)時
解方程式\(2x^2-32=0\)
解為\( [\;x=-4,x=4 ]\; \)
驗算\([\;-4 ]\;=-4\)是否等於4 否,不為正確答案
驗算\([\;4 ]\;=4\)是否等於4 是,正確答案為\(x=4\)
(%o9) done

TOP

已知\( \Delta ABC \)三邊所在的三直線\( L_{AB} \):\( a_1x+b_1y=c_1 \),\( L_{AC} \):\( a_2x+b_2y=c_2 \),\( L_{BC} \):\(a_3x+b_3y=c_3\),則\( \Delta \)的面積為\( \displaystyle \frac{1}{2}\frac{\left| \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_3&b_3&c_3} \right|^2}{\left| \matrix{a_1&b_1\cr a_2&b_2} \right| \cdot \left| \matrix{a_2&b_2\cr a_3&b_3} \right| \cdot \left| \matrix{a_3&b_3\cr a_1&b_1} \right|} \)之絕對值。
阮瑞泰(2013):已知三角形三邊所在直線方程式之面積公式。科學教育月刊,362 期(9月號),p43~48。
https://www.sec.ntnu.edu.tw/uplo ... B997-%E5%8D%B0).pdf
陳建燁(2015): 「已知三邊直線方程式之三角形面積公式」的另一種證法。科學教育月刊,第 382 期(9 月號),p32~34。
https://www.sec.ntnu.edu.tw/uplo ... 9C%88%E5%88%8A).pdf

改變變數顯示順序
例:x+y+z+1=0;
原本為z+y+x+1=0;
變成1+x+y+z=0;

(%i1) powerdisp:true;
(%o1) true

計算三角形面積副程式
(%i2)
Triangle(L1,L2,L3):=block
([augcoef,subaugcoef,detaugcoef,detsubaugcoef],
augcoef:augcoefmatrix([L1,L2,L3],[x,y]),
detaugcoef:determinant(augcoef),
print("取出三個直線的係數",matrix([L1],[L2],[L3]),"=>",augcoef,",行列式值=",detaugcoef),
subaugcoef:create_list(submatrix(i,augcoef,3),i,1,3),
detsubaugcoef:create_list(determinant(subaugcoef[ i ]),i,1,3),
print("取",matrix(["L2:",L2],["L3:",L3]),"的x,y係數=>",subaugcoef[1],"行列式值=",detsubaugcoef[1]),
print("取",matrix(["L1:",L1],["L3:",L3]),"的x,y係數=>",subaugcoef[2],"行列式值=",detsubaugcoef[2]),
print("取",matrix(["L1:",L1],["L2:",L2]),"的x,y係數=>",subaugcoef[3],"行列式值=",detsubaugcoef[3]),
print("三角形面積=1/2*",augcoef,"^2/|",subaugcoef[1],subaugcoef[2],subaugcoef[3],"|"),
print("=1/2*",detaugcoef,"^2/|",detsubaugcoef[1],"*",detsubaugcoef[2],"*",detsubaugcoef[3],"|"),
print("=",1/2*detaugcoef^2/abs(detsubaugcoef[1]*detsubaugcoef[2]*detsubaugcoef[3]))
)$


三個直線方程式
(%i5)
L1:x+y=1;
L2:x-y=1;
L3:x+2*y=4;

(%o3) \( x+y=1 \)
(%o4) \( x-y=1 \)
(%o5) \( x+2y=4 \)

得到三角形面積
(%i6) Triangle(L1,L2,L3);
取出三個直線的係數\( \left[ \matrix{x+y=1 \cr x-y=1 \cr x+2y=4} \right] \)=>\( \left[ \matrix{1&1&-1\cr 1&-1&-1\cr 1&2&-4} \right] \),行列式值\(=6\)
取\( \left[ \matrix{L2:&x-y=1 \cr L3:&x+2y=4}\right] \)的\(x,y\)係數=>\( \left[ \matrix{1&-1 \cr 1&2} \right] \)行列式值\(=3\)
取\( \left[ \matrix{L1:&x+y=1 \cr L3:&x+2y=4}\right] \)的\(x,y\)係數=>\( \left[ \matrix{1&1 \cr 1&2} \right] \)行列式值\(=1\)
取\( \left[ \matrix{L1:&x+y=1 \cr L2:&x-y=1}\right] \)的\(x,y\)係數=>\( \left[ \matrix{1&1 \cr 1&-1} \right] \)行列式值\(=-2\)
三角形面積\( =1/2*\left[ \matrix{1&1&-1\cr 1&-1&-1\cr 1&2&-4} \right]^2/|\; \left[ \matrix{1&-1\cr 1&2}\right] \left[ \matrix{1&1\cr 1&2}\right] \left[ \matrix{1&1\cr 1&-1}\right] |\; \)
\( =1/2*6^2/|\; 3*1*-2 |\; \)
\( =3\)
(%o6)
3

___________________________________
在空間中,已知某一四面體\(ABCD\)的四個面所在的平面方程式分別為:
\(E_1\):\( a_1x+b_1y+c_1z+d_1=0 \),\(E_2\):\(a_2x+b_2y+c_2z+d_2=0\)
\(E_3\):\(a_3x+b_3y+c_3z+d_3=0\),\(E_4\):\(a_4x+b_4y+c_4z+d_4=0\)。
令\(A\)為\(E_2,E_3,E_4\)三平面的交點,\(B\)為\(E_1,E_3,E_4\)三平面的交點,
\(C\)為\(E_1,E_2,E_4\)三平面的交點,\(D\)為\(E_1,E_2,E_3\)三平面的交點。
則四面體體積\( \displaystyle V_{ABCD}=\frac{1}{6}\cdot \frac{|\; \left| \matrix{a_1&b_1&c_1&d_1 \cr a_2&b_2&c_2&d_2 \cr a_3&b_3&c_3&d_3 \cr a_4&b_4&c_4&d_4} \right| |\;^3}{|\; \left| \matrix{a_2&b_2&c_2 \cr a_3&b_3&c_3 \cr a_4&b_4&c_4} \right| \cdot \left| \matrix{a_1&b_1&c_1 \cr a_3&b_3&c_3 \cr a_4&b_4&c_4} \right| \cdot \left| \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_4&b_4&c_4} \right| \cdot \left| \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_3&b_3&c_3} \right| |\;} \)。
陳建燁(2015): 已知四面方程式之四面體體積公式。科學教育月刊,第 388 期(5月號),p32~35。
http://www.sec.ntnu.edu.tw/Month ... 公式(修改).pdf

改變變數顯示順序
例:x+y+z+1=0;
原本為z+y+x+1=0;
變成1+x+y+z=0;

(%i1) powerdisp:true;
(%o1) true

計算四面體體積副程式
(%i2)
Tetrahedron(E1,E2,E3,E4):=block
([augcoef,subaugcoef,detaugcoef,detsubaugcoef],
augcoef:augcoefmatrix([E1,E2,E3,E4],[x,y,z]),
print("取出四個平面的係數",matrix([E1],[E2],[E3],[E4]),"=>",augcoef),
subaugcoef:create_list(submatrix(1,augcoef,i),i,1,4),/*針對第1列降階*/
detsubaugcoef:create_list(determinant(subaugcoef[ i ]),i,1,4),
print("針對第1列降階計算行列式值",augcoef),
print("=+",augcoef[1,1],subaugcoef[1],
         "-",augcoef[1,2],subaugcoef[2],
         "+",augcoef[1,3],subaugcoef[3],
         "-",augcoef[1,4],subaugcoef[4]),
print("=+",augcoef[1,1],"*",detsubaugcoef[1],
         "-",augcoef[1,2],"*",detsubaugcoef[2],
         "+",augcoef[1,3],"*",detsubaugcoef[3],
         "-",augcoef[1,4],"*",detsubaugcoef[4]),
print("=",detaugcoef:determinant(augcoef)),
subaugcoef:create_list(submatrix(i,augcoef,4),i,1,4),/*針對第4行降階*/
detsubaugcoef:create_list(determinant(subaugcoef[ i ]),i,1,4),
print("取",matrix(["E2:",E2],["E3:",E3],["E4:",E4]),"的x,y,z係數=>",subaugcoef[1],",行列式值=",detsubaugcoef[1]),
print("取",matrix(["E1:",E1],["E3:",E3],["E4:",E4]),"的x,y,z係數=>",subaugcoef[2],",行列式值=",detsubaugcoef[2]),
print("取",matrix(["E1:",E1],["E2:",E2],["E4:",E4]),"的x,y,z係數=>",subaugcoef[3],",行列式值=",detsubaugcoef[3]),
print("取",matrix(["E1:",E1],["E2:",E2],["E3:",E3]),"的x,y,z係數=>",subaugcoef[4],",行列式值=",detsubaugcoef[4]),
print("四面體體積=1/6*|",augcoef,"|^3/|",subaugcoef[1],"*",subaugcoef[2],"*",subaugcoef[3],"*",subaugcoef[4],"|"),
print("=1/6*|",detaugcoef,"|^3/|",detsubaugcoef[1],"*",detsubaugcoef[2],"*",detsubaugcoef[3],"*",detsubaugcoef[4],"|"),
print("=",1/6*abs(detaugcoef)^3/abs(detsubaugcoef[1]*detsubaugcoef[2]*detsubaugcoef[3]*detsubaugcoef[4]))
)$


4個平面方程式
(%i6)
E1:x+y+z-2=0;
E2:x+y-z=0;
E3:x-y+z=0;
E4:-x+y+z=0;

(%o3) \( -2+x+y+z=0 \)
(%o4) \( x+y-z=0 \)
(%o5) \( x-y+z=0 \)
(%o6) \( -x+y+z=0 \)

得到四面體體積
(%i7) Tetrahedron(E1,E2,E3,E4);
取出四個平面的係數\( \left[ \matrix{-2+x+y+z=0 \cr x+y-z=0 \cr x-y+z=0 \cr -x+y+z=0} \right] \)=>\( \left[ \matrix{1&1&1&-2 \cr 1&1&-1&0 \cr 1&-1&1&0 \cr -1&1&1&0} \right] \)
針對第1列降階計算行列式值\( \left[ \matrix{1&1&1&-2 \cr 1&1&-1&0 \cr 1&-1&1&0 \cr -1&1&1&0} \right] \)
\( =+1 \left[ \matrix{1&-1&0\cr -1&1&0\cr 1&1&0} \right]-1\left[ \matrix{1&-1&0\cr 1&1&0\cr -1&1&0} \right]+1\left[ \matrix{1&1&0\cr 1&-1&0\cr -1&1&0} \right]--2\left[ \matrix{1&1&-1\cr 1&-1&1\cr -1&1&1} \right] \)
\( =+1*0-1*0+1*0--2*-4 \)
\(=-8\)
取\( \left[ \matrix{L2:&x+y-z=0 \cr L3:&x-y+z=0 \cr L4:&-x+y+z=0} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&-1 \cr 1&-1&1 \cr -1&1&1 } \right] \),行列式值\(=-4\)
取\( \left[ \matrix{L1:&-2+x+y+z=0 \cr L3:&x-y+z=0 \cr L4:&-x+y+z=0} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&1 \cr 1&-1&1 \cr -1&1&1 } \right] \),行列式值\(=-4\)
取\( \left[ \matrix{L1:&-2+x+y+z=0 \cr L2:&x+y-z=0 \cr L4:&-x+y+z=0} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&1 \cr 1&1&-1 \cr -1&1&1 } \right] \),行列式值\(=4\)
取\( \left[ \matrix{L1:&-2+x+y+z=0 \cr L2:&x+y-z=0& \cr L3:&x-y+z=0&} \right] \)的\(x,y,z\)係數=>\( \left[ \matrix{1&1&1 \cr 1&1&-1 \cr 1&-1&1} \right] \),行列式值\(-4\)
四面體體積\(=1/6*|\; \left[ \matrix{1&1&1&-2\cr 1&1&-1&0\cr 1&-1&1&0\cr -1&1&1&0}\right] |\;^3/|\; \left[ \matrix{1&1&-1 \cr 1&-1&1 \cr -1&1&1}\right]*\left[ \matrix{1&1&1 \cr 1&-1&1 \cr -1&1&1}\right]*\left[ \matrix{1&1&1 \cr 1&1&-1 \cr -1&1&1}\right]*\left[ \matrix{1&1&1 \cr 1&1&-1 \cr 1&-1&1}\right] |\;\)
\( =1/6*|\; -8 |\;^3/|\; -4*-4*4*-4 |\; \)
\( =\displaystyle \frac{1}{3} \)
(%o7) \( \displaystyle \frac{1}{3} \)

TOP

用行列式計算平面上的平行四邊形面積與空間中的平行六面體體積
https://www.sec.ntnu.edu.tw/uplo ... BF%AE%E6%94%B9).pdf
___________________________________

已知\( \Bigg\{\; \matrix{t_1 \le a_1x+b_1y \le t_2 \cr s_1 \le a_2x+b_2y \le s_2} \)求滿足條件的點\((x,y)\)所形成的平行四邊形面積\( \displaystyle =\frac{(t_2-t_1)(s_2-s_1)}{\left|\ \matrix{a_1&b_1 \cr a_2&b_2} \right|\ } \)的絕對值。

我以100新北市國中聯招這題示範如何使用Parallelogram(L1,L2)副程式。

在坐標平面上\(L_1\):\(x-y=0\)、\( L_2 \):\( x-y=h \),\( h<0 \)、\( L_3 \):\( \displaystyle y=-\frac{5}{2} \)及\(x\)軸四條直線圍出一個面積為10的平行四邊形,若直線\(L_2\)與\(y\)軸交點於點\( (0,k) \),則\( k+h \)為何?
(A)0 (B)2 (C)4 (D)8
(100新北市國中聯招,https://math.pro/db/thread-1135-1-1.html)

105.12.7補充
求區域\( S=\{\; (x,y)|\; 0\le a \le 1,0 \le b \le 1,x=a+b+1,y=2a-3b+1 \}\; \)所圍成的區域面積  
(105台南女中,https://math.pro/db/viewthread.php?tid=2488&page=2#pid15152)

110.7.29補充
在坐標平面上\(|\;x+2y|\;=3\)與\(|\;x-2y|\;=3\)所圍成的圖形面積為   平方單位。
(110建功高中國中部,https://math.pro/db/thread-3535-1-1.html)


改變變數顯示順序
例:x+y+1=0;
原本為y+x+1=0;
變成1+x+y=0;

(%i1) powerdisp:true;
(%o1) true

計算平行四邊形面積副程式
(%i2)
Parallelogram(L1,L2):=block
([coef,detcoef],
coef:coefmatrix([L1[2],L2[2]],[x,y]),
detcoef:determinant(coef),
print("取出二個直線的x,y係數",matrix([L1[2]],[L2[2]]),"=>",coef,",行列式值=",detcoef),
print("=|(",L1[3],"-",L1[1],")(",L2[3],"-",L2[1],")/",coef,"|"),
print("=|",L1[3]-L1[1],"*",L2[3]-L2[1],"/",detcoef,"|"),
print("=",abs((L1[3]-L1[1])*(L2[3]-L2[1])/detcoef))
)$


求1≦2x+3y≦4所圍成的平行四邊形面積?
 5≦6x+7y≦8

(%i4)
L1:[1,2*x+3*y,4];
L2:[5,6*x+7*y,8];

(%o3) \( [\; 1,2x+3y,4 ]\; \)
(%o4) \( [\; 5,6x+7y,8 ]\; \)

求平行四邊形面積
(%i5) Parallelogram(L1,L2);
取出二個直線的\(x,y\)係數\( \left[ \matrix{2x+3y \cr 6x+7y} \right] \)=>\( \left[ \matrix{2&3 \cr 6&7} \right] \),行列式值\(=-4\)
\( =|\; (4-1)(8-5)/ \left[ \matrix{2&3 \cr 6&7} \right] |\; \)
\( =|\; 3*3/-4 |\; \)
\( \displaystyle =\frac{9}{4}\)
(%o5) \( \displaystyle \frac{9}{4} \)

h≦x-y≦0,圍出面積為10的平行四邊形,h<0,求h=?
-5/2≦y≦0
(100新北市國中聯招)

(%i7)
L1:[h,x-y,0];
L3:[-5/2,y,0];

(%o6) \( [\;h,x-y,0 ]\; \)
(%o7) \( \displaystyle [\; -\frac{5}{2},y,0 ]\; \)

(%i8) Parallelogram(L1,L2)=10;
取出二個直線的\( x,y \)係數\( \left[ \matrix{x-y \cr 6x+7y} \right] \)=>\( \left[ \matrix{1&-1 \cr 6&7} \right] \),行列式值\(=13\)
\( =|\; (0-h)(8-5)/ \left[ \matrix{1&-1 \cr 6&7} \right] |\; \)
\( =|\; -h*3/13 |\; \)
\( \displaystyle =\frac{3 |\; h |\;}{13} \)
(%o8) \( \displaystyle \frac{3 |\; h |\;}{13}=10 \)

得到h=-130/3(正不合)
(%i9) to_poly_solve(%,h);
to_poly_solve: to_poly_solver.mac is obsolete; I'm loading to_poly_solve.mac instead.
(%o9) %\( \displaystyle union \left( [\; h=-\frac{130}{3} ]\;,[\; h=\frac{130}{3} ]\; \right)\)

___________________________________

已知\( \cases{\matrix{t_1 \le a_1x+b_1y+c_1z \le t_2 \cr s_1 \le a_2x+b_2y+c_2z \le s_2 \cr u_1 \le a_3x+b_3y+c_3z \le u_2}} \)求滿足條件的\((x,y,z)\)所形成的平行六面體體積\( \displaystyle =\frac{(t_2-t_1)(s_2-s_1)(u_2-u_1)}{\left|\ \matrix{a_1&b_1&c_1 \cr a_2&b_2&c_2 \cr a_3&b_3&c_3} \right|\ } \)的絕對值。

我以2題教甄試題來示範如何使用Parallelepiped(L1,L2,L3)副程式。

由三組平行平面\( \cases{\matrix{0 \le x+2y \le 4 \cr -1 \le x-3y+z \le 3 \cr 1 \le x+3y-2z \le 7}} \)所圍成的平行六面體體積為?
(99文華高中,https://math.pro/db/viewthread.php?tid=924&page=1#pid1993)

設空間中\( P(x,y,z) \)滿足不等式\( \displaystyle \Bigg\{\; \matrix{0 \le x+y \le 2 \cr 0 \le y+z \le 2 \cr 0 \le x+z \le 2} \),此P點之點集合形成一平行六面體,求此平行六面體體積為?
(102新化高中,https://math.pro/db/viewthread.php?tid=1710&page=1#pid9038)




改變變數顯示順序
例:x+y+z+1=0;
原本為z+y+x+1=0;
變成1+x+y+z=0;

(%i1) powerdisp:true;
(%o1) true

計算平行六面體體積副程式
(%i2)
Parallelepiped(L1,L2,L3):=block
([coef,detcoef],
coef:coefmatrix([L1[2],L2[2],L3[2]],[x,y,z]),
detcoef:determinant(coef),
print("取出三個直線的x,y,z係數",matrix([L1[2]],[L2[2]],[L3[2]]),"=>",coef,",行列式值=",detcoef),
print("=|(",L1[3],"-",L1[1],")(",L2[3],"-",L2[1],")(",L3[3],"-",L3[1],")/",coef,"|"),
print("=|",L1[3]-L1[1],"*",L2[3]-L2[1],"*",L3[3]-L3[1],"/",detcoef,"|"),
print("=",abs((L1[3]-L1[1])*(L2[3]-L2[1])*(L3[3]-L3[1])/detcoef))
)$


  0≦x+2y   ≦4
求-1≦x-3y+z ≦3所圍成的平行六面體體積?
  1≦x+3y-2z≦7
(99文華高中)

(%i5)
L1:[0,x+2*y,4];
L2:[-1,x-3*y+z,3];
L3:[1,x+3*y-2*z,7];

(%o3) \( [\; 0,x+2y,4 ]\; \)
(%o4) \( [\; -1,x-3y+z,3 ]\; \)
(%o5) \( [\; 1,x+3y-2z,7 ]\; \)

得到平行六面體體積
(%i6) Parallelepiped(L1,L2,L3);
取出三個直線的\(x,y,z\)係數\( \left[ \matrix{x+2y \cr x-3y+z \cr x+3y-2z} \right] \)=>\( \left[ \matrix{1&2&0\cr 1&-3&-1\cr 1&3&-2} \right] \),行列式值\(=9\)
\( =|\; (4-0)(3--1)(7-1)/\left[ \matrix{1&2&0\cr 1&-3&1\cr 1&3&-2} \right] |\; \)
\( =|\; 4*4*6/9 |\; \)
\( \displaystyle =\frac{32}{3} \)

(%o6) \( \displaystyle \frac{32}{3} \)

 0≦x+y≦2
求0≦y+z≦2所圍成的平行六面體體積?
 0≦x+z≦2
(102新化高中)

(%i9)
L1:[0,x+y,2];
L2:[0,y+z,2];
L3:[0,x+z,2];

(%o7) \( [\; 0,x+y,2 ]\; \)
(%o8) \( [\; 0,y+z,2 ]\; \)
(%o9) \( [\; 0,x+z,2 ]\; \)

得到平行六面體體積
(%i10) Parallelepiped(L1,L2,L3);
取出三個直線的\(x,y,z\)係數\( \left[ \matrix{x+y \cr y+z \cr x+z} \right] \)=>\( \left[ \matrix{1&1&0\cr 0&1&1\cr 1&0&1} \right] \),行列式值\(=2\)
\( =|\; (2-0)(2-0)(2-0)/\left[ \matrix{1&1&0\cr 0&1&1\cr 1&0&1} \right] |\; \)
\( =|\; 2*2*2/2 |\; \)
\( =4 \)
(%o10) 4

TOP

在坐標平面上以\(\Omega\)表曲線\(y=x-x^2\)與直線\(y=0\)所圍的有界區域。
(1)試求\(\Omega\)的面積。(3分)
(2)若直線\(y=cx\)將\(\Omega\)分成面積相等的兩塊區域,試求\(c\)之值。
(103指考數甲,https://math.pro/db/thread-1992-1-1.html)

(%i1)
HalfArea(y):=block
([Bound,LowerB,UpperB,Area,Equation,c],
print("y=",y,"和x軸交點的x坐標",Bound:sort(solve(y=0,x))),
[LowerB,UpperB]:map(rhs,Bound),
print("∫積分從",LowerB,"到",UpperB,"(",y,")dx=",Area:integrate(y,x,LowerB,UpperB)),
print("y=",y,"和y=cx交點的x坐標",Bound:sort(solve(y=c*x,x))),
[LowerB,UpperB]:map(rhs,Bound),
print("∫積分從",LowerB,"到",UpperB,"(",y-c*x,")dx為原來面積的一半"),
print("積分結果",Equation:factor(integrate(y-c*x,x,LowerB,UpperB)),"=",1/2,"*",Area),
print("去掉分數",Equation: (Equation=1/2*Area)*denom(lhs(Equation))),
print("開三次根號",Equation:Equation^(1/3)),
print("實數",c:solve(Equation,c)[1]),
return(rhs(c))
)$


(%i2)   c:HalfArea(x-x^2);
\(y=x-x^2\)和\(x\)軸交點的\(x\)坐標\( \left[x=0,x=1 \right] \)
∫積分從0到1\(\displaystyle (x-x^2)dx=\frac{1}{6}\)
\(y=x-x^2\)和\(y=cx\)交點的\(x\)坐標\(\left[x=0,x=1-c\right]\)
∫積分從0到\(1-c(-x^2-cx+x)dx\)為原來面積的一半
積分結果\(\displaystyle -\frac{(c-1)^3}{6}=\frac{1}{2}*\frac{1}{6} \)
去掉分數\(\displaystyle -(c-1)^3=\frac{1}{2}\)
開三次根號\( \displaystyle 1-c=\frac{1}{2^{1/3}} \)
實數\( \displaystyle c=\frac{2^{1/3}-1}{2^{1/3}} \)
(%o2) \( \displaystyle \frac{2^{1/3}-1}{2^{1/3}} \)

TOP

https://math.pro/db/thread-3030-1-2.html
已知三角形的內心到三頂點的距離分別為6,4,3,求此三角形面積為何?
原題的內切圓半徑不好算,不適合命題。

嘗試其他距離是否有簡單解,以下試兩種方案
方案1.\(x,y,z\)為整數,結論:方程式\(2xyzr^3+(x^2y^2+y^2z^2+z^2x^2)r^2−x^2y^2z^2=0\)沒有簡單解,不適合命題。
方案2.\(x,y,z\)加上根號,結論:方程式\(2\sqrt{xyz}r^3+(xy+yz+zx)r^2−xyz=0\)有簡單解,適合命題。
當\(x=\sqrt{2},y=\sqrt{5},z=\sqrt{10}\)時,內切圓半徑\(r=1\),三角形三邊長為3,4,5,面積為6
題目:已知三角形的內心到三頂點的距離分別為\(\sqrt{2},\sqrt{5},\sqrt{10}\),求此三角形面積為何?6


是否有整數x,y,z讓方程式\(2xyzr^3+(x^2y^2+y^2z^2+z^2x^2)r^2-x^2y^2z^2=0\)有簡單解
結論:方程式沒有簡單解,不適合命題

(%i1)
n:10;
for x:1 thru n do
  (for y:x+1 thru n do
     (for z:y+1 thru n do
        (equation:2*x*y*z*r^3+(x^2*y^2+y^2*z^2+z^2*x^2)*r^2-x^2*y^2*z^2,
         print("x=",x,",y=",y,",z=",z,",方程式",factor(equation),"=0")
        )
     )
  );

(%o1) 10
\( x=1,y=2,z=3\),方程式\(12r^3+49r^2-36=0\)
\( x=1,y=2,z=4\),方程式\(4(4r^3+21r^2-16)=0\)
\( x=1,y=2,z=5\),方程式\(20r^3+129r^2-100=0\)
\( x=1,y=2,z=6\),方程式\(8(3r^3+23r^2-18)=0\)
\( x=1,y=2,z=7\),方程式\(28r^3+249r^2-196=0\)
\( x=1,y=2,z=8\),方程式\(4(8r^3+81r^2-64)=0\)
\( x=1,y=2,z=9\),方程式\(36r^3+409r^2-324=0\)
\( x=1,y=2,z=10\),方程式\(8(5r^3+63r^2-50)=0\)
\( x=1,y=3,z=4\),方程式\(24r^3+169r^2-144=0\)
\( x=1,y=3,z=5\),方程式\(30r^3+259r^2-225=0\)
\( x=1,y=3,z=6\),方程式\(9(4r^3+41r^2-36)=0\)
\( x=1,y=3,z=7\),方程式\(42r^3+499r^2-441=0\)
\( x=1,y=3,z=8\),方程式\(48r^3+649r^2-576=0\)
\( x=1,y=3,z=9\),方程式\(9(6r^3+91r^2-81)=0\)
\( x=1,y=3,z=10\),方程式\(60r^3+1009r^2-900=0\)
\( x=1,y=4,z=5\),方程式\(40r^3+441r^2-400=0\)
\( x=1,y=4,z=6\),方程式\(4(12r^3+157r^2-144)=0\)
\( x=1,y=4,z=7\),方程式\(56r^3+849r^2-784=0\)
\( x=1,y=4,z=8\),方程式\(16(4r^3+69r^2-64)=0\)
\( x=1,y=4,z=9\),方程式\(72r^3+1393r^2-1296=0\)
\( x=1,y=4,z=10\),方程式\(4(20r^3+429r^2-400)=0\)
\( x=1,y=5,z=6\),方程式\(60r^3+961r^2-900=0\)
\( x=1,y=5,z=7\),方程式\(70r^3+1299r^2-1225=0\)
\( x=1,y=5,z=8\),方程式\(80r^3+1689r^2-1600=0\)
\( x=1,y=5,z=9\),方程式\(90r^3+2131r^2-2025=0\)
\( x=1,y=5,z=10\),方程式\(25(4r^3+105r^2-100)=0\)
\( x=1,y=6,z=7\),方程式\(84r^3+1849r^2-1764=0\)
\( x=1,y=6,z=8\),方程式\(4(24r^3+601r^2-576)=0\)
\( x=1,y=6,z=9\),方程式\(9(12r^3+337r^2-324)=0\)
\( x=1,y=6,z=10\),方程式\(8(15r^3+467r^2-450)=0\)
\( x=1,y=7,z=8\),方程式\(112r^3+3249r^2-3136=0\)
\( x=1,y=7,z=9\),方程式\(126r^3+4099r^2-3969=0\)
\( x=1,y=7,z=10\),方程式\(140r^3+5049r^2-4900=0\)
\( x=1,y=8,z=9\),方程式\(144r^3+5329r^2-5184=0\)
\( x=1,y=8,z=10\),方程式\(4(40r^3+1641r^2-1600)=0\)
\( x=1,y=9,z=10\),方程式\(180r^3+8281r^2-8100=0\)
\( x=2,y=3,z=4\),方程式\(4(12r^3+61r^2-144)=0\)
\( x=2,y=3,z=5\),方程式\(60r^3+361r^2-900=0\)
\( x=2,y=3,z=6\),方程式\(72(r^3+7r^2-18)=0\)
\( x=2,y=3,z=7\),方程式\(84r^3+673r^2-1764=0\)
\( x=2,y=3,z=8\),方程式\(4(24r^3+217r^2-576)=0\)
\( x=2,y=3,z=9\),方程式\(9(12r^3+121r^2-324)=0\)
\( x=2,y=3,z=10\),方程式\(8(15r^3+167r^2-450)=0\)
\( x=2,y=4,z=5\),方程式\(4(20r^3+141r^2-400)=0\)
\( x=2,y=4,z=6\),方程式\(16(6r^3+49r^2-144)=0\)
\( x=2,y=4,z=7\),方程式\(4(28r^3+261r^2-784)=0\)
\( x=2,y=4,z=8\),方程式\(64(2r^3+21r^2-64)=0\)
\( x=2,y=4,z=9\),方程式\(4(36r^3+421r^2-1296)=0\)
\( x=2,y=4,z=10\),方程式\(16(10r^3+129r^2-400)=0\)
\( x=2,y=5,z=6\),方程式\(8(15r^3+143r^2-450)=0\)
\( x=2,y=5,z=7\),方程式\(140r^3+1521r^2-4900=0\)
\( x=2,y=5,z=8\),方程式\(4(40r^3+489r^2-1600)=0\)
\( x=2,y=5,z=9\),方程式\(180r^3+2449r^2-8100=0\)
\( x=2,y=5,z=10\),方程式\(200(r^3+15r^2-50)=0\)
\( x=2,y=6,z=7\),方程式\(8(21r^3+263r^2-882)=0\)
\( x=2,y=6,z=8\),方程式\(16(12r^3+169r^2-576)=0\)
\( x=2,y=6,z=9\),方程式\(72(3r^3+47r^2-162)=0\)
\( x=2,y=6,z=10\),方程式\(16(15r^3+259r^2-900)=0\)
\( x=2,y=7,z=8\),方程式\(4(56r^3+897r^2-3136)=0\)
\( x=2,y=7,z=9\),方程式\(252r^3+4489r^2-15876=0\)
\( x=2,y=7,z=10\),方程式\(8(35r^3+687r^2-2450)=0\)
\( x=2,y=8,z=9\),方程式\(4(72r^3+1441r^2-5184)=0\)
\( x=2,y=8,z=10\),方程式\(16(20r^3+441r^2-1600)=0\)
\( x=2,y=9,z=10\),方程式\(8(45r^3+1103r^2-4050)=0\)
\( x=3,y=4,z=5\),方程式\(120r^3+769r^2-3600=0\)
\( x=3,y=4,z=6\),方程式\(36(4r^3+29r^2-144)=0\)
\( x=3,y=4,z=7\),方程式\(168r^3+1369r^2-7056=0\)
\( x=3,y=4,z=8\),方程式\(16(12r^3+109r^2-576)=0\)
\( x=3,y=4,z=9\),方程式\(9(24r^3+241r^2-1296)=0\)
\( x=3,y=4,z=10\),方程式\(4(60r^3+661r^2-3600)=0\)
\( x=3,y=5,z=6\),方程式\(9(20r^3+161r^2-900)=0\)
\( x=3,y=5,z=7\),方程式\(210r^3+1891r^2-11025=0\)
\( x=3,y=5,z=8\),方程式\(240r^3+2401r^2-14400=0\)
\( x=3,y=5,z=9\),方程式\(9(30r^3+331r^2-2025)=0\)
\( x=3,y=5,z=10\),方程式\(25(12r^3+145r^2-900)=0\)
\( x=3,y=6,z=7\),方程式\(9(28r^3+281r^2-1764)=0\)
\( x=3,y=6,z=8\),方程式\(36(8r^3+89r^2-576)=0\)
\( x=3,y=6,z=9\),方程式\(81(4r^3+49r^2-324)=0\)
\( x=3,y=6,z=10\),方程式\(72(5r^3+67r^2-450)=0\)
\( x=3,y=7,z=8\),方程式\(336r^3+4153r^2-28224=0\)
\( x=3,y=7,z=9\),方程式\(9(42r^3+571r^2-3969)=0\)
\( x=3,y=7,z=10\),方程式\(420r^3+6241r^2-44100=0\)
\( x=3,y=8,z=9\),方程式\(9(48r^3+721r^2-5184)=0\)
\( x=3,y=8,z=10\),方程式\(4(120r^3+1969r^2-14400)=0\)
\( x=3,y=9,z=10\),方程式\(9(60r^3+1081r^2-8100)=0\)
\( x=4,y=5,z=6\),方程式\(4(60r^3+469r^2-3600)=0\)
\( x=4,y=5,z=7\),方程式\(280r^3+2409r^2-19600=0\)
\( x=4,y=5,z=8\),方程式\(16(20r^3+189r^2-1600)=0\)
\( x=4,y=5,z=9\),方程式\(360r^3+3721r^2-32400=0\)
\( x=4,y=5,z=10\),方程式\(100(4r^3+45r^2-400)=0\)
\( x=4,y=6,z=7\),方程式\(4(84r^3+781r^2-7056)=0\)
\( x=4,y=6,z=8\),方程式\(64(6r^3+61r^2-576)=0\)
\( x=4,y=6,z=9\),方程式\(36(12r^3+133r^2-1296)=0\)
\( x=4,y=6,z=10\),方程式\(16(30r^3+361r^2-3600)=0\)
\( x=4,y=7,z=8\),方程式\(16(28r^3+309r^2-3136)=0\)
\( x=4,y=7,z=9\),方程式\(504r^3+6049r^2-63504=0\)
\( x=4,y=7,z=10\),方程式\(4(140r^3+1821r^2-19600)=0\)
\( x=4,y=8,z=9\),方程式\(16(36r^3+469r^2-5184)=0\)
\( x=4,y=8,z=10\),方程式\(64(10r^3+141r^2-1600)=0\)
\( x=4,y=9,z=10\),方程式\(4(180r^3+2749r^2-32400)=0\)
\( x=5,y=6,z=7\),方程式\(420r^3+3889r^2-44100=0\)
\( x=5,y=6,z=8\),方程式\(4(5r+24)(24r^2+125r-600)=0\)
\( x=5,y=6,z=9\),方程式\(9(60r^3+649r^2-8100)=0\)
\( x=5,y=6,z=10\),方程式\(200(3r^3+35r^2-450)=0\)
\( x=5,y=7,z=8\),方程式\(560r^3+5961r^2-78400=0\)
\( x=5,y=7,z=9\),方程式\(630r^3+7219r^2-99225=0\)
\( x=5,y=7,z=10\),方程式\(25(28r^3+345r^2-4900)=0\)
\( x=5,y=8,z=9\),方程式\(720r^3+8809r^2-129600=0\)
\( x=5,y=8,z=10\),方程式\(100(8r^3+105r^2-1600)=0\)
\( x=5,y=9,z=10\),方程式\(25(36r^3+505r^2-8100)=0\)
\( x=6,y=7,z=8\),方程式\(4(168r^3+1801r^2-28224)=0\)
\( x=6,y=7,z=9\),方程式\(9(84r^3+961r^2-15876)=0\)
\( x=6,y=7,z=10\),方程式\(8(105r^3+1283r^2-22050)=0\)
\( x=6,y=8,z=9\),方程式\(36(24r^3+289r^2-5184)=0\)
\( x=6,y=8,z=10\),方程式\(16(60r^3+769r^2-14400)=0\)
\( x=6,y=9,z=10\),方程式\(72(15r^3+203r^2-4050)=0\)
\( x=7,y=8,z=9\),方程式\(1008r^3+12289r^2-254016=0\)
\( x=7,y=8,z=10\),方程式\(4(280r^3+3609r^2-78400)=0\)
\( x=7,y=9,z=10\),方程式\(1260r^3+16969r^2-396900=0\)
\( x=8,y=9,z=10\),方程式\(4(360r^3+4921r^2-129600)=0\)
(%o2) done

是否有\(\sqrt{x},\sqrt{y},\sqrt{z}\)讓方程式\(2\sqrt{xyz}r^3+(xy+yz+zx)r^2-xyz=0\)有簡單解
結論:當\(x=\sqrt{2},y=\sqrt{5},z=\sqrt{10}\)時,內切圓半徑\(r=1\),三角形三邊長為3,4,5,面積為6,適合命題

(%i3)
n:10;
for x:1 thru n do
  (for y:x+1 thru n do
     (for z:y+1 thru n do
        (equation:2*sqrt(x*y*z)*r^3+(x*y+y*z+z*x)*r^2-x*y*z,
         print("x=",sqrt(x),",y=",sqrt(y),",z=",sqrt(z),",方程式",factor(equation),"=0")
        )
     )
  );

(%o3) 10
\(x=1,y=\sqrt{2},z=\sqrt{3}\),方程式\(2\sqrt{6}r^3+11r^2-6=0\)
\(x=1,y=\sqrt{2},z=2\),方程式\(2(2^{3/2}r^3+7r^2-4)=0\)
\(x=1,y=\sqrt{2},z=\sqrt{5}\),方程式\(2\sqrt{10}r^3+17r^2-10=0\)
\(x=1,y=\sqrt{2},z=\sqrt{6}\),方程式\(4(\sqrt{3}r^3+5r^2-3)=0\)
\(x=1,y=\sqrt{2},z=\sqrt{7}\),方程式\(2\sqrt{14}r^3+23r^2-14=0\)
\(x=1,y=\sqrt{2},z=2^{3/2}\),方程式\(2(4r^3+13r^2-8)=0\)
\(x=1,y=\sqrt{2},z=3\),方程式\(32^{3/2}r^3+29r^2-18=0\)
\(x=1,y=\sqrt{2},z=\sqrt{10}\),方程式\(4(\sqrt{5}r^3+8r^2-5)=0\)
\(x=1,y=\sqrt{3},z=2\),方程式\(4\sqrt{3}r^3+19r^2-12=0\)
\(x=1,y=\sqrt{3},z=\sqrt{5}\),方程式\(2\sqrt{15}r^3+23r^2-15=0\)
\(x=1,y=\sqrt{3},z=\sqrt{6}\),方程式\(3(2^{3/2}r^3+9r^2-6)=0\)
\(x=1,y=\sqrt{3},z=\sqrt{7}\),方程式\(2\sqrt{21}r^3+31r^2-21=0\)
\(x=1,y=\sqrt{3},z=2^{3/2}\),方程式\(4\sqrt{6}r^3+35r^2-24=0\)
\(x=1,y=\sqrt{3},z=3\),方程式\(3(2\sqrt{3}r^3+13r^2-9)=0\)
\(x=1,y=\sqrt{3},z=\sqrt{10}\),方程式\(2\sqrt{30}r^3+43r^2-30=0\)
\(x=1,y=2 ,z=\sqrt{5}\),方程式\(4\sqrt{5}r^3+29r^2-20=0\)
\(x=1,y=2 ,z=\sqrt{6}\),方程式\(2(2\sqrt{6}r^3+17r^2-12)=0\)
\(x=1,y=2 ,z=\sqrt{7}\),方程式\(4\sqrt{7}r^3+39r^2-28=0\)
\(x=1,y=2 ,z=2^{3/2}\),方程式\(4(2^{3/2}r^3+11r^2-8)=0\)
\(x=1,y=2 ,z=3\),方程式\(12r^3+49r^2-36=0\)
\(x=1,y=2 ,z=\sqrt{10}\),方程式\(2(2\sqrt{10}r^3+27r^2-20)=0\)
\(x=1,y=\sqrt{5},z=\sqrt{6}\),方程式\(2\sqrt{30}r^3+41r^2-30=0\)
\(x=1,y=\sqrt{5},z=\sqrt{7}\),方程式\(2\sqrt{35}r^3+47r^2-35=0\)
\(x=1,y=\sqrt{5},z=2^{3/2}\),方程式\(4\sqrt{10}r^3+53r^2-40=0\)
\(x=1,y=\sqrt{5},z=3\),方程式\(6\sqrt{5}r^3+59r^2-45=0\)
\(x=1,y=\sqrt{5},z=\sqrt{10}\),方程式\(5(2^{3/2}r^3+13r^2-10)=0\)
\(x=1,y=\sqrt{6},z=\sqrt{7}\),方程式\(2\sqrt{42}r^3+55r^2-42=0\)
\(x=1,y=\sqrt{6},z=2^{3/2}\),方程式\(2(4\sqrt{3}r^3+31r^2-24)=0\)
\(x=1,y=\sqrt{6},z=3\),方程式\(3(2\sqrt{6}r^3+23r^2-18)=0\)
\(x=1,y=\sqrt{6},z=\sqrt{10}\),方程式\(4(\sqrt{15}r^3+19r^2-15)=0\)
\(x=1,y=\sqrt{7},z=2^{3/2}\),方程式\(4\sqrt{14}r^3+71r^2-56=0\)
\(x=1,y=\sqrt{7},z=3\),方程式\(6\sqrt{7}r^3+79r^2-63=0\)
\(x=1,y=\sqrt{7},z=\sqrt{10}\),方程式\(2\sqrt{70}r^3+87r^2-70=0\)
\(x=1,y=2^{3/2},z=3\),方程式\(32^{5/2}r^3+89r^2-72=0\)
\(x=1,y=2^{3/2},z=\sqrt{10}\),方程式\(2(4\sqrt{5}r^3+49r^2-40)=0\)
\(x=1,y=3 ,z=\sqrt{10}\),方程式\(6\sqrt{10}r^3+109r^2-90=0\)
\(x=\sqrt{2},y=\sqrt{3},z=2\),方程式\(2(2\sqrt{6}r^3+13r^2-12)=0\)
\(x=\sqrt{2},y=\sqrt{3},z=\sqrt{5}\),方程式\(2\sqrt{30}r^3+31r^2-30=0\)
\(x=\sqrt{2},y=\sqrt{3},z=\sqrt{6}\),方程式\(12(r^3+3r^2-3)=0\)
\(x=\sqrt{2},y=\sqrt{3},z=\sqrt{7}\),方程式\(2\sqrt{42}r^3+41r^2-42=0\)
\(x=\sqrt{2},y=\sqrt{3},z=2^{3/2}\),方程式\(2(4\sqrt{3}r^3+23r^2-24)=0\)
\(x=\sqrt{2},y=\sqrt{3},z=3\),方程式\(3(2\sqrt{6}r^3+17r^2-18)=0\)
\(x=\sqrt{2},y=\sqrt{3},z=\sqrt{10}\),方程式\(4(\sqrt{15}r^3+14r^2-15)=0\)
\(x=\sqrt{2},y=2 ,z=\sqrt{5}\),方程式\(2(2\sqrt{10}r^3+19r^2-20)=0\)
\(x=\sqrt{2},y=2 ,z=\sqrt{6}\),方程式\(4(2\sqrt{3}r^3+11r^2-12)=0\)
\(x=\sqrt{2},y=2 ,z=\sqrt{7}\),方程式\(2(2\sqrt{14}r^3+25r^2-28)=0\)
\(x=\sqrt{2},y=2 ,z=2^{3/2}\),方程式\(8(2r^3+7r^2-8)=0\)
\(x=\sqrt{2},y=2 ,z=3\),方程式\(2(32^{3/2}r^3+31r^2-36)=0\)
\(x=\sqrt{2},y=2 ,z=\sqrt{10}\),方程式\(4(2\sqrt{5}r^3+17r^2-20)=0\)
\(x=\sqrt{2},y=\sqrt{5},z=\sqrt{6}\),方程式\(4(\sqrt{15}r^3+13r^2-15)=0\)
\(x=\sqrt{2},y=\sqrt{5},z=\sqrt{7}\),方程式\(2\sqrt{70}r^3+59r^2-70=0\)
\(x=\sqrt{2},y=\sqrt{5},z=2^{3/2}\),方程式\(2(4\sqrt{5}r^3+33r^2-40)=0\)
\(x=\sqrt{2},y=\sqrt{5},z=3\),方程式\(6\sqrt{10}r^3+73r^2-90=0\)
\(\bbox[border:1px solid black]{x=\sqrt{2},y=\sqrt{5},z=\sqrt{10},方程式20(r-1)(r^2+5r+5)=0}\)
\(x=\sqrt{2},y=\sqrt{6},z=\sqrt{7}\),方程式\(4(\sqrt{21}r^3+17r^2-21)=0\)
\(x=\sqrt{2},y=\sqrt{6},z=2^{3/2}\),方程式\(4(2\sqrt{6}r^3+19r^2-24)=0\)
\(x=\sqrt{2},y=\sqrt{6},z=3\),方程式\(12(\sqrt{3}r^3+7r^2-9)=0\)
\(x=\sqrt{2},y=\sqrt{6},z=\sqrt{10}\),方程式\(4(\sqrt{30}r^3+23r^2-30)=0\)
\(x=\sqrt{2},y=\sqrt{7},z=2^{3/2}\),方程式\(2(4\sqrt{7}r^3+43r^2-56)=0\)
\(x=\sqrt{2},y=\sqrt{7},z=3\),方程式\(6\sqrt{14}r^3+95r^2-126=0\)
\(x=\sqrt{2},y=\sqrt{7},z=\sqrt{10}\),方程式\(4(\sqrt{35}r^3+26r^2-35)=0\)
\(x=\sqrt{2},y=2^{3/2},z=3\),方程式\(2(12r^3+53r^2-72)=0\)
\(x=\sqrt{2},y=2^{3/2},z=\sqrt{10}\),方程式\(4(2\sqrt{10}r^3+29r^2-40)=0\)
\(x=\sqrt{2},y=3 ,z=\sqrt{10}\),方程式\(4(3\sqrt{5}r^3+32r^2-45)=0\)
\(x=\sqrt{3},y=2 ,z=\sqrt{5}\),方程式\(4\sqrt{15}r^3+47r^2-60=0\)
\(x=\sqrt{3},y=2 ,z=\sqrt{6}\),方程式\(6(2^{3/2}r^3+9r^2-12)=0\)
\(x=\sqrt{3},y=2 ,z=\sqrt{7}\),方程式\(4\sqrt{21}r^3+61r^2-84=0\)
\(x=\sqrt{3},y=2 ,z=2^{3/2}\),方程式\(4(2\sqrt{6}r^3+17r^2-24)=0\)
\(x=\sqrt{3},y=2 ,z=3\),方程式\(3(4\sqrt{3}r^3+25r^2-36)=0\)
\(x=\sqrt{3},y=2 ,z=\sqrt{10}\),方程式\(2(2\sqrt{30}r^3+41r^2-60)=0\)
\(x=\sqrt{3},y=\sqrt{5},z=\sqrt{6}\),方程式\(3(2\sqrt{10}r^3+21r^2-30)=0\)
\(x=\sqrt{3},y=\sqrt{5},z=\sqrt{7}\),方程式\(2\sqrt{105}r^3+71r^2-105=0\)
\(x=\sqrt{3},y=\sqrt{5},z=2^{3/2}\),方程式\(4\sqrt{30}r^3+79r^2-120=0\)
\(x=\sqrt{3},y=\sqrt{5},z=3\),方程式\(3(2\sqrt{15}r^3+29r^2-45)=0\)
\(x=\sqrt{3},y=\sqrt{5},z=\sqrt{10}\),方程式\(5(2\sqrt{6}r^3+19r^2-30)=0\)
\(x=\sqrt{3},y=\sqrt{6},z=\sqrt{7}\),方程式\(3(2\sqrt{14}r^3+27r^2-42)=0\)
\(x=\sqrt{3},y=\sqrt{6},z=2^{3/2}\),方程式\(6(4r^3+15r^2-24)=0\)
\(x=\sqrt{3},y=\sqrt{6},z=3\),方程式\(9(2^{3/2}r^3+11r^2-18)=0\)
\(x=\sqrt{3},y=\sqrt{6},z=\sqrt{10}\),方程式\(12(\sqrt{5}r^3+9r^2-15)=0\)
\(x=\sqrt{3},y=\sqrt{7},z=2^{3/2}\),方程式\(4\sqrt{42}r^3+101r^2-168=0\)
\(x=\sqrt{3},y=\sqrt{7},z=3\),方程式\(3(2\sqrt{21}r^3+37r^2-63)=0\)
\(x=\sqrt{3},y=\sqrt{7},z=\sqrt{10}\),方程式\(2\sqrt{210}r^3+121r^2-210=0\)
\(x=\sqrt{3},y=2^{3/2},z=3\),方程式\(3(4\sqrt{6}r^3+41r^2-72)=0\)
\(x=\sqrt{3},y=2^{3/2},z=\sqrt{10}\),方程式\(2(4\sqrt{15}r^3+67r^2-120)=0\)
\(x=\sqrt{3},y=3 ,z=\sqrt{10}\),方程式\(3(2\sqrt{30}r^3+49r^2-90)=0\)
\(x=2,y=\sqrt{5},z=\sqrt{6}\),方程式\(2(2\sqrt{30}r^3+37r^2-60)=0\)
\(x=2,y=\sqrt{5},z=\sqrt{7}\),方程式\(4\sqrt{35}r^3+83r^2-140=0\)
\(x=2,y=\sqrt{5},z=2^{3/2}\),方程式\(4(2\sqrt{10}r^3+23r^2-40)=0\)
\(x=2,y=\sqrt{5},z=3\),方程式\(12\sqrt{5}r^3+101r^2-180=0\)
\(x=2,y=\sqrt{5},z=\sqrt{10}\),方程式\(10(2^{3/2}r^3+11r^2-20)=0\)
\(x=2,y=\sqrt{6},z=\sqrt{7}\),方程式\(2(2\sqrt{42}r^3+47r^2-84)=0\)
\(x=2,y=\sqrt{6},z=2^{3/2}\),方程式\(8(2\sqrt{3}r^3+13r^2-24)=0\)
\(x=2,y=\sqrt{6},z=3\),方程式\(6(2\sqrt{6}r^3+19r^2-36)=0\)
\(x=2,y=\sqrt{6},z=\sqrt{10}\),方程式\(4(2\sqrt{15}r^3+31r^2-60)=0\)
\(x=2,y=\sqrt{7},z=2^{3/2}\),方程式\(4(2\sqrt{14}r^3+29r^2-56)=0\)
\(x=2,y=\sqrt{7},z=3\),方程式\(12\sqrt{7}r^3+127r^2-252=0\)
\(x=2,y=\sqrt{7},z=\sqrt{10}\),方程式\(2(2\sqrt{70}r^3+69r^2-140)=0\)
\(x=2,y=2^{3/2},z=3\),方程式\(4(32^{3/2}r^3+35r^2-72)=0\)
\(x=2,y=2^{3/2},z=\sqrt{10}\),方程式\(8(2\sqrt{5}r^3+19r^2-40)=0\)
\(x=2,y=3 ,z=\sqrt{10}\),方程式\(2(6\sqrt{10}r^3+83r^2-180)=0\)
\(x=\sqrt{5},y=\sqrt{6},z=\sqrt{7}\),方程式\(2\sqrt{210}r^3+107r^2-210=0\)
\(x=\sqrt{5},y=\sqrt{6},z=2^{3/2}\),方程式\(2(4\sqrt{15}r^3+59r^2-120)=0\)
\(x=\sqrt{5},y=\sqrt{6},z=3\),方程式\(3(2\sqrt{30}r^3+43r^2-90)=0\)
\(x=\sqrt{5},y=\sqrt{6},z=\sqrt{10}\),方程式\(20(\sqrt{3}r^3+7r^2-15)=0\)
\(x=\sqrt{5},y=\sqrt{7},z=2^{3/2}\),方程式\(4\sqrt{70}r^3+131r^2-280=0\)
\(x=\sqrt{5},y=\sqrt{7},z=3\),方程式\(6\sqrt{35}r^3+143r^2-315=0\)
\(x=\sqrt{5},y=\sqrt{7},z=\sqrt{10}\),方程式\(5(2\sqrt{14}r^3+31r^2-70)=0\)
\(x=\sqrt{5},y=2^{3/2},z=3\),方程式\(12\sqrt{10}r^3+157r^2-360=0\)
\(x=\sqrt{5},y=2^{3/2},z=\sqrt{10}\),方程式\(10(4r^3+17r^2-40)=0\)
\(x=\sqrt{5},y=3 ,z=\sqrt{10}\),方程式\(5(32^{3/2}r^3+37r^2-90)=0\)
\(x=\sqrt{6},y=\sqrt{7},z=2^{3/2}\),方程式\(2(4\sqrt{21}r^3+73r^2-168)=0\)
\(x=\sqrt{6},y=\sqrt{7},z=3\),方程式\(3(2\sqrt{42}r^3+53r^2-126)=0\)
\(x=\sqrt{6},y=\sqrt{7},z=\sqrt{10}\),方程式\(4(\sqrt{105}r^3+43r^2-105)=0\)
\(x=\sqrt{6},y=2^{3/2},z=3\),方程式\(6(4\sqrt{3}r^3+29r^2-72)=0\)
\(x=\sqrt{6},y=2^{3/2},z=\sqrt{10}\),方程式\(4(2\sqrt{30}r^3+47r^2-120)=0\)
\(x=\sqrt{6},y=3 ,z=\sqrt{10}\),方程式\(12(\sqrt{15}r^3+17r^2-45)=0\)
\(x=\sqrt{7},y=2^{3/2},z=3\),方程式\(12\sqrt{14}r^3+191r^2-504=0\)
\(x=\sqrt{7},y=2^{3/2},z=\sqrt{10}\),方程式\(2(4\sqrt{35}r^3+103r^2-280)=0\)
\(x=\sqrt{7},y=3 ,z=\sqrt{10}\),方程式\(6\sqrt{70}r^3+223r^2-630=0\)
\(x=2^{3/2},y=3 ,z=\sqrt{10}\),方程式\(2(12\sqrt{5}r^3+121r^2-360)=0\)
(%o4) done

TOP


數學圖形素描教室:用旋轉曲面、多面體、拓樸形狀來創作!結合數學與美學的全新領域
数学デッサン教室 描いて楽しむ数学のかたち
作者: 瑞慶山 香佳
譯者: 陳朕疆
出版社:台灣東販
出版日期:2019/10/28

節錄書中蘋果曲面參數式

◎蘋果曲面的製作方法
  該怎麼建構出蘋果曲面呢?讓我們來看看製作方法吧。
①建構出一個環面。
\(\cases{x=(4+cos u)cos v \cr y=(4+cos u)sin v \cr z=5 sin u},-\pi \le u \le \pi,0 \le v \le 2 \pi\)
②調整成接近角狀環面的形狀。
\(\cases{x=(4+3.8cos u)cos v \cr y=(4+3.8 cos u)sin v \cr z=5sin u},-\pi \le u \le \pi,0\le v \le 2 \pi\)
③調整成上方較胖,下方較瘦的形狀。
\(\cases{x=(4+3.8 cos u)cos v \cr y=(4+3.8 cos u)sin v \cr z=5sin u+2 cos u},-\pi \le u \le \pi,0\le v \le 2\pi\)
④建構出蘋果的芯。
\(\cases{x=(4+3.8 cos u)cos v \cr y=(4+3.8 cos u)sin v \cr z=-5log_{10}(1-0.315u)+5sin u+2 cos u},-\pi \le u \le \pi,0\le v \le 2\pi\)



以前要先載入draw.lisp才能使用draw3d指令
但現在draw3d已經是maxima內建指令不再需要先載入draw.lisp

(%i1) load("draw");
(%o1) C:/maxima-5.43.0/share/maxima/5.43.0/share/draw/draw.lisp

以vtk當作渲染器
(%i2) draw_renderer: 'vtk;
(%o2) vtk

①建構出一個環面
(%i6)
x: (4+cos(u))*cos(v);
y: (4+cos(u))*sin(v);
z:5*sin(u);
draw3d(enhanced3d=true,
              parametric_surface(x,y,z,u,-%pi,%pi,v,0,2*%pi));

(x) \((cos(u)+4)cos(v)\)
(y) \((cos(u)+4)sin(v)\)
(z) \(5sin(u)\)
(%o6) done


②調整成接近角狀環面的形狀
(%i10)
x: (4+3.8*cos(u))*cos(v);
y: (4+3.8*cos(u))*sin(v);
z:5*sin(u);
draw3d(enhanced3d=true,
              parametric_surface(x,y,z,u,-%pi,%pi,v,0,2*%pi));

(x) \((3.8cos(u)+4)cos(v)\)
(y) \((3.8cos(u)+4)sin(v)\)
(z) \(5sin(u)\)
(%o10) done


③調整成上方較胖,下方較瘦的形狀
(%i14)
x: (4+3.8*cos(u))*cos(v);
y: (4+3.8*cos(u))*sin(v);
z:5*sin(u)+2*cos(u);
draw3d(enhanced3d=true,
              parametric_surface(x,y,z,u,-%pi,%pi,v,0,2*%pi));

(x) \((3.8cos(u)+4)cos(v)\)
(y) \((3.8cos(u)+4)sin(v)\)
(z) \(5sin(u)+2cos(u)\)
(%o14) done


④建構出蘋果的芯
(%i18)
x: (4+3.8*cos(u))*cos(v);
y: (4+3.8*cos(u))*sin(v);
z:-5*log(1-0.315*u)/log(10)+5*sin(u)+2*cos(u);
draw3d(enhanced3d=true,
              parametric_surface(x,y,z,u,-%pi,%pi,v,0,2*%pi));

(x) \((3.8cos(u)+4)cos(v)\)
(y) \((3.8cos(u)+4)sin(v)\)
(z) \(\displaystyle 5sin(u)+2cos(u)-\frac{5log(1-0.315u)}{log(10)}\)
(%o18) done

TOP

 40 1234
發新話題